[Devil259]

Ton sound c'est un mp3 ou un wav ?

[P0u$$!n]

C'est un .wav

[P0u$$!n]

Re UP, il ne me manque plus que le son

[ConnorMcLeod]

Le code est vraiment dégueu, jvais faire une version debug si tu veux

[P0u$$!n]

ok c'est gentil =)

[ConnorMcLeod]

Essaie déjà ça, c'est écrit autrement :

Edit
Faudra surement remonter amx_headsplash_min_velocity à 300 ou 400 ou 500 (sachant que 250 c'est la vitesse d'un mec qui court).
J'utilise la formule qui détermine les dégâts qu'un joueur prend en tombant, et dans cette formule, l'équivalent de cette cvar est à 500.
/ Edit

PHP Code:

#include <amxmodx>
#include <fakemeta_stocks>
#include <hamsandwich>
#include <xs>

// plugin
#include <chatcolor>

// rage module
// #include <colorchat>

new const HEADSPLASH_PAIN_SOUND[] = "misc/own.wav"

#define VERSION "0.1.5"
#define PLUGIN "Head Splash"

new g_iMaxPlayers
#define IsPlayer(%0)    ( 1 <= %0 <= g_iMaxPlayers )

#define        m_LastHitGroup    75
#define        m_iTeam                114
#define        m_flFallVelocity        251

#define BLOOD_COLOR_RED 247

new g_pCvarMinFallVelocity
new mp_friendlyfire
new g_sModelIndexBloodSpray, g_sModelIndexBloodDrop

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    register_dictionary_colored("headsplash.txt")

    g_iMaxPlayers = get_maxplayers()
    mp_friendlyfire = get_cvar_pointer("mp_friendlyfire")
    g_pCvarMinFallVelocity = register_cvar("amx_headsplash_min_velocity", "100")
    g_sModelIndexBloodSpray = EF_PrecacheModel("sprites/bloodspray.spr") // initial blood
    g_sModelIndexBloodDrop = EF_PrecacheModel("sprites/blood.spr") // splattered blood 

    RegisterHam(Ham_Touch, "player", "OnCBasePlayer_Touch")
}

public plugin_precache()
{
    precache_sound( HEADSPLASH_PAIN_SOUND )
}

public OnCBasePlayer_Touch( id, iOther )
{
    if( IsPlayer( iOther ) && pev(iOther, pev_groundentity) == id )
    {
        static bool:TK
        TK = get_pdata_int(id,m_iTeam) == get_pdata_int(iOther,m_iTeam )
        if( TK && !get_pcvar_num(mp_friendlyfire) )
        {
            return HAM_IGNORED
        }
        new Float:flFallVelocity = get_pdata_float(iOther, m_flFallVelocity)
        new Float:flMaxSafeFallSpeed = get_pcvar_float(g_pCvarMinFallVelocity)
        if( flFallVelocity > flMaxSafeFallSpeed )
        {
            flFallVelocity -= flMaxSafeFallSpeed
            new Float:flDamage = flFallVelocity * 100.0 / ( 980.0 - flMaxSafeFallSpeed )
            if( TK )
            {
                flDamage *= 0.35
            }

            new Float:origin[3]
            pev(id, pev_origin, origin)
            origin[2] += pev(id, pev_flags) & FL_DUCKING ? 12.0 : 17.0
            new Float:vecAttackerOrigin[3], Float:direction[3]
            pev(iOther, pev_origin, vecAttackerOrigin)
            xs_vec_sub(vecAttackerOrigin, origin, direction)
            xs_vec_normalize(direction, direction)

            UTIL_BloodDrips(origin, BLOOD_COLOR_RED, floatround(flDamage, floatround_ceil) )

            new ptr = create_tr2()
            engfunc(EngFunc_TraceLine, vecAttackerOrigin, origin, DONT_IGNORE_MONSTERS, iOther, ptr)
            ExecuteHam(Ham_TraceBleed, id, flDamage, direction, ptr, DMG_BULLET)
            free_tr2(ptr)

            set_pdata_int(id, m_LastHitGroup, HIT_HEAD)
            static iszFeet = 0, iszInfoTarget = 0
            if( !iszFeet )
            {
                iszFeet = engfunc(EngFunc_AllocString, "feet")
            }
            if( !iszInfoTarget )
            {
                iszInfoTarget = engfunc(EngFunc_AllocString, "info_target")
            }
            new ent = engfunc(EngFunc_CreateNamedEntity, iszInfoTarget)
            set_pev_string(ent, pev_classname, iszInfoTarget)
            set_pev(ent, pev_owner, iOther)
            ExecuteHam(Ham_TakeDamage, id, ent, iOther, flDamage, DMG_FALL)
            emit_sound(id, CHAN_ITEM, HEADSPLASH_PAIN_SOUND, VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
            if( !is_user_alive(id) )
            {
                new szKillerName[32], szAttackerName[32]
                get_user_name(iOther, szKillerName, charsmax(szKillerName))
                get_user_name(id, szAttackerName, charsmax(szAttackerName))
                client_print_color(0, DontChange, "%L", LANG_PLAYER, "HEADSPLASH_KILL_MSG", szKillerName, szAttackerName)
            }
            return HAM_HANDLED
        }
    }
    return HAM_IGNORED
}

UTIL_BloodDrips( Float:origin[3], color, amount )
{
    amount *= 2;
    if( amount < 16 )
    {
        amount = 16
    }
    else if( amount > 255 )
    {
        amount = 255
    }

    MessageBegin( MSG_PVS, SVC_TEMPENTITY, origin )
    {
        write_byte( TE_BLOODSPRITE )
        EF_WriteCoord( origin[0] )                                // pos
        EF_WriteCoord( origin[1] )
        EF_WriteCoord( origin[2] )
        write_short( g_sModelIndexBloodSpray )                // initial sprite model
        write_short( g_sModelIndexBloodDrop )                // droplet sprite models
        write_byte( color )                                // color index into host_basepal
        write_byte( amount )        // size
    }
    message_end()
}

MessageBegin(dest, msg_type, const Float:vecOrigin[3] = {0.0,0.0,0.0}, player=0)
{
    engfunc(EngFunc_MessageBegin, dest, msg_type, vecOrigin, player)
} 


[P0u$$!n]

Je viens de tester ton plugin et il marche nikel avec la cvar réglée à "200".

Le petit problème c'est que quand on tue le mec, sa met en arme de kill l'arme qu'il tient dans sa main et non la tête de mort de l'ancien plugin. Du coup les autres personnes du serveur ne savent que la personne c'est fait tuer avec les pieds.

Sinon tout marche nikel il ne manque plus que le son quand il le tue et les phrases en couleurs comme sur celui de Devil

[ConnorMcLeod]

On progresse alors, le code est beaucoup mieux que celui qu'avait utilisé devil.
J'ai changé un truc tu devrais voir la tête de mort normalement et dans la console ça devrait écrire "feet" (pieds) à la place du nom de l'arme.

Je verrai pour le son et la phrase, as-tu installé mon plugin ou mon module colorchat ? (si oui lequel ?).

[P0u$$!n]

Ok je vais tester ça, sinon j'ai ton module colorchat.inc avec ton plugin colorchat.amxx normalement si c'est bien de ça que tu parle.

EDIT: Je vien de tester le plugin mais il a fait crash le serveur dés que je suis tombé sur sa tête.

Voici les logs:

L 07/15/2012 - 21:54:45: Info (map "awp_rooftops") (file "addons/amxmodx/logs/error_20120715.log") L 07/15/2012 - 21:54:45: [AMXX] Plugin file open error (plugin "Anty_Kzh.am") L 07/15/2012 - 21:54:45: Function "topten_show" was not found L 07/15/2012 - 21:54:45: [AMXX] Displaying debug trace (plugin "prokreedz.amxx") L 07/15/2012 - 21:54:45: [AMXX] Run time error 19: function not found L 07/15/2012 - 21:54:45: [AMXX] [0] prokreedz.sma::plugin_init (line 135) L 07/15/2012 - 21:56:53: Start of error session.

Je pense pas que ça est un rapport mais je les met quand même.

[ConnorMcLeod]

J'avais fait une grosse erreur, ceci dit les erreurs que tu montres n'ont absolument rien à voir.
Code édité.