[tobi187]

How could i set the defuse time with kit, to lets say 4 Seconds instead of 6?

ive only found something for AMX Mod http://forums.alliedmods.net/showthr...ht=defuse+time

Is it possible with sourcemod?

[Bacardi]

Ok...
- Hook event when player begin defuse c4.
- Check player have he defusing kits.
- Change entity planted c4 defusing end game time.

*edit
there is pRED* - quickdefuse plugins so you can peek plugin source code

[tobi187]

PHP Code:

public OnPluginStart(){
    HookEvent("bomb_begindefuse", Event_Defuse, EventHookMode_Post);
}
 
 

public Event_Defuse(Handle:event, const String:name[], bool:dontBroadcast)
{
    new clientId = GetEventInt(event, "userid");
    new client = GetClientOfUserId(clientId);
    new bool:kit = GetEventBool(event, "haskit");
    new bombent = FindEntityByClassname(-1,"planted_c4"); 
    if(kit) SetEntPropFloat(bombent, Prop_Send, "m_flDefuseCountDown", 3.0);
    if(!kit) SetEntPropFloat(bombent, Prop_Send, "m_flDefuseCountDown", 5.0);
} 


Thats what i have and it doesnt work for me...

[Bacardi]

Originally Posted by tobi187 Thats what i have and it doesnt work for me...

Yeah, problem is that game event is coming little early than you can change c4 defusing end time.
So you need delay it just little.

I shorted also player defusing bar

PHP Code:

#include <sdktools>

public OnPluginStart()
{
    HookEventEx("bomb_begindefuse", begindefuse);
}

public begindefuse(Handle:event, const String:name[], bool:dontBroadcast)
{
    new userid = GetEventInt(event, "userid");
    CreateTimer(0.0, timer_delay, userid); // Need delay

}

public Action:timer_delay(Handle:timer, any:userid)
{

    new client = GetClientOfUserId(userid);

    if(client != 0)
    {
        if(IsPlayerAlive(client))
        {
            new Float:defuse_time;

            if(GetEntProp(client, Prop_Send, "m_bHasDefuser"))
            {
                defuse_time = 3.0;
            }
            else
            {
                defuse_time = 5.0;
            }
            new c4 = FindEntityByClassname(MaxClients+1, "planted_c4");
            if(c4 != -1)
            {
                SetEntPropFloat(c4, Prop_Send, "m_flDefuseCountDown", GetGameTime()+defuse_time);
                SetEntProp(client, Prop_Send, "m_iProgressBarDuration", RoundFloat(defuse_time));
            }
        }
    }
} 


[tobi187]

Thanks a lot, im gonna test it!

[tobi187]

Looks like its working.
Thanks a lot