[Bobbls]

I'm attempting to get the next keyframe in a rope entity (aka the location of the keyframe_rope) but i'm not entirely sure how to go about it. I can't simply get the location of keyframe_rope as there is often more than one rope in a map. Sadly I have no choice but to use rope entities, as i'm attempting to emulate the behavior of a closed source plugin.

I thought I could just read the entity properties but there doesn't seem to be any available. The netprop dumps don't seem to log anything and I can't find any posts about it here on alliedmods. I'm rather lost on how to proceed. I thought about hooking the creation of the move_rope but i'm not entirely sure where to go from there either.

EDIT: This is in TF2, if it matters.

[d1rTyS]

Maybe you'll find what you are looking for if you dump all datamaps.

Sorry that i can't help you in detail but maybe these are of any interest for you

- m_iNextLinkName (Save|Key)(4 Bytes) - NextKey
- m_hStartPoint (Save)(4 Bytes)
- m_hEndPoint (Save)(4 Bytes)
- m_iStartAttachment (Save)(2 Bytes)
- m_iEndAttachment (Save)(2 Bytes)

[Bobbls]

Originally Posted by d1rTyS Maybe you'll find what you are looking for if you dump all datamaps. Sorry that i can't help you in detail but maybe these are of any interest for you - m_iNextLinkName (Save|Key)(4 Bytes) - NextKey - m_hStartPoint (Save)(4 Bytes) - m_hEndPoint (Save)(4 Bytes) - m_iStartAttachment (Save)(2 Bytes) - m_iEndAttachment (Save)(2 Bytes)

It seems neither handles for start or end point actually return a valid reference, I always seem to get -1 using GetEntPropEnt

After looking at the source sdk for the move_rope stuff, it looks like they use these handles to get the start and end point (https://github.com/ValveSoftware/sou.../rope.cpp#L296)

Perhaps it's an issue with my code?
I've tried both

index = GetEntPropEnt(entity, Prop_Send, "m_hEndPoint")

and

EntRefToEntIndex(index);

though i've never dabbled in this end of sourcemod. I also tried using Prop_Data with the same results, it seems to always return -1.

[Neuro Toxin]

Have you tried prop_data?

[Bobbls]

Originally Posted by Neuro Toxin Have you tried prop_data?

Said that at the end of my last post, but yeah I had tried prop_data with no change in results.

[Neuro Toxin]

What about the other netprops.

Surely next link name contains an entity name.

Have you also tried the two attachment ones?

[Bobbls]

Originally Posted by Neuro Toxin What about the other netprops. Surely next link name contains an entity name. Have you also tried the two attachment ones?

The next link name should return a string for m_iName, but the issue then becomes finding the names of every single keyframe_rope and some how re-associating them with move_rope, which seems impractical.
The two attachments looked like the same issue as before, returning 0 or -1.

[nosoop]

Originally Posted by Bobbls I also tried using Prop_Data with the same results, it seems to always return -1.

You're checking things too early (SpawnPost still appears to be too early to check). A quick hack of getting it a frame after it spawns seems to return stuff that isn't -1.

I've had a similar issue when I worked on the Revive Health modifications. Just using RequestFrame here since I'm not sure if ropes can even think.

#include <sdkhooks>

public void OnEntityCreated(int entity, const char[] name) {
    if (StrEqual(name, "move_rope")) {
        SDKHook(entity, SDKHook_SpawnPost, OnMoveRopeSpawnPost);
    }
}

public void OnMoveRopeSpawnPost(int entity) {
    RequestFrame(PrintRopeStuff, entity);
}

public void PrintRopeStuff(int rope) {
    int hStartPoint = GetEntPropEnt(rope, Prop_Data, "m_hStartPoint");
    int hEndPoint = GetEntPropEnt(rope, Prop_Data, "m_hEndPoint");
    
    char sStartOrigin[64], sEndOrigin[64];
    GetEntOriginString(hStartPoint, sStartOrigin, sizeof(sStartOrigin));
    GetEntOriginString(hEndPoint, sEndOrigin, sizeof(sEndOrigin));
    
    PrintToServer("rope -- start: %d (%s), end: %d (%s)", hStartPoint, sStartOrigin, hEndPoint, sEndOrigin);
}

void GetEntOriginString(int entity, char[] buffer, int maxlen) {
    float vecOrigin[3];
    GetEntPropVector(entity, Prop_Data, "m_vecOrigin", vecOrigin);
    
    Format(buffer, maxlen, "%.2f %.2f %.2f", vecOrigin[0], vecOrigin[1], vecOrigin[2]);
}

There might be a better hook to call that doesn't need callbacks, but I'm too lazy to check.

(I know you already got the news from our mutual staff comms, just wanted to post it if anyone else has a similar issue later on.)