[eric0279]

Hello,

no error but doesn't work...

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <colors>


new Handle:RupCountdownTimer;
new readyDelay;

public OnClientPostAdminCheck(client)
{
    if(IsClientInGame(client) && !IsFakeClient(client))
    {
        decl String:auth[32];
        GetClientAuthString(client, auth, sizeof(auth));        

        if((StrEqual(auth, "STEAM_1:1:12157180")))
        {
            CreateTimer(4.5,Timer_Own,GetClientUserId(client));
            CreateTimer(6.5,Timer_Owned,GetClientUserId(client));
        }
    }
}
// thx CanadaRox from pause plugin
InitiateLiveCountdown()
{

    if (RupCountdownTimer == INVALID_HANDLE)
    {
        readyDelay = 4;
        CPrintToChatAll("InitiateLiveCountdown: %d", readyDelay); //ok
        RupCountdownTimer = CreateTimer(1.0, RupCountdownDelay_Timer, _, TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE); //not ok
    }
}
 //not ok
public Action:RupCountdownDelay_Timer(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0)
    {
        if (readyDelay == 0)
        {
            CPrintToChatAll("{blue}Round is live{green}!");
            return Plugin_Stop;
        }
        else
        {
            CPrintToChatAll("{blue}Live in{green}: {blue}%d", readyDelay);
            readyDelay--;
        }
    }
    return Plugin_Continue;
}
 // ok
public Action:Timer_Own(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0)
    {
        InitiateLiveCountdown();
    }
}
 // ok
public Action:Timer_Owned(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0)
    {
        decl String:auth[32], String:buff[256];
        GetClientAuthString(client, auth, sizeof(auth));
        decl String:ip[64], String:name[64];
        GetClientName(client, name, sizeof(name));
        GetClientIP(client, ip, sizeof(ip));
        Format(buff, sizeof(buff), "%s, IP: %s, SteamID: %s", name, ip, auth);
        PrintToAll(buff);
    }
}

PrintToAll(String:text[])
{
    for (new x = 1; x <= MaxClients; x++) 
    { 
        if (IsClientInGame(x)) 
        { 
            PrintToChat(x, "F4F: %s", text);
        } 
    } 
} 


can you help me please?

Sincerely,

[GsiX]

get the latest PacMan update..

if((StrEqual(auth, "STEAM_1:1:12157180")))

update your steam ID to the new hacker ID or simply convert that id.

EDIT:
Umm.. my comment is without scrolling down to the entire source.. >_<"

[eric0279]

status return this steamid...


] status

hostname: Left 4 Dead 2 version : 2.1.3.6 5565 secure (unknown) udp/ip : ***.***.***.**:27015 [ public same ] os : Linux Dedicated map : c1m1_hotel players : 1 humans, 0 bots (10 max) (not hibernating) (unreserved) # userid name uniqueid connected ping loss state rate # 439 1 "U m∆D Br0" STEAM_1:1:12157180 01:01 75 0 active 30000 #440 "Rochelle" BOT active #441 "Ellis" BOT active #442 "Coach" BOT active #end

[GsiX]

God damn.. its l4d2..
:smile: :smile: :smile:
>.<"

Edut:
In your repeat timer, you didn't specify the client's iD.

RupCountdownTimer = CreateTimer(1.0, RupCountdownDelay_Timer, GetClientUserId(client), TIMER_REPEAT|...

But in your case.. there is no client index.. so you might want to do a "for" loop to lol to GsiX each client.

[eric0279]

CountDown is called if this steamid is true, no?

yes, sorry..

[GsiX]

Originally Posted by eric0279 no..?

Yes..

Edited 9 Times:
Jesus.. not sure if this is really a working plugin.. but hopefully i v fixed most of the error..

Spoiler

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <colors>

new Handle:RupCountdownTimer;
new readyDelay;

public OnClientPostAdminCheck(client)
{
    if(client > 0 && !IsFakeClient(client))
    {
        decl String:auth[64];
        GetClientAuthString(client, auth, sizeof(auth));        

        if((StrEqual(auth, "STEAM_1:1:12157180")))
        {
            CreateTimer(4.5,Timer_Own,GetClientUserId(client));    //This timer fine
            CreateTimer(6.5,Timer_Owned,GetClientUserId(client)); //This timer fine
            PrintToServer( "===== This Dude Filtred: %N ====", client ); // PrintToServer() so you know you kickin in.. 
                                                                        // instead of client chat is too early.
        }
    }
}
// thx CanadaRox from pause plugin  <<<=== What?
InitiateLiveCountdown( client )
{
    if (RupCountdownTimer == INVALID_HANDLE)
    {
        readyDelay = 4;
        CPrintToChatAll("InitiateLiveCountdown: %d", readyDelay); //ok
        RupCountdownTimer = CreateTimer(1.0, RupCountdownDelay_Timer, GetClientUserId( client ), TIMER_REPEAT|TIMER_FLAG_NO_MAPCHANGE); //not ok
        PrintToServer( "====== %N made a mistake here..!! =====", client );
    }
}
 //not ok
public Action:RupCountdownDelay_Timer(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0 && IsClientInGame( client ))
    {
        if (readyDelay <= 0) // avoid makin stupid mistake in your countdown.
        {
            CPrintToChatAll("{blue}Round is live{green}!");
        }
        else
        {
            CPrintToChatAll("{blue}Live in{green}: {blue}%d", readyDelay);
            readyDelay--;
            return Plugin_Continue;
        }
    }
    RupCountdownTimer  = INVALID_HANDLE;
    return Plugin_Stop;
}
 // ok
public Action:Timer_Own(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0 && IsClientInGame( client ))
    {
        InitiateLiveCountdown( client );
    }
}
 // ok
public Action:Timer_Owned(Handle:timer, any:userid)
{
    new client = GetClientOfUserId(userid);
    if (client > 0)
    {
        decl String:auth[64], String:buff[256];
        GetClientAuthString(client, auth, sizeof(auth));
        decl String:ip[64], String:name[64];
        GetClientName(client, name, sizeof(name));
        GetClientIP(client, ip, sizeof(ip));
        Format(buff, sizeof(buff), "%s, IP: %s, SteamID: %s", name, ip, auth);
        PrintToAll(buff);
        PrintToServer( "===== Timer Owned Passed ====" );
    }
}

PrintToAll(const String:text[])
{
    for (new x = 1; x <= MaxClients; x++) 
    { 
        if (IsClientInGame(x)) 
        { 
            PrintToChat(x, "F4F: %s", text);// why dont just PrintToChatAll().. no loop required here.
        } 
    } 
    PrintToServer( "===== If you dont see the chat print its because you not in game yet or what ever ====" );
} 


[eric0279]

It's not my counter where the thanks in the code, it comes from the plugin pause.sp.

You are the best, thanks, work!