[Electroo]

Bonjours,
Dans le sujet de Aooka j'ai vu le code du plugin qui bloque tous les /cmd !

PHP Code:

#include < amxmodx >


new g_szMsg[ 192 ];

public plugin_init( )
{
    register_plugin( "Block /cmd" , "1.0" , "Aooka" );
    
    register_clcmd( "say" , "HookSay" );
    register_clcmd( "say_team" , "HookSay" );
}

public HookSay( const id )
{
    static message[ 3 ];
    
    if( read_args( message , charsmax( message ) ) )
    {
        new c = message[ message[ 0 ] == '"' ];
        static const charactersToCheck[] = { '/', '.', '@' };
        
        for( new i = 0; i < sizeof charactersToCheck; i++ )
        {
            if( charactersToCheck[ i ] == c )
            {
                return PLUGIN_HANDLED;
            }
        }
    }

    return PLUGIN_CONTINUE;
} 


Mais moi je veux modifié un peu pour que le plugin bloque juste un ou plusieurs /cmd et non pas tous ! ^^
Quelqu'un peut m'aider svp ? !

Merci !

[Devil259]

#include < amxmodx >

new const szCommandsToBlock[ ][ ] = 
{
     "/admin",
     "/respawn",
     "/etc"
}

public plugin_init( )
{
     register_clcmd( "say", "ClientCommand_Say" );
     register_clcmd( "say_team", "ClientCommand_Say" );
}

public ClientCommand_Say( id )
{
     new szArgs[ 64 ];
     read_args( szArgs, charsmax( szArgs ) );

     for( new i = 0; i < sizeof( szCommandsToBlock ); i++ )
     {
          if( equal( szArgs, szCommandsToBlock[ i ] ) )
          {
               return PLUGIN_HANDLED;
          }
     }

     return PLUGIN_CONTINUE;
}

Y'a sûrement mieux, mais ça devrait fonctionner.

[ConnorMcLeod]

Quand on connait exactement les commandes, on déclare celles-ci !!!

PHP Code:

#include < amxmodx >

public plugin_init()
{
    new szSayCommandsToBlock[][] = 
    {
        "/admin",
        "/respawn",
        "/etc"
    }
    new szBlockCmdCallBack[] = "ClCmd_BlockCommand"
    new szCommandToRegister[32]
    for(new i; i<sizeof(szSayCommandsToBlock); i++)
    {
        formatex(szCommandToRegister, charsmax(szCommandToRegister), "say %s", szSayCommandsToBlock[i])
        register_clcmd(szCommandToRegister, szBlockCmdCallBack)

        formatex(szCommandToRegister, charsmax(szCommandToRegister), "say_team %s", szSayCommandsToBlock[i])
        register_clcmd(szCommandToRegister, szBlockCmdCallBack)        
    }
}

public ClCmd_BlockCommand( id )
{
    return PLUGIN_HANDLED;
} 


[Electroo]

Le plugin (running...)
Mais ça ne bloque toujours pas les cmd !
J'ai tester /admin ça marche

Une erreur dans le code ?

[Arkshine]

Mais ça ne bloque toujours pas les cmd ! J'ai tester /admin ça marche

:facepalm: Tu dis que ça bloque pas, et après que ça bloque bien /admin...

Faudrait prendre la peine de t'EXPRIMER CLAIREMENT. De quelles commandes parles-tu ? Ce n'est qu'un exemple le plugin hein.

[Electroo]

Bah j'ai vu l'exemple et je voulais le tester :

new szSayCommandsToBlock[][] = { "/admin", "/respawn", "/etc"

J'ai fais : /admin
et j'ai vu : Admin connecté : Electro

C'est pas bloquer ^^

[Arkshine]

Ca veut dire qu'il y a un autre plugin avec cette commande et que le plugin qui bloque les commandes est déclaré après cet autre plugin. Déplaçe le plugin qui bloque en tête de liste et ça marchera.

[Electroo]

Bien compris Arkshine !
Merci !

[ConnorMcLeod]

Mais bon le mieux c'est de désactiver directement dans le plugin concerné au lieu d'utiliser des plugins supplémentaires, c'est vraiment idiot.
C'est pas amx_super le plugin par hasard ? Dans ce cas les commandes doivent pouvoir se bloquer.

[Electroo]

Le plugin marche bien c'est bon , Merci !

C'est pas amx_super le plugin par hasard ?

Non ^^