[Rineek]

Hi

I'm looking for Fall Damage HP Restore for CSGO. When you take damage from world (ground) you get back(you get restored) a certain amount of damage

[Nomad_pl]

I have absolutely no clue if this will work but try it out, the sm_falldamage_restore cvar determines the health to restore.

[Bacardi]

Here quick sample.
- Red screen fade when fall damage.
- If player survive after fall, player health restore half of fall damage.

PHP Code:



#include <sdkhooks>
#include <sdktools>
#include <cstrike>

public void OnPluginStart()
{
    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsClientInGame(i)) OnClientPutInServer(i);
    }
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamageAlivePost, OnTakeDamageAlivePost);
}

public void OnTakeDamageAlivePost(int victim, int attacker, int inflictor, float damage, int damagetype)
{
    if(attacker != 0 || attacker != inflictor || damagetype != DMG_FALL) return;

    if(GetClientHealth(victim) <= 0) return;

    DataPack pack;
    CreateDataTimer(0.5, reg, pack, TIMER_FLAG_NO_MAPCHANGE);
    pack.WriteCell(GetClientUserId(victim));
    pack.WriteFloat(damage);
    pack.Reset();



    int duration = 255;
    int hold_time = 128;
    int flags = 0x0001;
    int clr[4];
    clr[0] = 255;
    clr[1] = 0;
    clr[2] = 0;
    clr[3] = 255;



    Protobuf fade = view_as<Protobuf>(StartMessageOne("Fade", victim));
    fade.SetInt("duration", duration);
    fade.SetInt("hold_time", hold_time);
    fade.SetInt("flags", flags);
    fade.SetColor("clr", clr);
    EndMessage();

    return;
}

public Action reg(Handle timer, DataPack pack)
{
    int victim = GetClientOfUserId(pack.ReadCell());

    if(victim == 0 || !IsClientInGame(victim) || !IsPlayerAlive(victim)) return Plugin_Stop;

    int heal = RoundFloat(pack.ReadFloat());
    SetEntityHealth(victim, GetClientHealth(victim) + heal/2);
    return Plugin_Continue;
} 


[Nomad_pl]

Also, I was being stupid in my last one and forgot to add the original health onto the restore ammount, meaning right now it just sets you to 15 HP no matter what... I would go with bacardis solution, or I can edit mine if you want me to...

[Rineek]

Bacardi, Nomad_pl Thank you

[Ilusion9]

PHP Code:

sv_falldamage_scale 0.5 


You can control the fall damage with this cvar, if you don't need at all the restore thing.
0 = no fall damage, 1 = normal fall damage.