[FreezerPT]

Hello, I would like to know if this plugin or something that has the same effect exists! That is to say, I am talking about the grenade trail, but what I would like to know would be, so that when you throw the grenade, flash, or smoke, only the player who sent the grenade would see the trail, so as not to create great confusion when Send the grenades

[FreezerPT]

Hello, I would like to know if this plugin or something that has the same effect exists! That is to say, I am talking about the grenade trail, but what I would like to know would be, so that when you throw the grenade, flash, or smoke, only the player who sent the grenade would see the trail, so as not to create great confusion when Send the grenades

[Dr Zayd]

PHP Code:

/*
    Grenade Trail 1.0
    Author: Jim

    Cvars:
    grenade_tr: default 2
    0 - None
    1 - Random Colors
    2 - Nade Specific
    3 - Team Specific

    grenade_he "255000000" set the trail color of Hegrenade
    grenade_fb "000000255" set the trail color of Flashbang
    grenade_sg "000255000" set the trail color of Smokegrenade
*/

#include <amxmodx>
#include <csx>

#define PLUGIN "Grenade Trail"
#define VERSION "1.0"
#define AUTHOR "Jim"

new g_cvar_tr
new g_cvar_he
new g_cvar_fb
new g_cvar_sg
new g_trail

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    g_cvar_tr = register_cvar("grenade_tr", "2")
    g_cvar_he = register_cvar("grenade_he", "255000000")
    g_cvar_fb = register_cvar("grenade_fb", "000000255")
    g_cvar_sg = register_cvar("grenade_sg", "000255000")
}

public plugin_precache()
{
    g_trail = precache_model("sprites/smoke.spr")
}

public grenade_throw(id)
{
    new gtm = get_pcvar_num(g_cvar_tr)
    if(!gtm) return
    new r, g, b
    switch(gtm)
    {
        case 1:
        {
            r = random(256)
            g = random(256)
            b = random(256)
        }
        case 2:
        {
            new nade, color[10]
            switch(id)
            {
                case CSW_HEGRENADE:    nade = g_cvar_he
                case CSW_FLASHBANG:    nade = g_cvar_fb
                case CSW_SMOKEGRENADE:    nade = g_cvar_sg
            }
            get_pcvar_string(nade, color, 9)
            new c = str_to_num(color)
            r = c / 1000000
            c %= 1000000 
            g = c / 1000
            b = c % 1000
        }
        case 3:
        {
            switch(get_user_team(id))
            {
                case 1: r = 255
                case 2: b = 255
            }
        }
    }
    message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
    write_byte(TE_BEAMFOLLOW)
    write_short(id)
    write_short(g_trail)
    write_byte(10)
    write_byte(5)
    write_byte(r)
    write_byte(g)
    write_byte(b)
    write_byte(192)
    message_end()
} 


try this X)) idk if its will work

[edon1337]

Originally Posted by Dr Zayd PHP Code: /*     Grenade Trail 1.0     Author: Jim     Cvars:     grenade_tr: default 2     0 - None     1 - Random Colors     2 - Nade Specific     3 - Team Specific     grenade_he "255000000" set the trail color of Hegrenade     grenade_fb "000000255" set the trail color of Flashbang     grenade_sg "000255000" set the trail color of Smokegrenade */ #include <amxmodx> #include <csx> #define PLUGIN "Grenade Trail" #define VERSION "1.0" #define AUTHOR "Jim" new g_cvar_tr new g_cvar_he new g_cvar_fb new g_cvar_sg new g_trail public plugin_init() {     register_plugin(PLUGIN, VERSION, AUTHOR)     g_cvar_tr = register_cvar("grenade_tr", "2")     g_cvar_he = register_cvar("grenade_he", "255000000")     g_cvar_fb = register_cvar("grenade_fb", "000000255")     g_cvar_sg = register_cvar("grenade_sg", "000255000") } public plugin_precache() {     g_trail = precache_model("sprites/smoke.spr") } public grenade_throw(id) {     new gtm = get_pcvar_num(g_cvar_tr)     if(!gtm) return     new r, g, b     switch(gtm)     {         case 1:         {             r = random(256)             g = random(256)             b = random(256)         }         case 2:         {             new nade, color[10]             switch(id)             {                 case CSW_HEGRENADE:    nade = g_cvar_he                 case CSW_FLASHBANG:    nade = g_cvar_fb                 case CSW_SMOKEGRENADE:    nade = g_cvar_sg             }             get_pcvar_string(nade, color, 9)             new c = str_to_num(color)             r = c / 1000000             c %= 1000000              g = c / 1000             b = c % 1000         }         case 3:         {             switch(get_user_team(id))             {                 case 1: r = 255                 case 2: b = 255             }         }     }     message_begin(MSG_BROADCAST, SVC_TEMPENTITY)     write_byte(TE_BEAMFOLLOW)     write_short(id)     write_short(g_trail)     write_byte(10)     write_byte(5)     write_byte(r)     write_byte(g)     write_byte(b)     write_byte(192)     message_end() }  try this X)) idk if its will work

MSG_BROADCAST will send it to everyone.

[Depresie]

Use MSG_ONE_UNRELIABLE with the index of the grenade's owner

[OciXCrom]

The code above will add a trail to the player, not the grenade + won't work due to using switch(id).

PHP Code:

/*
    Grenade Trail 1.0
    Author: Jim

    Cvars:
    grenade_tr: default 2
    0 - None
    1 - Random Colors
    2 - Nade Specific
    3 - Team Specific

    grenade_he "255000000" set the trail color of Hegrenade
    grenade_fb "000000255" set the trail color of Flashbang
    grenade_sg "000255000" set the trail color of Smokegrenade
*/

#include <amxmodx>
#include <csx>

#define PLUGIN "Grenade Trail"
#define VERSION "1.0"
#define AUTHOR "Jim"

new g_cvar_tr
new g_cvar_he
new g_cvar_fb
new g_cvar_sg
new g_trail

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    g_cvar_tr = register_cvar("grenade_tr", "2")
    g_cvar_he = register_cvar("grenade_he", "255000000")
    g_cvar_fb = register_cvar("grenade_fb", "000000255")
    g_cvar_sg = register_cvar("grenade_sg", "000255000")
}

public plugin_precache()
{
    g_trail = precache_model("sprites/smoke.spr")
}

public grenade_throw(id, iGrenade, iWeapon)
{
    new gtm = get_pcvar_num(g_cvar_tr)
    if(!gtm) return
    new r, g, b
    switch(gtm)
    {
        case 1:
        {
            r = random(256)
            g = random(256)
            b = random(256)
        }
        case 2:
        {
            new nade, color[10]
            switch(iWeapon)
            {
                case CSW_HEGRENADE:    nade = g_cvar_he
                case CSW_FLASHBANG:    nade = g_cvar_fb
                case CSW_SMOKEGRENADE:    nade = g_cvar_sg
            }
            get_pcvar_string(nade, color, 9)
            new c = str_to_num(color)
            r = c / 1000000
            c %= 1000000 
            g = c / 1000
            b = c % 1000
        }
        case 3:
        {
            switch(get_user_team(id))
            {
                case 1: r = 255
                case 2: b = 255
            }
        }
    }
    message_begin(MSG_ONE_UNRELIABLE, SVC_TEMPENTITY, _, id)
    write_byte(TE_BEAMFOLLOW)
    write_short(iGrenade)
    write_short(g_trail)
    write_byte(10)
    write_byte(5)
    write_byte(r)
    write_byte(g)
    write_byte(b)
    write_byte(192)
    message_end()
}