[CrawDad]

Okay
This is a great idea. But may I suggest that EVERY players name IP be "SAVED" in a DAILY FILE named by date. This way the IPs can be grabbed later as necessary for punishment.

Even better their IP & ID at the same time...

EX: IPFILE 100506

Thanx,

Kilt/CrawDad

[`666]

cs* logs do that already

[Kabuto]

Hey, can you make without admin. but i did deleted ADMIN_KICK, error

[`666]

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

/*Description: This plugin enables an admin to find out a player's ip by 
	typing in amx_ip <name>. The ip prints in console and in the regular game.*/

public plugin_init() 
{ 
    register_plugin("Show IP","1.0","$uicid3"); 
    register_concmd("amx_ip","ShowIP",ADMIN_USER,"< player , @TEAM , *>"); 
} 

public ShowIP(id , level , cid) 
{ 
    if(!cmd_access(id , level , cid , 2)) 
        return PLUGIN_HANDLED; 

    new Arg[36]; 
    new szIP[46] , szName[36]; 
    new Players[32] , pnum; 
    read_argv(1, Arg , 35); 

    if(Arg[0] == '@') 
    { 
        switch( Arg[1] ) 
        { 
            case 'C' , 'c': 
            { 
                console_print(id , "[AMXX] IP print out for CT team"); 
                get_players(Players , pnum , "ce" , "CT"); 
                for(new i = 0; i < pnum; i++) 
                { 
                    get_user_ip(Players[i] , szIP , 45 , 1); 
                    get_user_name(Players[i] , szName , 35);
                    console_print(id , "%d) %s     - %s", (i + 1) , szName , szIP); 
                } 
            } 
            case 'T' , 't': 
            { 
                console_print(id , "[AMXX] IP print out for T team"); 
                get_players(Players , pnum , "ce" , "TERRORIST"); 
                for(new i = 0; i < pnum; i++) 
                { 
                    get_user_ip(Players[i] , szIP , 45 , 1); 
                    get_user_name(Players[i] , szName , 35); 
                    console_print(id , "%d) %s     - %s", (i + 1) , szName , szIP); 
                } 
            } 
        } 
    } 
    else if(equal( Arg , "*")) 
    { 
        get_players( Players , pnum , "c"); 
        console_print(id , "[AMXX] IP print out for all players"); 
        for(new i=0; i < pnum; i++) 
        { 
            get_user_ip(Players[i],szIP , 45 , 1); 
            get_user_name(Players[i] , szName , 35); 
            console_print(id , "%d) %s     - %s", (i + 1), szName , szIP); 
        } 
    } 
    else 
    { 
        new Target = cmd_target(id , Arg , 10); 
        if(!is_user_connected(Target)) 
            return PLUGIN_HANDLED; 
        get_user_ip( Target , szIP , 45 , 1); 
        get_user_name( Target , szName , 35); 
        console_print( id , "[AMXX] %s's IP address : %s", szName , szIP); 
    } 
    return PLUGIN_HANDLED; 
}  
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/

[zerbbi]

i would suggest making a plugin that will write player IP in scoreboard (tab) somewhere under name or etc. And admin IP would be hidden. Please make this

[fysiks]

Originally Posted by zerbbi i would suggest making a plugin that will write player IP in scoreboard (tab) somewhere under name or etc. And admin IP would be hidden. Please make this

Not possible unless you change the players name to their IP.

[happy_2012]

How about this general plugin? amx_data instead of amx_ip?

PHP Code:

/*
    AMX Mod X script.

    This plugin is free software; you can redistribute it and/or modify it
    under the terms of the GNU General Public License as published by the
    Free Software Foundation; either version 2 of the License, or (at
    your option) any later version. 
    
    This plugin is distributed in the hope that it will be useful, but
    WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
    General Public License for more details.
    
    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the Free Software Foundation,
    Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
*/

/* Version Settings */
#define PLUGIN_VERSION "1.0"

/* Includes */
#include < amxmodx >
#include < amxmisc >

#pragma semicolon 1

/* Variables */
new g_MaxPlayers;

/* Plugin Forwards */
public plugin_init()
{
    register_plugin("AMXX Data", PLUGIN_VERSION, "funkyfresh95");
    
    // Register the command
    register_concmd("amx_data", "ConCmd_ShowData", ADMIN_BAN, "< name | @team | * > - Show player Name, IP, and SteamID");
    
    // Get the MAX players count can be held in the servers
    g_MaxPlayers = get_maxplayers();
}

/* Client Commands */
public ConCmd_ShowData(PlayerID, iLevel, iCid)
{
    // No access?
    if( !cmd_access(PlayerID, iLevel, iCid, 2) )
        return PLUGIN_HANDLED;
    
    // String arrays to hold player data
    new szArgument[36], szPlayerIP[16], szPlayerName[32], szAuthID[36], iLoop;
    read_argv(1, szArgument, charsmax(szArgument));
    
    if( szArgument[0] == '@' )
    {
        switch(szArgument[1])
        {
            // Counter-Terrorists
            case 'C', 'c':
            {
                console_print(PlayerID, "[AMXX] Server will generate the data for the COUNTER-TERRORISTS team");
                for(iLoop = 0; iLoop <= g_MaxPlayers; iLoop++)
                {
                    // Not connected?
                    if( !is_user_connected(iLoop) )
                        continue;
                    
                    // Not counter-terrorist?
                    if( get_user_team(iLoop) != 2 )
                        continue;
                    
                    // Get data
                    get_user_name(iLoop, szPlayerName, charsmax(szPlayerName));
                    get_user_ip(iLoop, szPlayerIP, charsmax(szPlayerIP));
                    get_user_authid(iLoop, szAuthID, charsmax(szAuthID));
                    
                    console_print(PlayerID, "%d. Name: %s - IP: %s - SteamID: %s", (iLoop + 1), szPlayerName, szPlayerIP, szAuthID);
                }
            }
            
            // Terrorists
            case 'T', 't':
            {
                console_print(PlayerID, "[AMXX] Server will generate the data for the TERRORISTS team");
                for(iLoop = 0; iLoop <= g_MaxPlayers; iLoop++)
                {
                    // Not connected?
                    if( !is_user_connected(iLoop) )
                        continue;
                    
                    // Not terrorist?
                    if( get_user_team(iLoop) != 1 )
                        continue;
                    
                    // Get data
                    get_user_name(iLoop, szPlayerName, charsmax(szPlayerName));
                    get_user_ip(iLoop, szPlayerIP, charsmax(szPlayerIP));
                    get_user_authid(iLoop, szAuthID, charsmax(szAuthID));
                    
                    console_print(PlayerID, "%d. Name: %s - IP: %s - SteamID: %s", (iLoop + 1), szPlayerName, szPlayerIP, szAuthID);
                }
            }
        }
    }
    else if( equal(szArgument, "*") )
    {
        console_print(PlayerID, "[AMXX] Server will generate the data for the ALL players");
        for(iLoop = 0; iLoop <= g_MaxPlayers; iLoop++)
        {
            // Not connected?
            if( !is_user_connected(iLoop) )
                continue;
            
            // Get data
            get_user_name(iLoop, szPlayerName, charsmax(szPlayerName));
            get_user_ip(iLoop, szPlayerIP, charsmax(szPlayerIP));
            get_user_authid(iLoop, szAuthID, charsmax(szAuthID));
            
            console_print(PlayerID, "%d. Name: %s - IP: %s - SteamID: %s", (iLoop + 1), szPlayerName, szPlayerIP, szAuthID);
        }
    }
    else
    {
        new TargetID = cmd_target(PlayerID, szArgument, 2);
        
        // Invalid target
        if( !TargetID )
        {
            console_print(PlayerID, "(!) Invalid target id (%d)", TargetID);
            return PLUGIN_HANDLED;            
        }
        
        // Get data
        get_user_name(TargetID, szPlayerName, charsmax(szPlayerName));
        get_user_ip(TargetID, szPlayerIP, charsmax(szPlayerIP));
        get_user_authid(TargetID, szAuthID, charsmax(szAuthID));
        
        console_print(PlayerID, "Name: %s - IP: %s - SteamID: %s", szPlayerName, szPlayerIP, szAuthID);
    }
    
    // Get admin data
    new szAdminName[32], szAdminAuthID[36];
    get_user_name(PlayerID, szAdminName, charsmax(szAdminName));
    get_user_authid(PlayerID, szAdminAuthID, charsmax(szAdminAuthID));
    
    // Log data to the server for some security reasons!
    log_amx("Admin %s (SteamID: %s) Used the AMXX Data Command.", szAdminName, szAdminAuthID);
    
    return PLUGIN_HANDLED;
} 


[maxd]

Hello. Can anybody modify this amx_ip plugin (#16) so that all player list shows by inputting only amx_ip command without giving "*" wildcard? All other functionality can remain the same.
Edit: I assume that desired result can be achieved by modifying line 53. No idea what to do with it. Simply deleting asterix symbol there does not work.

[ViBE]

i don't know where can i suggest this, but showing IP's would be good with amx_who for example. it can be usefull for admins.

[fysiks]

Originally Posted by ViBE i don't know where can i suggest this, but showing IP's would be good with amx_who for example. it can be usefull for admins.

If you are wanting to change functionality of AMX Mod X, you should create a bug report here. Choose "Enhancement" for the severity.