[Gasior]

Hi guys,

Is there any easier way to save the below?

public SaveData(id) 
{  
    new szKey[ 40 ] , szData[ 3 ];
    new sBurner[ 40 ] , zBurner[ 3 ];
    new sCarbon[ 40 ], zCarbon[ 3 ];
    new sCrimson[ 40 ], zCrimson[ 3 ];
    new sGradient[ 40 ], zGradient[ 3 ];
    new sKrolewski[ 40 ], zKrolewski[ 3 ];
    new sKrwawy[ 40 ], zKrwawy[ 3 ];
     
    formatex( szKey , charsmax( szKey ) , "%s_glock" , g_szAuthID[ id ] ); 
    num_to_str( _:glock_model[ id ] , szData , charsmax( szData ) ); 
    
    formatex( sBurner , charsmax( sBurner ) , "%s_Burner" , g_szAuthID[ id ] ); 
    num_to_str( _:Burner1[ id ] , zBurner , charsmax( zBurner ) );
    
    formatex( sCarbon , charsmax( sCarbon ) , "%s_Carbon" , g_szAuthID[ id ] ); 
    num_to_str( _:Carbon1[ id ] , zCarbon , charsmax( zCarbon ) );
    
    formatex( sCrimson , charsmax( sCrimson ) , "%s_Crimson" , g_szAuthID[ id ] ); 
    num_to_str( _:Crimson1[ id ] , zCrimson , charsmax( zCrimson ) );
    
    formatex( sGradient , charsmax( sGradient ) , "%s_Gradient" , g_szAuthID[ id ] ); 
    num_to_str( _:Gradient1[ id ] , zGradient , charsmax( zGradient ) );
    
    formatex( sKrolewski , charsmax( sKrolewski ) , "%s_Krolewski" , g_szAuthID[ id ] ); 
    num_to_str( _:Krolewski1[ id ] , zKrolewski , charsmax( zKrolewski ) );
    
    formatex( sKrwawy , charsmax( sKrwawy ) , "%s_Krwawy" , g_szAuthID[ id ] ); 
    num_to_str( _:Krwawy1[ id ] , zKrwawy , charsmax( zKrwawy ) );

    nvault_set( zapis_vault , szKey , szData );
    nvault_set( zapis_vault , sBurner , zBurner ); 
    nvault_set( zapis_vault , sCarbon , zCarbon ); 
    nvault_set( zapis_vault , sCrimson , zCrimson ); 
    nvault_set( zapis_vault , sGradient , zGradient ); 
    nvault_set( zapis_vault , sKrolewski , zKrolewski );
    nvault_set( zapis_vault , sKrwawy , zKrwawy );
} 

public LoadData(id)  
{  
    new szKey[ 40 ] , szData[ 3 ] , iTS;
    new sBurner[ 40 ] , zBurner[ 3 ], kTS;
    new sCarbon[ 40 ], zCarbon[ 3 ], oTS;
    new sCrimson[ 40 ], zCrimson[ 3 ], tTS;
    new sKrolewski[ 40 ], zKrolewski[ 3 ], bTS;
    new sGradient[ 40 ], zGradient[ 3 ], nTS;
    new sKrwawy[ 40 ], zKrwawy[ 3 ], qTS;
     
    formatex( szKey , charsmax( szKey ) , "%s_glock" , g_szAuthID[ id ] );
    formatex( sGradient , charsmax( sGradient ) , "%s_Gradient" , g_szAuthID[ id ] );
    formatex( sKrolewski , charsmax( sKrolewski ) , "%s_Krolewski" , g_szAuthID[ id ] );
    formatex( sCrimson , charsmax( sCrimson ) , "%s_Crimson" , g_szAuthID[ id ] );
    formatex( sCarbon , charsmax( sCarbon ) , "%s_Carbon" , g_szAuthID[ id ] );
    formatex( sBurner , charsmax( sBurner ) , "%s_Burner" , g_szAuthID[ id ] );
    formatex( sKrwawy , charsmax( sKrwawy ) , "%s_Krwawy" , g_szAuthID[ id ] );
     
    if ( nvault_lookup( zapis_vault , szKey , szData , charsmax( szData ) , iTS ) )   
    { 
        glock_model[ id ] = Glocks:str_to_num( szData ); 
    }
    if ( nvault_lookup( zapis_vault , sBurner , zBurner , charsmax( zBurner ) , kTS ) )   
    { 
        Burner1[ id ] = str_to_num( zBurner ); 
    } 
    if ( nvault_lookup( zapis_vault , sCarbon , zCarbon , charsmax( zCarbon ) , oTS ) )   
    { 
        Carbon1[ id ] = str_to_num( zCarbon ); 
    } 
    if ( nvault_lookup( zapis_vault , sCrimson , zCrimson , charsmax( zCrimson ) , tTS ) )   
    { 
        Crimson1[ id ] = str_to_num( zCrimson ); 
    } 
    if ( nvault_lookup( zapis_vault , sGradient , zGradient , charsmax( zGradient ) , nTS ) )   
    { 
        Gradient1[ id ] = str_to_num( zGradient ); 
    } 
    if ( nvault_lookup( zapis_vault , sKrolewski , zKrolewski , charsmax( zKrolewski ) , bTS ) )   
    {
        Krolewski1[ id ] = str_to_num( zKrolewski ); 
    }
    if ( nvault_lookup( zapis_vault , sKrwawy , zKrwawy , charsmax( zKrwawy ) , qTS ) )   
    {
        Krwawy1[ id ] = str_to_num( zKrwawy ); 
    }
}

[HamletEagle]

Yeah, you can make the code shorter.

[Gasior]

How can I do that? I know it can be shortened but could you show me how to do it?

[Craxor]

use Nvault array.

I believe you already open some threads about this subject, you understand nothing from them?

[Bugsy]

Assign values for each player like this:

g_pdData[ id ][ Crimson ] = 343;
g_pdData[ id ][ Burner ] = 123;

PHP Code:


#include <amxmodx>
#include <nvault_array>

#define MAX_PLAYERS 32

enum PlayerData
{
    Glock,
    Burner,
    Carbon,
    Crimson,
    Gradient,
    Krolewski,
    Krwawy
}

new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];
new g_szAuthID[ MAX_PLAYERS + 1 ][ 34 ];
new bool:g_bIgnorePlayer[ MAX_PLAYERS + 1 ];
new zapis_vault;

public plugin_init() 
{
    zapis_vault = nvault_open( "zapis_vault" );
}

public plugin_end()
{
    nvault_close( zapis_vault );
}

public client_authorized( id )
{
    if ( !( g_bIgnorePlayer[ id ] = ( is_user_bot( id ) || is_user_hltv( id ) ) ) ) 
    {
        get_user_authid( id , g_szAuthID[ id ] , charsmax( g_szAuthID[] ) );
        LoadData( id );
    }
}

public client_disconnect( id )
{
    if ( !g_bIgnorePlayer[ id ] )
    {
        SaveData( id );
    }

    arrayset( g_pdData[ id ][ PlayerData:0 ] , 0 , sizeof( g_pdData[] ) );
}

public SaveData( id ) 
{  
    nvault_set_array( zapis_vault , g_szAuthID[ id ] , g_pdData[ id ][ PlayerData:0 ] , sizeof( g_pdData[] ) );
} 

public LoadData( id )  
{  
    nvault_get_array( zapis_vault , g_szAuthID[ id ] , g_pdData[ id ][ PlayerData:0 ] , sizeof( g_pdData[] ) );
} 


[Gasior]

Thanks Bugsy, that's making my life so much easier.