[DarthMan]

Hello. I am trying to retrive the distance to floor.
Can anyone help me a bit here?
Thanks !

PHP Code:

bool TraceRayNoPlayers(const int iEnt, const int iMask, any iData)
{
    if(iEnt == iData || IsPlayer(iEnt))
        return false;
    
    return true;
}

float GetDistanceToFloor(const int iID)
{
    float fStart[3], fEnd[3];
    bool bDucking;
    
    GetEntPropVector(iID, Prop_Send, "m_vecOrigin", fStart);
    
    bDucking = !!(GetEntityFlags(iID) & FL_DUCKING);
    
    if(bDucking)
        fStart[2] += 18.00;
    
    fEnd[0] = fStart[0];
    fEnd[1] = fStart[1];
    fEnd[2] = fStart[2] - 8192.0;
    
    Handle hTrace = TR_TraceRayFilterEx(fStart, fEnd, MASK_PLAYERSOLID, RayType_EndPoint, TraceRayNoPlayers, iID);
    
    if(TR_DidHit())
    {
        float fDistance = TR_GetFraction(hTrace);
        
        CloseHandle(hTrace);
        
        fDistance *= 8192.0;
        
        return fDistance;
    }
    
    CloseHandle(hTrace);
    
    return -1.0;
} 


[backwards]

PHP Code:

float GetDistanceToFloor(const int iID)
{
    float fStart[3], fEnd[3];
    //bool bDucking;
    
    GetEntPropVector(iID, Prop_Send, "m_vecOrigin", fStart);
    
    //bDucking = !!(GetEntityFlags(iID) & FL_DUCKING);
    
    //why? ducking wont change the base pos, unless the pos is the eye position...
    //if(bDucking)
    //    fStart[2] += 18.00;
    
    fEnd[0] = fStart[0];
    fEnd[1] = fStart[1];
    fEnd[2] = fStart[2] - 8192.0;
    
    Handle hTrace = TR_TraceRayFilterEx(fStart, fEnd, MASK_PLAYERSOLID, RayType_EndPoint, TraceRayNoPlayers, iID);
    
    if(TR_DidHit())
    {
        float fEndPos[3];
        TR_GetEndPosition(fEndPos, hTrace);
        float fDistance = GetVectorDistance(fStart, fEndPos, false);
        
        CloseHandle(hTrace);
        
        return fDistance;
    }
    
    CloseHandle(hTrace);
    
    return -1.0;
} 


[DarthMan]

Originally Posted by 1337norway PHP Code: float GetDistanceToFloor(const int iID) {     float fStart[3], fEnd[3];     //bool bDucking;          GetEntPropVector(iID, Prop_Send, "m_vecOrigin", fStart);          //bDucking = !!(GetEntityFlags(iID) & FL_DUCKING);          //why? ducking wont change the base pos, unless the pos is the eye position...     //if(bDucking)     //    fStart[2] += 18.00;          fEnd[0] = fStart[0];     fEnd[1] = fStart[1];     fEnd[2] = fStart[2] - 8192.0;          Handle hTrace = TR_TraceRayFilterEx(fStart, fEnd, MASK_PLAYERSOLID, RayType_EndPoint, TraceRayNoPlayers, iID);          if(TR_DidHit())     {         float fEndPos[3];         TR_GetEndPosition(fEndPos, hTrace);         float fDistance = GetVectorDistance(fStart, fEndPos, false);                  CloseHandle(hTrace);                  return fDistance;     }          CloseHandle(hTrace);          return -1.0; }

Thanks, I thought that ducking would make a difference but you are right, origin doesn't change if player is ducking.

[DarthMan]

Originally Posted by 1337norway PHP Code: float GetDistanceToFloor(const int iID) {     float fStart[3], fEnd[3];     //bool bDucking;          GetEntPropVector(iID, Prop_Send, "m_vecOrigin", fStart);          //bDucking = !!(GetEntityFlags(iID) & FL_DUCKING);          //why? ducking wont change the base pos, unless the pos is the eye position...     //if(bDucking)     //    fStart[2] += 18.00;          fEnd[0] = fStart[0];     fEnd[1] = fStart[1];     fEnd[2] = fStart[2] - 8192.0;          Handle hTrace = TR_TraceRayFilterEx(fStart, fEnd, MASK_PLAYERSOLID, RayType_EndPoint, TraceRayNoPlayers, iID);          if(TR_DidHit())     {         float fEndPos[3];         TR_GetEndPosition(fEndPos, hTrace);         float fDistance = GetVectorDistance(fStart, fEndPos, false);                  CloseHandle(hTrace);                  return fDistance;     }          CloseHandle(hTrace);          return -1.0; }

I tested and it doesn't seem to work, I did a print to server before returning fDistance and it didn't print anything in the console. Before I tried some other way using Trace too and it printed but the values were so high, smth like 800 or whatever.

[backwards]

I made this to test out the function and it appears to be working fine on my end. Post some of your code where you call the function and print it.

PHP Code:

#include <sourcemod>
#include <sdktools>

bool:IsValidClient(client, bool:bAllowBots = true)
{
    if(!(1 <= client <= MaxClients) || !IsClientConnected(client) || !IsClientInGame(client) || (IsFakeClient(client) && !bAllowBots))
        return false;

    return true;
}

public bool:TraceRayNoPlayers(entity, mask, any:data)
{
    if(entity == data || (entity >= 1 && entity <= MaxClients))
        return false;

    return true;
}

float GetDistanceToFloor(const int iID) 
{ 
    float fStart[3], fEnd[3]; 
     
    GetEntPropVector(iID, Prop_Send, "m_vecOrigin", fStart); 
   
    fEnd[0] = fStart[0]; 
    fEnd[1] = fStart[1]; 
    fEnd[2] = fStart[2] - 8192.0; 
     
    Handle hTrace = TR_TraceRayFilterEx(fStart, fEnd, MASK_PLAYERSOLID, RayType_EndPoint, TraceRayNoPlayers, iID); 
     
    if(TR_DidHit()) 
    { 
        float fEndPos[3]; 
        TR_GetEndPosition(fEndPos, hTrace); 
        float fDistance = GetVectorDistance(fStart, fEndPos, false); 
         
        CloseHandle(hTrace); 
         
        return fDistance; 
    } 
     
    CloseHandle(hTrace); 
     
    return -1.0; 
}  

public void OnGameFrame() 
{
    static int slow = 0;
    slow++;
    if(slow == 100)
    {
        slow = 0;

        for(new client = 1; client <= MaxClients; client++) 
        { 
            if(!IsValidClient(client) || IsFakeClient(client))
                continue;

            PrintToChat(client, "Distance: %f", GetDistanceToFloor(client));
        }
    }
} 


It could be your TraceRayNoPlayers filter. Also the last argument of GetVectorDistance is true or false to square, resulting in a bigger or smaller number.

[DarthMan]

Originally Posted by 1337norway I made this to test out the function and it appears to be working fine on my end. Post some of your code where you call the function and print it. PHP Code: #include <sourcemod> #include <sdktools> bool:IsValidClient(client, bool:bAllowBots = true) {     if(!(1 <= client <= MaxClients) || !IsClientConnected(client) || !IsClientInGame(client) || (IsFakeClient(client) && !bAllowBots))         return false;     return true; } public bool:TraceRayNoPlayers(entity, mask, any:data) {     if(entity == data || (entity >= 1 && entity <= MaxClients))         return false;     return true; } float GetDistanceToFloor(const int iID)  {      float fStart[3], fEnd[3];            GetEntPropVector(iID, Prop_Send, "m_vecOrigin", fStart);          fEnd[0] = fStart[0];      fEnd[1] = fStart[1];      fEnd[2] = fStart[2] - 8192.0;            Handle hTrace = TR_TraceRayFilterEx(fStart, fEnd, MASK_PLAYERSOLID, RayType_EndPoint, TraceRayNoPlayers, iID);            if(TR_DidHit())      {          float fEndPos[3];          TR_GetEndPosition(fEndPos, hTrace);          float fDistance = GetVectorDistance(fStart, fEndPos, false);                    CloseHandle(hTrace);                    return fDistance;      }            CloseHandle(hTrace);            return -1.0;  }   public void OnGameFrame()  {     static int slow = 0;     slow++;     if(slow == 100)     {         slow = 0;         for(new client = 1; client <= MaxClients; client++)          {              if(!IsValidClient(client) || IsFakeClient(client))                 continue;             PrintToChat(client, "Distance: %f", GetDistanceToFloor(client));         }     } }  It could be your TraceRayNoPlayers filter. Also the last argument of GetVectorDistance is true or false to square, resulting in a bigger or smaller number.

PHP Code:

stock bool TraceRayNoPlayers(const int iEnt, const int iMask, any iData)
{
    if(iEnt == iData || IsPlayer(iEnt))
        return false;
    
    return true;
}

stock int IsPlayer(int iEnt)
{
    return 1 <= iEnt <= MaxClients;
} 


On the OnPlayerRunCmd Action, I checked if it is valid and is not a bot, then checked if the player was pressing the use key and inside if(GetDistanceToFloor(iID) <= 100.0 && !g_bHasParachute[iID - 1] && !IsValidEntity(g_szParaEnt[iID - 1])) return Plugin_Continue;

I did a server print and it didn't print anything unfortunately.

[backwards]

I belive it's an issue somewhere else in your code as the snippet i posted works.
possibly this part:

PHP Code:

!g_bHasParachute[iID - 1] && !IsValidEntity(g_szParaEnt[iID - 1])) 


just comment out these checks and try running it without anything else preventing the GetDistance function from being called

[DarthMan]

Originally Posted by 1337norway I belive it's an issue somewhere else in your code as the snippet i posted works. possibly this part: PHP Code: !g_bHasParachute[iID - 1] && !IsValidEntity(g_szParaEnt[iID - 1]))  just comment out these checks and try running it without anything else preventing the GetDistance function from being called

Sure. I will check tomorrow night, since I am dealing with another more important issue right now.

[Dragokas]

A little bit simplier version: https://forums.alliedmods.net/showthread.php?t=161305

[eyal282]

I personally prefer using TraceHull, whose result origin is an origin you can teleport into without getting stuck inside the ground ( hull takes your size into account, not assuming you're an entity that is 0 sized )