[MeliMeli]

Hello, can someone give me an example of how I can create a stock that selects random players without repeating them? For example, Player 1 cannot be Player 2, and if they are, the stock should find another player who is not Player 1. It would be useful to create an array and add the IDs of these players to that array. If any of them disconnect from the server, their ID should be removed from the array.

[EFFx]

Needs some testing.

PHP Code:

#include <amxmodx>

#define PLUGIN "A stock that selects random players without repeating them"
#define VERSION "1.0"
#define AUTHOR "author"

new bool:g_bAlreadySelected[MAX_PLAYERS + 1]

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /find", "getRandomPlayer")
}

public client_disconnected(id) g_bAlreadySelected[id] = false

public getRandomPlayer(id)
{
    new iPlayer = findRandomPlayer(1)
    log_amx("Debug: Random player selected: %n", iPlayer)
}

findRandomPlayer(iIncludeBots)
{
    new iPlayers[MAX_PLAYERS], iNum, iPlayersNotSelected[MAX_PLAYERS], iPlayersFound, iRandomPlayer
    get_players(iPlayers, iNum, iIncludeBots ? "h" : "ch")
    for(new i, iPlayer;i < iNum;i++)
    {
        if(!g_bAlreadySelected[(iPlayer = iPlayers[i])])
        {
            iPlayersNotSelected[iPlayersFound++] = iPlayer
        }
    }
    
    // At this point, all players must have been selected already
    // If so, select a random player to restart the cicle
    if(!iPlayersFound)
    {
        g_bAlreadySelected[(iRandomPlayer = iPlayers[random(iNum)])]
        resetAllPlayers(iIncludeBots)
        return iRandomPlayer
    }
    
    g_bAlreadySelected[(iRandomPlayer = iPlayersNotSelected[random(iPlayersFound)])] = true
    return iRandomPlayer
}

resetAllPlayers(iIncludeBots)
{
    new iPlayers[MAX_PLAYERS], iNum
    get_players(iPlayers, iNum, iIncludeBots ? "h" : "ch")
    for(new i;i < iNum;i++)
    {
        g_bAlreadySelected[i] = false
    }
} 


[fysiks]

I would probably use the functions provided by Bugsy here. Doing something like this:

PHP Code:

#include <amxmodx>

new const Version[] = "0.1";

//Set this to the absolute max random number that you will attempt to generate.
const MaxRandom = 32;

new AllNumbers[ ( MaxRandom >> 5 ) + 1 ];

public plugin_init()
{
    register_plugin( "Random Number No Dupes" , Version , "bugsy/fysiks" );
    register_concmd("randplayers", "cmdGetRandomPlayers", .info=" - <number of random players>")
}

public cmdGetRandomPlayers(id)
{
    new iPlayers[32], iPlayerCount, szName[32]
    get_players(iPlayers, iPlayerCount)

    new szArg[3], iCount
    read_argv(1, szArg, charsmax(szArg))
    iCount = min(str_to_num(szArg), iPlayerCount)
    
    PrepRandom(0 , iPlayerCount - 1);

    for( new i = 0 ; i < iCount ; i++ )
    {
        get_user_name(GetRandom(0, iPlayerCount - 1), szName, charsmax(szName))
        console_print(id, "Random player: %s", szName);
    }
}

// Source:  https://forums.alliedmods.net/showpost.php?p=2417667&postcount=7
PrepRandom( iRanMin , iRanMax )
{
    for ( new i = iRanMin ; i <= iRanMax ; i++ )
        AllNumbers[ i >> 5 ] |= ( 1 << i );
}

public GetRandom( iRanMin , iRanMax )
{
    static UsedNumbers[ ( MaxRandom >> 5 ) + 1 ];
    new iRandom , bool:bAllUsed=true;

    if ( iRanMax > MaxRandom )
        set_fail_state( "Must increase MaxRandom value: %d > %d" , iRanMax , MaxRandom );

    //Check if all numbers have already bee nused, if so this will reset the 'used' variable.
    for ( new i = 0 ; i < sizeof( UsedNumbers ) ; i++ )
    {
        if ( AllNumbers[ i ] && ( AllNumbers[ i ] != UsedNumbers[ i ] ) )
        {
            bAllUsed = false;
            break;
        }
    }

    //If all random numbers have already been used, reset variable so they can be re-used.
    if ( bAllUsed )
        arrayset( UsedNumbers , 0 , sizeof( UsedNumbers ) );

    //Find random number
    do
    {
        iRandom = random_num( iRanMin , iRanMax );
    }
    while ( ( UsedNumbers[ iRandom >> 5 ] & ( 1 << iRandom ) ) )

    //Set current random number as used
    UsedNumbers[ iRandom >> 5 ] |= ( 1 << iRandom );

    //Return random number
    return iRandom;
} 


I'm not able to test it but I think it's mostly there.