[Aooka]

Voilà j'ai fais un petit code rapidement qui enlève toute commande disponible sur le serveur :

#include < amxmodx >


new g_szMsg[ 192 ];

public plugin_init( )
{
    register_plugin( "Block /cmd" , "1.0" , "Aooka" );
    
    register_clcmd( "say" , "HookSay" );
    register_clcmd( "say_team" , "HookSay" );
}

public HookSay( const id )
{
    read_args( g_szMsg , charsmax( g_szMsg ) );
    remove_quotes( g_szMsg );
    
    if( g_szMsg[ 0 ] == '/'
    || g_szMsg[ 0 ] == '.'
    || g_szMsg[ 0 ] == '@'
    || g_szMsg[ 0 ] == ' ' )
    {
        return 2;
    }

    return 0;
}

Je voulais juste savoir comment le trouviez-vous. Des choses à modifier à refaire ... etc.

A +

[Sherazaa]

A mon avis ce code est bon.
Mais pourquoi tu fais cela :

if( g_szMsg[ 0 ] == '/'
    || g_szMsg[ 0 ] == '.'
    || g_szMsg[ 0 ] == '@'
    || g_szMsg[ 0 ] == ' ' )

et pourquoi tu met ' ' et pas " " ?

[Aooka]

A mon avis ce code est bon. Mais pourquoi tu fais cela : Code: if( g_szMsg[ 0 ] == '/' || g_szMsg[ 0 ] == '.' || g_szMsg[ 0 ] == '@' || g_szMsg[ 0 ] == ' ' )

Bah je fais sa pour que sa soit plus lisible. Je m'y retrouve mieux. C'est un méthode pour coder. Si sa ne t'aide pas ne le fait pas. Si tu trouve sa mieux je te conseils de le faire

et pourquoi tu met ' ' et pas " " ?

Lorsque tu n'a qu'un seul caractère ( a , b , c , ; , i , ! , / , etc. ) tu peux mettre ce type de guillemet. Sa reste facultatif bien sûr. Tu peux aussi bien faire :

g_szMsg[ 0 ] == '/'

et sa :

g_szMsg[ 0 ] == "/"

Par contre impossible de faire ceci :

g_szMsg[ 0 ] == 'Salut les filles'

Dans ce cas là. Obligation de faire ceci :

g_szMsg[ 0 ] == "Salut les filles"

Ps: D'ailleurs là je fais comment si je fias une chaîne de caractère ? Je ne peux pas laisser g_szMsg[ 0 ]... Que mettre ? [ 15 ] ?

Voilà j'espère que tu aura compris :p

[Arkshine]

Pas sûr de comprendre l'intérêt de faire ça, mais tu peux améliorer les choses comme ceci :

public HookSay( const id )
{
    static message[ 3 ];
    
    if( read_args( message , charsmax( message ) ) )
    {
        new c = message[ message[ 0 ] == '"' ];
        static const charactersToCheck[] = { '/', '.', '@' };
        
        for( new i = 0; i < sizeof charactersToCheck; i++ )
        {
            if( charactersToCheck[ i ] == c )
            {
                return PLUGIN_HANDLED;
            }
        }
    }

    return PLUGIN_CONTINUE;
}

- Même si ça ne change rien, y'a pas vraiment d'intérêt à ce que g_szMsg soit global à tout le plugin.
- Mettre la taille de g_szMsg à 192 n'est pas très logique si tu veux vérifier que les premiers caractères.
- Pas besoin donc remote_quotes, une native en moins, c'est toujours ça de pris.
- La taille de 3 pour g_szMsg est suffisant, car le message peut commencer avec un " et sachant que tu veux vérifier que le premier caractère, la taille est donc de 2 max + 1 pour le EOS.
- Réindexer un array est à éviter quand tu peux. Dans ce cas là, tu pouvais soit faire un switch soit faire ce que j'ai fais, un tableau constant avec les caractères à vérifier et boucler. Et pour éviter de réindexer, je sauvegarde le premier caractère dans 'c'.

[ConnorMcLeod]

Le mec on lui dit d'utiliser les return standarts il se borne comme un gros con à utiliser des nombres.
Et en + il les utilise mal.

Jverrais bien ça pour parfaire le code d'arkshine :

PHP Code:

public HookSay( const id )
{
    static message[ 3 ];
    
    if( read_args( message , charsmax( message ) ) )
    {
        if( !isalnum( message[ message[ 0 ] == '"' ] ) )
        {
            return PLUGIN_HANDLED;
        }
    }

    return PLUGIN_CONTINUE;
} 


[Aooka]

Juste pour savoir Arkshine je ne comprends pas bien cette ligne :

new c = message[ message[ 0 ] == '"' ]; // pourquoi tu met comme premier caractère " ? 

Après je comrpends se que tu veux faire mais cette ligne ...

Merci à vous deux.

Ps Connor: Hum pour le PLUGIN_CONTINUE il est égale à 0 donc je l'ai bien utiliser et le return 2 = HANDLED_MAIN et j'aurais mis sa aussi donc même avec ces trucs je me serais trompé.

[ConnorMcLeod]

C'est juste une astuce pour ne pas utiliser remove_quotes

Si le 1er caractère est " on va vérifier le 2ème, sinon on vérifie le 1er.

On aurait pu mettre :

message[ message[0] == '"' ? 1 : 0 ]

Mais la valeur boléenne de message[0] == '"' a le même effet est est plus efficiente.

[Electroo]

Ce plugin bloque tous les /cmd ?
Et pour bloquer juste une /cmd (/rs par exemple) , je change ça ? :

static const charactersToCheck[] = { '/', '.', '@' };

à celui la ?

static const charactersToCheck[] = {"/rs"};

[Arkshine]

Non. Ce n'était pas ce que tu voulais au départ... Pour vérifier par commande exacte, le code doit être revu. Par exemple faire un Trie.

[Electroo]

Non. Ce n'était pas ce que tu voulais au départ... Pour vérifier par commande exacte, le code doit être revu.

Ah ok !
Tu peux me donner le code pour bloquer juste une cmd ou plusieurs , mais pas tous ?
Merci