[Arkshine]

Then you do something wrong.

[Rirre]

Well do you see anything wrong here then?

server console:

Parsing functions stated.
	Parsing file "InstallGameRules" started
		Return type "CHalfLifeMultiplayer *" validated
		Searching for name "InstallGameRules_Fv"... FOUND
	Parsing file "InstallGameRules" ended
Parsing functions ended.

configs/orpheu/memory/CGameRulesOffsets:

[
    //...
    {
        "name"        : "m_flRoundCount",
        "type"        : "long",
        "memoryType"  : "data",
        "identifiers" : 
        [
            {
                "os"    : "windows",
                "mod"   : "cstrike",
                "value" : 56
            },
            {
                "os"    : "linux",
                "mod"   : "cstrike",
                "value" : 48
            }
        ]
    },
    {
        "name"        : "m_iRoundTimeSecs",
        "type"        : "int",
        "memoryType"  : "data",
        "identifiers" : 
        [
            {
                "os"    : "windows",
                "mod"   : "cstrike",
                "value" : 64
            },
            {
                "os"    : "linux",
                "mod"   : "cstrike",
                "value" : 52
            }
        ]
    },
    //...
]

#include <amxmodx>
#include <orpheu>
#include <orpheu_memory>

#define PLUGIN  "Fix RoundTimer"
#define AUTHOR  "Rirre/Arkshine"
#define VERSION "1.1"

enum GameRulesMembers 
{ 
    m_iRoundTimeSecs, 
    m_flRoundCount 
};

new const GameRulesMI[ GameRulesMembers ][] = 
{ 
    "m_iRoundTimeSecs", 
    "m_flRoundCount" 
};
    
new g_pGameRules;
new g_c4timer, mp_c4timer;

#define set_mp_pdata(%1,%2)  ( OrpheuMemorySetAtAddress( g_pGameRules, GameRulesMI[ %1 ], 1, %2 ) )
#define get_mp_pdata(%1)     ( OrpheuMemoryGetAtAddress( g_pGameRules, GameRulesMI[ %1 ] ) )

public plugin_precache() OrpheuRegisterHook( OrpheuGetFunction( "InstallGameRules" ), "OnInstallGameRules", OrpheuHookPost );

public OnInstallGameRules() g_pGameRules = OrpheuGetReturn();

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_logevent("PlantedBomb", 3, "2=Planted_The_Bomb");

    mp_c4timer = get_cvar_pointer("mp_c4timer");
}

public plugin_cfg() g_c4timer = get_pcvar_num(mp_c4timer);

public PlantedBomb() setRoundTime( g_c4timer );

setRoundTime( const newTime )
{
    set_mp_pdata( m_iRoundTimeSecs, newTime );
    set_mp_pdata( m_flRoundCount, get_gametime() );
    
    static msgIndexRoundTime;
    
    if( msgIndexRoundTime || ( msgIndexRoundTime = get_user_msgid( "RoundTime" ) ) )
    {
        message_begin( MSG_ALL, msgIndexRoundTime );
        write_short( newTime );
        message_end();
    }
}

[WaLkMaN]

With ReAPI:

#include <amxmodx>
#include <reapi>

new const PluginName   [] = "Set Round Time";
new const PluginVersion[] = "1.0";
new const PluginAuthor [] = "Arkshine";

const YourRoundTimeValue = 5 * 60; // 5 min in seconds.

public plugin_init()
{
    register_plugin( PluginName, PluginVersion, PluginAuthor );

    register_clcmd( "say /resettime", "ClientCommand_ResetRoundTime" );
}

public ClientCommand_ResetRoundTime( const client )
{
    setRoundTime( YourRoundTimeValue );
    return PLUGIN_HANDLED;
}

setRoundTime( const newTime )
{
    set_member_game( m_iRoundTimeSecs, newTime );
    set_member_game( m_fRoundStartTime, get_gametime() ); // deprecated name m_fRoundCount in ReGameDLL_CS
    
    static msgIndexRoundTime;
    
    if( msgIndexRoundTime || ( msgIndexRoundTime = get_user_msgid( "RoundTime" ) ) )
    {
        message_begin( MSG_ALL, msgIndexRoundTime );
        write_short( newTime );
        message_end();
    }
}