[TnTSCS]

*post removed.

Ask me if you want to see the code I had - don't want people thinking I'm jumping their work!!

[Despirator]

try this one

[Corneus]

Doesn't work, because admin can spec only 1 random player without possibility to change him.

[Dreamy]

final code, just ~120 lines and working smoothly on css (for me).. can sb test it on other games as well pls? =)

[Powerlord]

Is there any reason we're removing all our old code posts? I was under the impression that the forum mods frowned on that sort of thing.

[TnTSCS]

Powerlord, you're right. Here's a more complete code of the version I removed:

Still working on code for forcing specmode_firstperson though

code

PHP Code:

#pragma semicolon 1

#include <sourcemod>

#define SPECMODE_NONE                0
#define SPECMODE_FIRSTPERSON        4
#define SPECMODE_3RDPERSON            5
#define SPECMODE_FREELOOK            6

new bool:SpecAny[MAXPLAYERS+1] = {false, ...};
new Handle:ClientTimer[MAXPLAYERS+1] = {INVALID_HANDLE, ...};

new Handle:mp_forcecamera = INVALID_HANDLE;

public OnPluginStart()
{
    HookEvent("player_death", Event_Death);
    
    AddCommandListener(Command_SpecNext, "spec_next");
    AddCommandListener(Command_SpecPrev, "spec_prev");
    AddCommandListener(Command_SpecMode, "spec_mode");
    
    if ((mp_forcecamera = FindConVar("mp_forcecamera")) == INVALID_HANDLE)
    {
        SetFailState("Convar mp_forcecamera not found");
    }
}

public OnClientPostAdminCheck(client)
{
    if (IsFakeClient(client))
    {
        return;
    }
    if (CheckCommandAccess(client, "allow_all_spectate", ADMFLAG_GENERIC))
    {
        SpecAny[client] = true;
        SendConVarValue(client, mp_forcecamera, "0");
    }
    else
    {
        SpecAny[client] = false;
        SendConVarValue(client, mp_forcecamera, "1");
    }
}

public OnClientDisconnect(client)
{
    if (IsClientInGame(client))
    {
        if (!IsFakeClient(client))
        {
            ClearTimer(ClientTimer[client]);
            
            SpecAny[client] = false;
            SendConVarValue(client, mp_forcecamera, "0");
        }
    }
}

public Event_Death(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if(IsFakeClient(client))
    {
        return;
    }
    
    ClearTimer(ClientTimer[client]);
    
    ClientTimer[client] = CreateTimer(7.1, Timer_DiedSpec, client);
}

public Action:Timer_DiedSpec(Handle:timer, any:client)
{
    ClientTimer[client] = INVALID_HANDLE;
    
    FindNextSpec(client);
}

public Action:Command_SpecMode(client, const String:command[], argc) 
{
    if (client == 0 || IsFakeClient(client))
    {
        return Plugin_Handled;
    }
    
    PrintToChatAll("argc = %i", argc);
    
    new String:arg[2];
    arg[0] = '\0';
    
    GetCmdArg(1, arg, sizeof(arg));
    
    new mode = StringToInt(arg);
    
    if (mode == SPECMODE_3RDPERSON || mode == SPECMODE_FREELOOK)
    {
        PrintToChatAll("MODE is %i", mode);
        SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_NONE);
        PrintToChatAll("Set mode to NONE");
    }
    
    return Plugin_Continue;
}

public Action:Command_SpecNext(client, const String:command[], argc) 
{
    if(!SpecAny[client] && !IsFakeClient(client))
    {
        FindNextSpec(client);
        
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
}

public Action:Command_SpecPrev(client, const String:command[], argc) 
{
    if(!SpecAny[client] && !IsFakeClient(client))
    {
        FindPrevSpec(client);
        
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
}

public FindNextSpec(client)
{
    new client_team = GetClientTeam(client);
    
    new target = GetEntPropEnt(client, Prop_Send, "m_hObserverTarget");
    
    new bool:found = false;
    
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsValidEntity(i) && IsClientInGame(i) && IsPlayerAlive(i) && client_team == GetClientTeam(i) && i > target && client != target)
        {
            SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_FIRSTPERSON);
            SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", i);
            PrintToChat(client, "observermode is %i", GetEntPropEnt(client, Prop_Send, "m_iObserverMode"));
            found = true;
            return;
        }
    }
    
    if(!found)
    {
        new temp = MaxClients+1;
        
        for (new i = MaxClients; i >= 1; i--)
        {
            if (IsValidEntity(i) && IsClientInGame(i) && IsPlayerAlive(i) && client_team == GetClientTeam(i) && i < target && client != target)
            {
                if (i < temp)
                {
                    temp = i;
                }
            }
        }
        
        if(temp == MaxClients+1)
        {
            SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_NONE);
            SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", temp);
            
            return;
        }
        
        SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_FIRSTPERSON);
        SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", temp);
    }
}

public FindPrevSpec(client)
{
    new client_team = GetClientTeam(client);
    new target = GetEntPropEnt(client, Prop_Send, "m_hObserverTarget");
    
    new bool:found = false;
    
    for (new i = MaxClients; i >= 1; i--)
    {
        if (IsValidEntity(i) && IsClientInGame(i) && IsPlayerAlive(i) && client_team == GetClientTeam(i) && i < target && client != target)
        {
            SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_FIRSTPERSON);
            SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", i);
            found = true;
            return;
        }
    }
    
    if(!found)
    {
        new temp = 0;
        for (new i = 1; i <= MaxClients; i++)
        {
            if (IsValidEntity(i) && IsClientInGame(i) && IsPlayerAlive(i) && client_team == GetClientTeam(i) && i > target && client != target)
            {
                if(i > temp)
                {
                    temp = i;
                }
            }
        }
        
        if(temp == 0)
        {
            SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_NONE);
            SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", temp);
            
            return;
        }
        
        SetEntPropEnt(client, Prop_Send, "m_iObserverMode", SPECMODE_FIRSTPERSON);
        SetEntPropEnt(client, Prop_Send, "m_hObserverTarget", temp);
    }
}

stock ClearTimer(&Handle:timer)
{
    if(timer != INVALID_HANDLE)
    {
        KillTimer(timer);
        timer = INVALID_HANDLE;
    }
} 


[Dr!fter]

You can do this easily with a hook here is a quick example

Example

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <dhooks>

new Handle:hIsValidTarget;

public OnPluginStart()
{
    new Handle:temp = LoadGameConfigFile("allow-spec.games");
    if(!temp)
    {
        SetFailState("Why you no has gamedata?");
    }
    new offset = GameConfGetOffset(temp, "IsValidObserverTarget");
    hIsValidTarget = DHookCreate(offset, HookType_Entity, ReturnType_Bool, ThisPointer_CBaseEntity, IsValidTarget);
    DHookAddParam(hIsValidTarget, HookParamType_CBaseEntity);
    CloseHandle(temp);
}
public OnClientPutInServer(client)
{
    DHookEntity(hIsValidTarget, true, client, RemoveCB);
}
public MRESReturn:IsValidTarget(this, Handle:hReturn, Handle:hParams)
{
    new target = DHookGetParam(hParams, 1);
    if(target == -1 || this == -1 || !IsClientInGame(this) || !IsClientInGame(target) || !IsPlayerAlive(target) || IsPlayerAlive(this) || GetClientTeam(this) <= 1 || GetClientTeam(target) <= 1)
    {
        return MRES_Ignored;
    }
    else
    {
        //Allow them to spec this target
        //Add your checks here for admin
        DHookSetReturn(hReturn, true);
        return MRES_Override;
    }
}
public RemoveCB(hookid){} 


Gamedata

"Games"
{
	"cstrike"
	{
		"Offsets"
		{
			"IsValidObserverTarget"
			{
				"windows"	"371"
				"linux"		"372"
			}
		}
	}
}

The example requires DHooks

All the example does is even with mp_forcecamera 1 it still allows everybody to spec anybody (I was too lazy to add anything else to it). But if someone wants to use it they are free to use this method if they want. Note that I only provided the gamedata for cstrike. But if someone wants the offset for another game feel free to ask and ill try to get them.

[Dreamy]

haha really thought about taking your awesome extension (did it with sdkhooks b4 but hooking playerthink kinda felt wrong)..
+i didnt know how to get those offsets..

dammit its only in alpha, but I already love it

[Dr!fter]

Originally Posted by Dreamy haha really thought about taking your awesome extension (did it with sdkhooks b4 but hooking playerthink kinda felt wrong).. +i didnt know how to get those offsets.. dammit its only in alpha, but I already love it

http://wiki.alliedmods.net/Finding_Virtual_Offsets Thats a tutorial on how to get them.

Also, its only in pre alpha since I didnt test it fully (I didnt test all the possible combinations of params/returns which if something is wrong can cause a crash) and Im still adding param types/other things. But its safe to use (as long as you test the hook) and wont change much in terms of what is there already.

As for your pm for the offsets for TF2

Gamedata

"Games"
{
	"cstrike"
	{
		"Offsets"
		{
			"IsValidObserverTarget"
			{
				"windows"	"371"
				"linux"		"372"
			}
		}
	}
	"tf"
	{
		"Offsets"
		{
			"IsValidObserverTarget"
			{
				"windows"	"370"
				"linux"		"371"
			}
		}
	}
}

If it dosnt work let me know. Linux should be right, but windows might not.

Edit:
Also just realized you can get them from here http://www.sourcemodplugins.org/inde...=vtableoffsets Select the game and search for "IsValidObserverTarget"

[FudgePoly]

So should I wait for a DHooks-based plugin or does one of the above succeed? I already crashed my Arena server several times (my fault, obviously) by doing this so I'd rather have something at least semi-stable to test.