[claudiuhks]

Hello, my game server is actually running a plug-in which allows the Admins to spectate the enemies, but I also want the Admins to be able to switch between First-Person, Third-Person (optional) and Free-Look modes if they wish.

Is it possible? I've searched over the Internet, but couldn't find any results.
Thanks!

Oh, I underline that an Admin can switch between these modes while SPEC. While T/ CT, it's not possible.

[BraveFox]

You can make a plugin that allowed only to admins to join spec team and then it will be with third person,first person...
If you wan't I can make 1 for you
EDIT:
I think you should change this mp_forcecamera convar to 0

[claudiuhks]

Originally Posted by BraveFox You can make a plugin that allowed only to admins to join spec team and then it will be with third person,first person... If you wan't I can make 1 for you EDIT: I think you should change this mp_forcecamera convar to 0

I want the Admins to be able to Free-Look while T/ CT (dead). They can only Free-Look while SPEC, at the moment.

[BraveFox]

Originally Posted by claudiuhks I want the Admins to be able to Free-Look while T/ CT (dead). They can only Free-Look while SPEC, at the moment.

oh.
You can take the ttt - spec menu plugin and edit that only admins can do /spm

[claudiuhks]

Originally Posted by BraveFox oh. You can take the ttt - spec menu plugin and edit that only admins can do /spm

Thank you so much. I will post the script soon, so others can use it and mark the thread as "Solved".

PHP Code:

#include <sourcemod>
#include <cstrike>

public Plugin myinfo =
{
    name = "specmode",
    author = "Hattrick HKS",
    description = "Admin Spectator Mode",
    version = "2.0",
    url = "http://hattrick.go.ro/"
};

enum SpecMode:
{
    SpecMode_None = 0,

    SpecMode_1ST_Person = 4,
    SpecMode_3RD_Person,

    SpecMode_Free_Look
};

public void OnPluginStart()
{
    RegConsoleCmd("spec_mode", OnSpecMode);
}

public Action OnSpecMode(int iId, int iArgs)
{
    static int iTeam = CS_TEAM_NONE;
    static int iTarget = INVALID_ENT_REFERENCE;

    static SpecMode pMode = SpecMode_None;

    if (iId >= 1 && \
        iId <= MaxClients && \
        IsClientInGame(iId) && \
        !IsPlayerAlive(iId) && \
        !IsFakeClient(iId) && \
        !IsClientSourceTV(iId) && \
        IsClientObserver(iId) && \
        CheckCommandAccess(iId, "sm_ban", ADMFLAG_BAN) && \
        ((iTeam = GetClientTeam(iId)) == CS_TEAM_T || iTeam == CS_TEAM_CT) && \
        (pMode = view_as<SpecMode>(GetEntProp(iId, Prop_Send, "m_iObserverMode"))) != SpecMode_None && \
        (iTarget = GetEntPropEnt(iId, Prop_Send, "m_hObserverTarget")) != INVALID_ENT_REFERENCE && \
        iTarget >= 1 && \
        iTarget <= MaxClients && \
        IsClientInGame(iTarget) && \
        IsPlayerAlive(iTarget))
    {
        switch (pMode)
        {
            case SpecMode_1ST_Person:
            {
                SetEntProp(iId, Prop_Send, "m_iObserverMode", view_as<int>(SpecMode_3RD_Person));
            }

            case SpecMode_3RD_Person:
            {
                SetEntProp(iId, Prop_Send, "m_iObserverMode", view_as<int>(SpecMode_Free_Look));
            }

            case SpecMode_Free_Look:
            {
                SetEntProp(iId, Prop_Send, "m_iObserverMode", view_as<int>(SpecMode_1ST_Person));
            }
        }

        return Plugin_Stop;
    }

    return Plugin_Continue;
}