[ish12321]

PHP Code:

new players[MAX_PLAYERS], num, player;
    get_players_ex(players, num, GetPlayers_ExcludeHLTV);    
    
    for(new i = 0; i < num; i++)
    {
        player = players[i];

        if(cs_get_user_team(player) == CS_TEAM_UNASSIGNED)
        {
            continue;
        }

        user_kill(player);
        cs_set_user_team(player, CS_TEAM_SPECTATOR);

    }
    
    get_players_ex(players, num, GetPlayers_ExcludeHLTV | GetPlayers_MatchTeam, "SPECTATOR");

    for(new i = 0; i < num; i++)
    {
        player = players[i];
        cs_set_user_team(player, CsTeams:random_num(1, 2));
    }

    new players_CT[MAX_PLAYERS], players_T[MAX_PLAYERS], num_CT, num_T;
    get_players_ex(players_CT, num_CT, GetPlayers_ExcludeHLTV | GetPlayers_MatchTeam, "CT");
    get_players_ex(players_T, num_T, GetPlayers_ExcludeHLTV | GetPlayers_MatchTeam, "TERRORIST");
    
    if(num_CT > num_T)
    {
        for(new i = 0; i < num_CT; i++)
        {
            if((num_CT - num_T) <= 1)
            {
                break;
            }

            player = players_CT[i];

            cs_set_user_team(player, CS_TEAM_T);
        }
    }
    else if(num_T > num_CT)
    {
        for(new i = 0; i < num_T; i++)
        {
            if((num_T - num_CT) <= 1)
            {
                break;
            }

            player = players_T[i];

            cs_set_user_team(player, CS_TEAM_CT);
        }
    } 


This is the code I used to randomize teams. It works perfectly for most time ,but sometimes is it sending all players to T or CT. Could someone please check it and point me out the bug ?

[Bugsy]

Originally Posted by ish12321 This is the code I used to randomize teams. It works perfectly for most time ,but sometimes is it sending all players to T or CT. Could someone please check it and point me out the bug ?

It's likely because when you're balancing them out you never subtract & add from each team count when moving a player to the opposite team. The for-loop continues for the entirety of num_CT or num_T since the if((num_TEAM1 - num_TEAM2) <= 1) condition never changes.

if(num_CT > num_T) 
{ 
    for(new i = 0; i < num_CT; i++) 
    { 
        if((num_CT - num_T) <= 1) 
        { 
            break; 
        } 
        
        player = players_CT[i]; 
        
        cs_set_user_team(player, CS_TEAM_T);
        num_CT--;
        num_T++;
    } 
} 
else if(num_T > num_CT) 
{ 
    for(new i = 0; i < num_T; i++) 
    { 
        if((num_T - num_CT) <= 1) 
        { 
            break; 
        } 
        
        player = players_T[i]; 
        
        cs_set_user_team(player, CS_TEAM_CT); 
        num_T--;
        num_CT++;
    } 
}