[MeliMeli]

People, can someone give me an example of how I can save something in nVault through a given value? I see a lot of using "i++" to save automatically but I would like to save it manually through certain values (if this is possible) example:

PHP Code:

if (g_M4A1_Black[id] & g_HasBlack[id])
    {
        formatex(amenu,charsmax(amenu),"\yM4A1 Black \r[Selected]") 
        menu_additem(menuz,amenu,"1")

       }
       
       if (g_M4A1_Rose[id] & g_HasRose[id])
    {
        formatex(amenu,charsmax(amenu),"\yM4A1 Rose \r[Selected]") 
        menu_additem(menuz,amenu,"2")

       } 


Where (g_bM4A1_Black[id]) & if (g_M4A1_Rose[id] is a number different value that will be saved in nvault, I'm doing it manually

I'm doing this because of a cost definition of each weapon. If the player buys a weapon, it is saved in the nvault and you do not have to buy it again if you have it.

[bigdaddy424]

you can combine it with bits if you ever heard of it. it also depends how many weapons you got.

[MeliMeli]

I would like an example please, I intend for 6 weapons.

[Bugsy]

Why do you need 2 variables, M4A1_Black and HasBlack?

Why not just use 1 variable and set the variable to true if the player has black m4a1?

[MeliMeli]

Because 1 is to save in nVault and the other is to identify if the player has it selected as the current model. If you have a better way to define this, please explain to me, have you even seen the code I sent you? I really need your help for an in-depth understanding in nvault (it's my first time using)

[Bugsy]

Take a look at this and see if you can apply this in your plugin. This supports up to 32 weapons - add others to the WeaponBits and Weapons enumerators as needed.

PHP Code:


#include <amxmodx>
#include <nvault_array>

enum WeaponBits (<<=1)
{
    wtBlack = 1,
    wtRose
}
enum Weapons
{
    WeaponBlack = 1,
    WeaponRose
}
enum PlayerData
{
    WeaponBits:PlayerWeapons,
    Weapons:CurrentWeapon
}

new g_szAuthID[ MAX_PLAYERS + 1 ][ 34 ];
new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];
new g_Vault;

#define AddWeapon(%1,%2)    g_pdData[%1][PlayerWeapons]|=%2    
#define RemoveWeapon(%1,%2)    g_pdData[%1][PlayerWeapons]&=~%2
    
public plugin_init() 
{
    g_Vault = nvault_open( "testVault" );
    
    register_clcmd( "say /buyblack" , "BuyBlack" );
    register_clcmd( "say /buyrose" , "BuyRose" );
    
    register_clcmd( "say /setblack" , "SetBlack" );
    register_clcmd( "say /setrose" , "SetRose" );
}

public plugin_end()
{
    nvault_close( g_Vault );
}

public BuyBlack( id )
{
    if ( g_pdData[ id ][ PlayerWeapons ] & wtBlack )
    {
        client_print( id , print_chat , "You already have Black" );
    }
    else
    {
        AddWeapon( id , wtBlack );
        client_print( id , print_chat , "Black has been given" );
    }
}

public BuyRose( id )
{
    if ( g_pdData[ id ][ PlayerWeapons ] & wtRose )
    {
        client_print( id , print_chat , "You already have Rose" );
    }
    else
    {
        AddWeapon( id , wtRose );
        client_print( id , print_chat , "Rose has been given" );
    }
}

public SetBlack( id )
{
    if ( g_pdData[ id ][ PlayerWeapons ] & wtBlack )
    {
        if ( g_pdData[ id ][ CurrentWeapon ] == WeaponBlack )
        {
            client_print( id , print_chat , "Black already set" );
        }
        else
        {
            client_print( id , print_chat , "Set to Black" );
            g_pdData[ id ][ CurrentWeapon ] = WeaponBlack;
        }
    }
    else
    {
        client_print( id , print_chat , "You do not have Black" );
    }
}

public SetRose( id )
{
    if ( g_pdData[ id ][ PlayerWeapons ] & wtRose )
    {
        if ( g_pdData[ id ][ CurrentWeapon ] == WeaponRose )
        {
            client_print( id , print_chat , "Rose already set" );
        }
        else
        {
            client_print( id , print_chat , "Set to Rose" );
            g_pdData[ id ][ CurrentWeapon ] = WeaponRose;
        }
    }
    else
    {
        client_print( id , print_chat , "You do not have Rose" );
    }
}

public client_authorized( id )
{
    new iTS;
    get_user_authid( id , g_szAuthID[ id ] , charsmax( g_szAuthID[] ) );
    nvault_get_array( g_Vault , g_szAuthID[ id ] , g_pdData[ id ][ PlayerData:0 ] , sizeof( g_pdData[] ) , iTS );
}

public client_disconnected( id )
{
    nvault_set_array( g_Vault , g_szAuthID[ id ] , g_pdData[ id ][ PlayerData:0 ] , sizeof( g_pdData[] ) );
} 


[MeliMeli]

So if I were to add new models I would have to edit:

PHP Code:

enum WeaponBits (<<=2)
{
    wtBlack = 1,
    wtRose = 2,
    wtDefault
}

enum Weapons
{
    WeaponBlack = 1,
    WeaponRose = 2,
    WeaponDefault
}

// What about this from here?
#define AddWeapon(%1,%2)    g_pdData[%1][PlayerWeapons]|=%2           // ?
#define RemoveWeapon(%1,%2)    g_pdData[%1][PlayerWeapons]&=~%2  // ? 


If I'm wrong, can you kindly tell me the right way?

[Bugsy]

I personally would do this, if you need a none/default option.

PHP Code:

enum WeaponBits (<<=1) //don't ever change this regardless of # of types
{
    wtDefault,
    wtBlack,
    wtRose
}

enum Weapons
{
    WeaponDefault,
    WeaponBlack,
    WeaponRose
} 


Add/Remove macros are how you set a player as having or not having a given weapon..

[MeliMeli]

Works perfectly, I managed to implement in my plugin, I have only a few questions, is it possible to implement for other weapons in the same plugin? could this cause some error?

[Bugsy]

You can do up to 31 weapons without messing anything up, just don't randomly change things and expect it to work, like you did above, for example: enum WeaponBits (<<=2)

To add more, this is all you need to do:

PHP Code:

enum WeaponBits (<<=1) //don't ever change this regardless of # of types
{
    wtDefault,
    wtBlack,
    wtRose,
    wt4,
    wt5,
    wt6,
    wt7,
    wt8,
    wt9,
    wt10
}

enum Weapons
{
    WeaponDefault,
    WeaponBlack,
    WeaponRose,
    Weapon4,
    Weapon5,
    Weapon6,
    Weapon7,
    Weapon8,
    Weapon9,
    Weapon10
} 


You can also do another array if you want to use printable names for each

PHP Code:

new const WeaponNames[ Weapons ][] = 
{
    "Default",
    "Black",
    "Rose",
    "1",
    "2",
    "3",
    "4",
    "5",
    "6",
    "7",
    "8",
    "9",
    "10"
};