[SOLVED] String array & translation

Grey83 · **Author**

Why I can use

PHP Code:

new String:sName[][] = { "First", "Second", "Third", ... "Last" }; ... Format(Item, sizeof(Item), "%s%t", sName[i], sText);

but can't use

PHP Code:

Format(Item, sizeof(Item), "%t%t", sName[i], sText);

or

PHP Code:

new String:sNewString[] = sName[i]; Format(Item, sizeof(Item), "%t%t", sNewString, sText);

or

PHP Code:

new String:sNewString[some_num] Format(sNewString, sizeof(sNewString), "%s", sName[i]); Format(Item, sizeof(Item), "%t%t", sNewString, sText);

What am I doing wrong?
Solved:

PHP Code:


			
Format(MenuItem, sizeof(MenuItem), "%T%T", sColorName[i], client, currPref == i ? "(Selected)" : "none", client);

Chaosxk · 04-05-2016 , 16:07 Re: [HELP] String array & translation

%t refers to the translation file. %s refers to the string "First", "Second", ...

A little confused on what you want. Do you want to print "First", "Second", ... or do you want to print what the translation is referenced to.

Bacardi · *Last edited by Bacardi; 04-06-2016 at 00:29.*

if you Format string, you need upper case %T and give client index after. Read wiki doc about formating.

https://wiki.alliedmods.net/Translat...ge_in_a_Plugin

Grey83 · 04-06-2016 , 04:04

i need it not for players.
Bacardi, I've read this article, but the necessary information there and not found. So wrote here
I edit my plugin Laser Aim and want to reduce the amount of code in it.
You can't just use text from the array to create a menu with translation.

Spoiler

Like this:

PHP Code:


			
#define NUM_COLORS 9
new String:sColorName[][] = {
"Red",
"Orange",
"Yellow",
"Green",
"Cyan",
"Blue",
"Magenta",
"White",
"Switch off"
};
...
public PrefMenu(client, CookieMenuAction:action, any:info, String:buffer[], maxlen)
{
...
        for (new i = 0; i < NUM_COLORS; i++)
        {
            Format(MenuItem, sizeof(MenuItem), "%t%t", sColorName[i], currPref == i ? "(Selected)" : "none");
            IntToString(i, sNum, 2);
            AddMenuItem(prefmenu, sNum, MenuItem, currPref == i ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        }
...
}

Instead of

PHP Code:


			
public PrefMenu(client, CookieMenuAction:action, any:info, String:buffer[], maxlen)
{
...
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Red", currPref == 0 ? "(Selected)" : "none", currPref == 0 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "0", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Orange", currPref == 1 ? "(Selected)" : "none", currPref == 1 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "1", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Yellow", currPref == 2 ? "(Selected)" : "none", currPref == 2 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "2", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Green", currPref == 3 ? "(Selected)" : "none", currPref == 3 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "3", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Cyan", currPref == 4 ? "(Selected)" : "none", currPref == 4 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "4", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Blue", currPref == 5 ? "(Selected)" : "none", currPref == 5 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "5", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Magenta", currPref == 6 ? "(Selected)" : "none", currPref == 6 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "6", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "White", currPref == 7 ? "(Selected)" : "none", currPref == 7 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "7", MenuItem);
        Format(MenuItem, sizeof(MenuItem), "%t%t", "Switch off", currPref == 8 ? "(Selected)" : "none", currPref == 8 ? ITEMDRAW_DISABLED : ITEMDRAW_DEFAULT);
        AddMenuItem(prefmenu, "8", MenuItem);
...
}

Bacardi · *Last edited by Bacardi; 04-06-2016 at 08:13.*

..read wiki again.

PHP Code:


			
Format(buffer, sizeof(buffer), "%T", "your translated phrase", client);

PHP Code:


			
Format(MenuItem, sizeof(MenuItem), "%T", "Laser_Aim_Control", client);

PHP Code:


			
Format(MenuItem, sizeof(MenuItem), "%T%T", "Red", client, currPref == 0 ? "(Selected)" : "none", client);

Spoiler

PHP Code:


			




new String:examples[][] = {

    "First",

    "Second",

    "Third",

    "Last"

};



public OnPluginStart()

{

    LoadTranslations("example.phrases");

    RegConsoleCmd("sm_test", test);

}



public Action:test(client, args)

{

    new String:buffer[512];



    Format(buffer, sizeof(buffer), "Format Translate:");



    for(new a = 0; a < sizeof(examples); a++)

    {

        Format(buffer, sizeof(buffer), "%s %s =", buffer, examples[a]); // default text

        Format(buffer, sizeof(buffer), "%s %T", buffer, examples[a], client); // Translated text, %T

    }



    PrintToChat(client, "%s", buffer);



    // Using lower case %t in SM natives PrintToChat(client, "%t");

    PrintToChat(client, "PrintToChat Format: %s = %t %s = %t", examples[0], examples[0], examples[3], examples[3]);







    

    // MENU PART!

    new Handle:menu = CreateMenu(menu_callback, MenuAction_End|MenuAction_DisplayItem);



    for(new a = 0; a < sizeof(examples); a++)

    {

        AddMenuItem(menu, "", examples[a]); // Set menu items with default texts

    }

    DisplayMenu(menu, client, 0);





    return Plugin_Handled;

}



public menu_callback(Menu:menu, MenuAction:action, param1, param2)

{

    if (action == MenuAction_DisplayItem)

    {

        new String:dispBuf[512];

        GetMenuItem(menu, param2, "", 0, _, dispBuf, sizeof(dispBuf)); // get menu display text



        Format(dispBuf, sizeof(dispBuf), "%T", dispBuf, param1); // Translate text here



        return RedrawMenuItem(dispBuf); // change menu item display text;

    }







    if (action == MenuAction_End)

    {

        CloseHandle(menu);

    }



    return 0; // when leave menu item display text unchagned

}

...translations/example.phrases

Code:

"Phrases"
{
	"First"
	{
		"en"		"First"
	}

	"Second"
	{
		"en"		"Second"
	}

	"Third"
	{
		"en"		"Third"
	}

	"Last"
	{
		"en"		"Last"
	}
}

...translations/ua/example.phrases

Code:

"Phrases"
{
	"First"
	{
		"ua"		"Перший"
	}

	"Second"
	{
		"ua"		"другий"
	}

	"Third"
	{
		"ua"		"третій"
	}

	"Last"
	{
		"ua"		"останній"
	}
	
}

WildCard65 · 04-06-2016 , 08:28 Re: [HELP] String array & translation

Or, if you want to translate phrase to server's language, use

PHP Code:


			
LANG_SERVER

instead of a client index.

Grey83 · 04-06-2016 , 08:59

Quote:

Originally Posted by Bacardi

PHP Code:


			
Format(MenuItem, sizeof(MenuItem), "%T%T", "Red", client, currPref == 0 ? "(Selected)" : "none", client);

Thanks for the help.
Now I can update the plugin.