[HarryPotter]

If possible, when survivor throws Bile Bomb at the ground, info_goal_infected_chase entity will be created, it makes all the infected in the map chase it.

Bur if survivor throws Bile Bomb out of map where zombie can't reach such as roof and sky,
all common infected just dance and stay where they are.

So my request is "Remove info_goal_infected_chase entity if this entity is out of map (nav)"

I haved tried

Spoiler

1. L4D_GetNearestNavArea from Left 4 DHooks Direct

PHP Code:

public void OnEntityCreated(int entity, const char[] classname)
{
    switch (classname[0])
    {
        case 'i':
        {
            if (StrEqual(classname, "info_goal_infected_chase"))
            {
                float pos[3];
                GetEntPropVector(entity, Prop_Send, "m_vecOrigin", pos);

                PrintToChatAll("%d (%.2f %.2f %.2f), nav: %d", entity, pos[0], pos[1], pos[2], L4D_GetNearestNavArea(pos));
                if( L4D_GetNearestNavArea(pos) == 0) //this always return positive number
                {
                        PrintToChatAll("%d is out of map",entity);
                }
            }
        }
    }
} 


2. L4D2_IsReachable from Left 4 DHooks Direct
,
this works on 99% case, but It appears the server will sometimes crash when passing a real players client index. :/

PHP Code:

/**
 * @brief Checks if a world position is accessible to a Survivor bot.
 * @remarks You must pass a survivor bots client index into this, otherwise the plugin will attempt to find a bot or throw an error otherwise.
 * @remarks It appears the server will sometimes crash when passing a real players client index.
 * @remarks If the clients flow distance is too far away from the position to test it will return false.
 *
 * @param client    Client id to use for testing
 * @param vecPos    Vector coordinate to test
 *
 * @return            True if accessible, false otherwise
 */
// L4D2 only.
native bool L4D2_IsReachable(int client, const float vecPos[3]); 


PHP Code:

This native only works for Survivor Bots. 


Edit: Solved by BHaType

[sorallll]

At present, no function has been found that can perfectly determine whether a location is reachable or not.
L4D2_IsReachable, L4D2_NavAreaTravelDistance, L4D2_VScriptWrapper_NavAreaBuildPath
None of these functions work very well

[Silvers]

On failure to detect out of bounds you could possibly watch for bile explosion and 1 second later check a few common if their animation is standing (I think facing the bile bomb?) with the animation of them waiving their arms and not moving. Then if that's the case the bile is out of bounds and delete.

but It appears the server will sometimes crash when passing a real players client index

This has been the issue with "L4D2_IsReachable" since that function is designed for Survivor bots. I haven't looked too closely to find any other out of bounds style functions. If you do let me know and I'll add.

[HarryPotter]

Originally Posted by sorallll At present, no function has been found that can perfectly determine whether a location is reachable or not. L4D2_IsReachable, L4D2_NavAreaTravelDistance, L4D2_VScriptWrapper_NavAreaBuildPath None of these functions work very well

Okay...

It seems the only way is to create fake bot and call L4D2_IsReachable(), then kick fake bot on next frame.

[Silvers]

Originally Posted by HarryPotter Okay... It seems the only way is to create fake bot and call L4D2_IsReachable(), then kick fake bot on next frame.

If that works without issues yeah, what if the Survivor team is full of players and unable to create a Survivor bot. This is something that should be added into left4dhooks "L4D2_IsReachable" native. I think a better solution should be found.

[BHaType]

The "Action" method is the most convenient and has 100% accuracy but requires to install Actions extension other methods will still work but not in all situations

Action

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>

#include <left4dhooks>
#include <actions>

public void OnActionCreated( BehaviorAction action, int actor, const char[] name )
{
    if ( strcmp(name, "InfectedAttack") == 0 )
    {
        action.OnUpdate = OnUpdate;
    }
}

public Action OnUpdate( BehaviorAction action, float interval, ActionResult result )
{    
    BehaviorAction chaseVictim = action.Child;
    
    /* ChaseVictim has property to set animation for waiving arms */
    /* In other words this is isReachable property */
    if ( chaseVictim == INVALID_ACTION || chaseVictim.Get(0x4844 /* 4850 - linux */, NumberType_Int8) == 1 )
        return Plugin_Continue;

    /* InfectedAttack stores victim handle at 0x34 */
    int victim = action.Get(0x34) & 0xFFF;
    
    if ( !IsValidEntity(victim) )
        return Plugin_Continue;
    
    char name[32];
    GetEntityClassname(victim, name, sizeof name);
    
    if ( strcmp(name, "info_goal_infected_chase") == 0 )
    {
        PrintToChatAll("Infected(%i) can't reach his target...", action.Actor);
        RemoveEntity(victim);
        
        victim = GetRandomSurvivor(1, -1);
        
        if ( victim )
        {
            /* Go attack random survivor */ 
            action.Set(0x34, GetEntityHandle(victim));
        }
    }
    
    return Plugin_Continue;
}

stock int GetEntityHandle( int entity ) 
{
    return EntIndexToEntRef(entity) & ~(1 << 31);
} 


Navigation

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>

#include <left4dhooks>
#include <actions>

Handle g_hGetNavArea;

public void OnPluginStart()
{
    StartPrepSDKCall(SDKCall_Raw);
    PrepSDKCall_SetSignature(SDKLibrary_Server, "\x55\x8B\xEC\x83\xEC\x18\x83\x79\x1C\x00", 10);
    PrepSDKCall_AddParameter(SDKType_Vector, SDKPass_ByRef);
    PrepSDKCall_AddParameter(SDKType_Float, SDKPass_Plain);
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_Plain);
    g_hGetNavArea = EndPrepSDKCall();
}

public void OnEntityCreated( int entity, const char[] name )
{
    if ( strcmp(name, "info_goal_infected_chase") == 0 )
    {
        SDKHook(entity, SDKHook_SpawnPost, OnEntitySpawned);
    }
}

public void OnEntitySpawned( int entity )
{
    RequestFrame(NextFrame, EntIndexToEntRef(entity));
}

public void NextFrame( int entity )
{
    if ( !entity || !IsValidEntity(entity) )
        return;
    
    entity = EntRefToEntIndex(entity);
    
    float vOrigin[3];
    GetEntPropVector(entity, Prop_Data, "m_vecOrigin", vOrigin);
    
    Address area = GetNavArea(vOrigin, 25.0);
    
    if ( area == Address_Null )
    {
        RemoveEntity(entity);
    }
}

Address GetNavArea( const float vPos[3], float beneathLimit)
{
    return SDKCall(g_hGetNavArea, L4D_GetPointer(POINTER_NAVMESH), vPos, beneathLimit);
} 


Left 4 DHooks & VScript

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>

#include <left4dhooks>
#include <sdkhooks>

int g_iGoalChase;
bool g_bChecked;

public void OnEntityCreated( int entity, const char[] name )
{
    if ( strcmp(name, "info_goal_infected_chase") == 0 )
    {
        g_iGoalChase = EntIndexToEntRef(entity);
        g_bChecked = false;
        
        SDKHook(entity, SDKHook_SpawnPost, OnEntitySpawned);
    }
    else if ( !g_bChecked && strcmp(name, "infected") == 0 )
    {
        SDKHook(entity, SDKHook_SpawnPost, OnEntitySpawned);
    }
}

public void OnEntitySpawned( int entity )
{
    RequestFrame(NextFrame);
}

public void NextFrame()
{
    if ( IsValidEntity(g_iGoalChase) && !CheckGoalChaseTraversablity() )
    {
        RemoveEntity(EntRefToEntIndex(g_iGoalChase));
        g_iGoalChase = -1;
    }
}

int CheckGoalChaseTraversablity()
{
    if ( g_bChecked )
        return -1;
    
    int infected = FindEntityByClassname(MaxClients + 1, "infected");
    
    if ( infected == -1 )
        return -1;
    
    float startPos[3], endPos[3];
    
    GetEntPropVector(infected, Prop_Data, "m_vecOrigin", startPos);
    GetEntPropVector(EntRefToEntIndex(g_iGoalChase), Prop_Data, "m_vecOrigin", endPos);
    
    g_bChecked = true;
    return L4D2_VScriptWrapper_NavAreaBuildPath(startPos, endPos, 1550.0, false, true, 3, false);
} 


[HarryPotter]

Originally Posted by BHaType The "Action" method is the most convenient and has 100% accuracy but requires to install Actions extension other methods will still work but not in all situations Action PHP Code: #pragma semicolon 1 #pragma newdecls required #include <sourcemod> #include <sdktools> #include <left4dhooks> #include <actions> public void OnActionCreated( BehaviorAction action, int actor, const char[] name ) {     if ( strcmp(name, "InfectedAttack") == 0 )     {         action.OnUpdate = OnUpdate;     } } public Action OnUpdate( BehaviorAction action, float interval, ActionResult result ) {         BehaviorAction chaseVictim = action.Child;          /* ChaseVictim has property to set animation for waiving arms */     /* In other words this is isReachable property */     if ( chaseVictim == INVALID_ACTION || chaseVictim.Get(0x4844 /* 4850 - linux */, NumberType_Int8) == 1 )         return Plugin_Continue;     /* InfectedAttack stores victim handle at 0x34 */     int victim = action.Get(0x34) & 0xFFF;          if ( !IsValidEntity(victim) )         return Plugin_Continue;          char name[32];     GetEntityClassname(victim, name, sizeof name);          if ( strcmp(name, "info_goal_infected_chase") == 0 )     {         PrintToChatAll("Infected(%i) can't reach his target...", action.Actor);         RemoveEntity(victim);                  victim = GetRandomSurvivor(1, -1);                  if ( victim )         {             /* Go attack random survivor */              action.Set(0x34, GetEntityHandle(victim));         }     }          return Plugin_Continue; } stock int GetEntityHandle( int entity )  {     return EntIndexToEntRef(entity) & ~(1 << 31); }

That is weird, I throw bile at reachable nav or common infected body, the chat still prints

Infected(1410) can't reach his target...
Infected(1422) can't reach his target...
Infected(1431) can't reach his target...
Infected(1436) can't reach his target...
Infected(1438) can't reach his target...
Infected(1420) can't reach his target...
Infected(1429) can't reach his target...
Infected(1439) can't reach his target...

and all infected just ignore bile jar location.

L4D2 windows dedicated server.

[HarryPotter]

Originally Posted by Silvers If that works without issues yeah, what if the Survivor team is full of players and unable to create a Survivor bot. This is something that should be added into left4dhooks "L4D2_IsReachable" native. I think a better solution should be found.

Here is what I write now, and you are right, if there are 18 survivors, can not create fake bot.

PHP Code:

#pragma semicolon 1
#pragma newdecls required
 
#include <sdktools>
#include <sdkhooks>
#include <multicolors>
#include <left4dhooks>
#undef REQUIRE_PLUGIN
#include <CreateSurvivorBot> //https://forums.alliedmods.net/showpost.php?p=2729883&postcount=16

public Plugin myinfo =
{
    name = "[L4D2] Bile Out Nav Negate",
    author = "HarryPotter",
    description = "If Vomit jar is thrown at the place which is out of map (NAV), negate bile effect",
    version = "1.0",
    url = "https://steamcommunity.com/profiles/76561198026784913"
}

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max)
{
    EngineVersion test = GetEngineVersion();

    if( test != Engine_Left4Dead2 )
    {
        strcopy(error, err_max, "Plugin only supports Left 4 Dead 2.");
        return APLRes_SilentFailure;
    }

    return APLRes_Success;
}

#define STRINGLENGTH_CLASSES            64
#define MAXENTITIES                     2048
#define CVAR_FLAGS                      FCVAR_NOTIFY
ConVar g_hCvar_Enabled;

int g_iOwner;
static int ge_iType[MAXENTITIES+1];

public void OnPluginStart()
{    
    g_hCvar_Enabled = CreateConVar("l4d2_bile_out_nav_negate_enable", "1", "Enable/Disable the plugin.\n0 = Disable, 1 = Enable.", CVAR_FLAGS, true, 0.0, true, 1.0);

    GetCvars();
    g_hCvar_Enabled.AddChangeHook(ConVarChanged_Cvars);

    AutoExecConfig(true, "l4d2_bile_out_nav_negate");
}

public void ConVarChanged_Cvars(ConVar convar, const char[] oldValue, const char[] newValue)
{
    GetCvars();
}

bool g_bCvar_Enabled;
void GetCvars()
{
    g_bCvar_Enabled = g_hCvar_Enabled.BoolValue;
}

bool g_bConfig;
public void OnConfigsExecuted()
{
    g_bConfig = true;
}

public void OnMapEnd()
{
    g_bConfig = false;
}

public void OnEntityCreated(int entity, const char[] classname)
{
    if (!g_bConfig || !g_bCvar_Enabled)
        return;


    if (!IsValidEntityIndex(entity))
        return;

    //PrintToChatAll("%d - %s", entity, classname);

    switch (classname[0])
    {
        case 'i':
        {
            if (StrEqual(classname, "info_goal_infected_chase"))
                RequestFrame(OnNextFrame, EntIndexToEntRef(entity));
        }
        case 'v':
        {
            if (StrEqual(classname, "vomitjar_projectile"))
            {
                SDKHook(entity, SDKHook_SpawnPost, OnSpawnPost);
            }
        }
    }
}

public void OnSpawnPost(int entity)
{
    if( !IsValidEntity(entity) ) return;
     
    int client = GetEntPropEnt(entity, Prop_Send, "m_hOwnerEntity");

    if(client <= 0 || !IsClientInGame(client)) 
        return;
        
    ge_iType[entity] = GetClientUserId(client);
    //PrintToChatAll("OnSpawnPost() %N throws a bilejar", client);
}

public void OnNextFrame(int entityRef)
{
    if (!g_bCvar_Enabled)
        return;

    int entity = EntRefToEntIndex(entityRef);

    if (entity == INVALID_ENT_REFERENCE)
        return;

    float pos[3];
    GetEntPropVector(entity, Prop_Send, "m_vecOrigin", pos);

    //PrintToChatAll("%d (%.2f %.2f %.2f), nav: %d", entity, pos[0], pos[1], pos[2], L4D_GetNearestNavArea(pos));
    // if( L4D_GetNearestNavArea(pos) == 0)
    // {
    //     PrintToChatAll("%d is out of map",entity);
    // }

    int owner = GetClientOfUserId(g_iOwner);
    g_iOwner = 0;
    if(owner && IsClientInGame(owner))
    {
        int client = GetRandomSurvivor(-1,1);
        int fakeclient;
        if(client == 0) {
            fakeclient = CreateSurvivorBot();
            if(fakeclient > 0 && IsClientInGame(fakeclient)) client = fakeclient;
            else return;
        }

        if(L4D2_IsReachable(client, pos) == false)
        {
            CPrintToChatAll("[{olive}TS{default}] {blue}%N{default} throws a {green}bilejar{default} at unreachable location, negate the bile effect.", owner);
            RemoveEntity(entity);
        }

        if(fakeclient > 0 && IsClientInGame(fakeclient)) KickClient(fakeclient, "Kicking FakeClient");    
    }
}

public void OnEntityDestroyed(int entity)
{
    if (!g_bConfig || !g_bCvar_Enabled)
        return;

    if (!IsValidEntityIndex(entity))
        return;

    char class[STRINGLENGTH_CLASSES];
    GetEdictClassname(entity, class, sizeof(class));

    if (strcmp(class, "vomitjar_projectile") != 0) return;  

    int client = ge_iType[entity];
    ge_iType[entity] = 0;
    client = GetClientOfUserId(client);
    if(client <= 0 || !IsClientInGame(client)) return;

    g_iOwner = GetClientUserId(client);
    //PrintToChatAll("%N thros a bilejar", client);
}

bool IsValidEntityIndex(int entity)
{
    return (MaxClients+1 <= entity <= GetMaxEntities());
} 


[BHaType]

Originally Posted by HarryPotter That is weird, I throw bile at reachable nav or common infected body, the chat still prints

Hmm... Game overwrites ChaseVictim property. Try this version

Code

PHP Code:

#pragma semicolon 1
#pragma newdecls required

#include <sourcemod>
#include <sdktools>

#include <left4dhooks>
#include <actions>
#include <sourcescramble>

MemoryPatch g_hBlockWavingAnimation;

public void OnPluginStart()
{
    GameData data = new GameData("l4d2_infected_navigation_out_of_map");
    g_hBlockWavingAnimation = MemoryPatch.CreateFromConf(data, "ChaseVictim::Update");
    delete data;
}

public void OnActionCreated( BehaviorAction action, int actor, const char[] name )
{
    if ( strcmp(name, "ChaseVictim") == 0 )
    {
        action.OnUpdate = OnUpdate;
        action.OnUpdatePost = OnUpdatePost;
    }
}

public Action OnUpdate( BehaviorAction chaseVictim, float interval, ActionResult result )
{
    if ( chaseVictim.Get(0x4844, NumberType_Int8) != 0 )
        return Plugin_Continue;
        
    chaseVictim.Set(0x4844, 0);
    BlockWavingAnimation(true);
    
    BehaviorAction attack = chaseVictim.Parent; 
    
    if ( attack == INVALID_ACTION )
        return Plugin_Continue;
    
    char szAction[ACTION_NAME_LENGTH];
    attack.GetName(szAction, sizeof szAction);
    
    PrintToChatAll(szAction);
    
    /* InfectedAttack stores victim handle at 0x34 */
    int victim = attack.Get(0x34) & 0xFFF;
    
    if ( !IsValidEntity(victim) )
        return Plugin_Continue;
    
    char name[32];
    GetEntityClassname(victim, name, sizeof name);
    
    if ( strcmp(name, "info_goal_infected_chase") == 0 )
    {
        PrintToChatAll("Infected(%i) can't reach his target...", chaseVictim.Actor);
        RemoveEntity(victim);
        
        victim = GetRandomSurvivor(1, -1);
        
        if ( victim )
        {
            /* Go attack random survivor */ 
            attack.Set(0x34, GetEntityHandle(victim));
        }
        else
        {
            attack.Set(0x34, -1);
        }
    }
    
    return Plugin_Continue;
}

public Action OnUpdatePost( BehaviorAction chaseVictim, float interval, ActionResult result )
{
    BlockWavingAnimation(false);
    return Plugin_Continue;
}

void BlockWavingAnimation( bool block )
{
    if ( block )
        g_hBlockWavingAnimation.Enable();
    else
        g_hBlockWavingAnimation.Disable();
}


stock int GetEntityHandle( int entity ) 
{
    return EntIndexToEntRef(entity) & ~(1 << 31);
} 


GameData

PHP Code:

"Games"
{
    "left4dead2"
    {
        "MemPatches"
        {
            "ChaseVictim::Update"
            {
                "signature" "ChaseVictim::Update"
                
                "linux"
                {
                    "offset"    "3916"
                    "verify"    "\x0F\x84\xA7\x02\x00\x00"
                }
                
                "windows"     
                {
                    
                    "offset"    "2427"
                    "verify"    "\x0F\x84\x9C\x00\x00\x00"
                }
                    
                "patch"        "\x90\x90\x90\x90\x90\x90"
            }
        }
        
        
        "Signatures"
        {
            "ChaseVictim::Update"
            {
                "linux" "@_ZN11ChaseVictim6UpdateEP8Infectedf"
                "windows" "\x55\x8B\xEC\x83\xEC\x68\xA1\x2A\x2A\x2A\x2A\x53\x56\x33\xF6\x8B\xD9"
            }
        }
    }
} 


Help information for everyone else who wants to find a better solution

Infected starts waving animation at 40EFD0 + 96D (ChaseVictim::Update) it compares ChaseVictim property which stores return value of Path::IsValid function, property getting set from DirectChaseVictim::Update at 3B71B7 and 3B717A (Windows offsets).

Probably the best solution is to detourPost DirectChaseVictim::Update function and check if chasing entity is vomitjar and path for it is unreachable if so delete vomitjar and set property to 1

[HarryPotter]

Originally Posted by BHaType Hmm... Game overwrites ChaseVictim property. Try this version

Thanks for your great work, but sadly still doesn't work,

InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack
Infected(1431) can't reach his target...
InfectedAttack
Infected(1436) can't reach his target...
InfectedAttack
Infected(1450) can't reach his target...
InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack
InfectedAttack