[kar731]

I have the root flag, and yet this command shows up as an unknown command.

PHP Code:

#define WHITE "\x01"
#define YELLOW "\x09"
#define GREY "\x08"
#define RED "\x02"
#define PINK "\x03"
#define BLUE "\x0B"
#define LBLUE "\x0A"
#define GREEN "\x04"

public void OnPluginStart()
{
    RegAdminCmd("sm_adminchat", Command_adminchat, ADMFLAG_GENERIC);
}

public Action Command_adminchat(client, args) {
    if (args <= 0) {
        ReplyToCommand(client, "[SM] Usage: sm_adminchat <message>");
        return Plugin_Handled;
    }
    
    char name[32];
    GetClientName(client, name, sizeof(name));
    
    for (int i = 0; i <= GetMaxClients(); i++) {
        if (GetAdminFlag(GetUserAdmin(i), ADMFLAG_GENERIC))
            PrintToChat(i, " %s[%sADMIN%s] %s%s%s: %s ", GREEN, RED, GREEN, BLUE, name, WHITE, args);
        //[ADMIN] Kar: sup dawgs
    }
    return Plugin_Handled;
} 


[8guawong]

are you doing sm_adminchat in the console cuz it'll show that
also add IsClientInGame(i) to your loop

[Darkness_]

When looping through clients use:

PHP Code:

for (int i = 1; i <= MaxClients; i++) 


and then check to make sure that the client is in game before doing anything else.

PHP Code:

if(!IsClientInGame(i)) continue; 


Edit: The args parameter is an integer. If you really are just trying to print out the number of arguments in your PrintToChat() then you should format wih %i instead of %s. If that is not what you intended then look into GetCmdArg();

[kar731]

 
] sm_adminchat sdfsdfsdf
Unknown command: sm_adminchat

Yes I am....

[kar731]

Originally Posted by Darkness_ When looping through clients use: PHP Code: for (int i = 1; i <= MaxClients; i++)  and then check to make sure that the client is in game before doing anything else. PHP Code: if(!IsClientInGame(i)) continue;

I did that, but it's still not showing as a command. And yes the plugin is loaded.

[8guawong]

Originally Posted by kar731 ] sm_adminchat sdfsdfsdf Unknown command: sm_adminchat Yes I am....

this is normal I THINK
you just need to focus on getting the code inside Command_adminchat to run

[xerox8521]

What game are you using ? also you can remove the GetClientName part and use %N for the players name requires client index as param.

[Grey83]

You need something like this:

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#define START    "\x01\x0B\x04"
#define WHITE    "\x01"
#define YELLOW    "\x09"
#define GREY    "\x08"
#define RED    "\x02"
#define PINK    "\x03"
#define BLUE    "\x0B"
#define LBLUE    "\x0A"
#define GREEN    "\x04"

bool bIsAdmin[MAXPLAYERS + 1];
bool bLateLoad;

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max) {
    bLateLoad = late;
    return APLRes_Success; 
}

public void OnPluginStart() {
    RegAdminCmd("sm_adminchat", Command_adminchat, ADMFLAG_GENERIC);
    if (bLateLoad) {
        LookupClients();
        bLateLoad = false;
    }
}

void LookupClients() {
    for (int i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i)) OnClientPostAdminCheck(i);
    }
}

public void OnClientPostAdminCheck(int client) {
    if (1 <= client <= MaxClients && !IsFakeClient(client)) bIsAdmin[client] = CheckCommandAccess(client, "sm_admin", ADMFLAG_GENERIC);
}

public Action Command_adminchat(int client, int args) {
    if (args <= 0) {
        ReplyToCommand(client, "[SM] Usage: sm_adminchat <message>");
        return Plugin_Handled;
    }

    char cArg[PLATFORM_MAX_PATH];
    GetCmdArgString(cArg, sizeof(cArg));

    for (int i = 1; i <= MaxClients; i++) {
        if(!IsClientInGame(i) || !bIsAdmin[i]) continue; 
        PrintToChat(i, "%s[%sADMIN%s] %s%N%s: %s", START, RED, GREEN, BLUE, client, WHITE, cArg);    //[ADMIN] Kar: sup dawgs
    }
    return Plugin_Handled;
}