[alcybery]

I'm trying to make tank to only burn while being in a fire but not after leaving fire. I have this code, but it doesn't compile (undefined symbol "ExtinguishEntity")

PHP Code:

public OnPluginStart()
    HookEvent("player_hurt", EventPlayerHurt)

public Action:EventPlayerHurt(Handle:h_Event, String:s_Name[], bool:b_DontBroadcast)
{
    decl i_UserID, i_Client, String:s_ModelName[64]
    
    i_UserID = GetEventInt(h_Event, "userid")
    i_Client = GetClientOfUserId(i_UserID)
    
    GetEntPropString(i_Client, Prop_Data, "m_ModelName", s_ModelName, sizeof(s_ModelName))

    if (StrContains(s_ModelName, "hulk") != -1)
    {
        decl String:s_Weapon[16], i_Type
        
        i_Type = GetEventInt(h_Event, "type")
        GetEventString(h_Event, "weapon", s_Weapon, sizeof(s_Weapon))

        if (i_Type == 268435464)
        {
            ExtinguishEntity(i_Client);
            SetEntPropFloat(i_Client, Prop_Send, "m_burnPercent", 1.0);
        }
    }
} 


[Silvers]

#include <sourcemod>
#include <sdktools>

at the top of plugin. But your code most likely won't work, damage and preventing death etc doesn't work on events. You need to use SDKHooks.. look at other plugins for example how to hook the entity when tank spawns (using events) and then SDKHooks OnTakeDamage to handle it correctly and make it work.

[alcybery]

Thanks, it was silly to forget to add these lines Plugin seems to be working, tank stops burning after leaving the fire and doesn't die.

[xerox8521]

Instead of checking the model for hulk you should just retrieve the m_zombieClass prop and check if the value is 8 ( i believe).
Honestly I suggest forcing semicolons (#pragma semicolon 1 at the top of the plugin) as it is bad practice to not use them as alot of other languages require them to work.

[Silvers]

I was going to say, for what I call hackish-type solutions this would probably work, but if you want accurate health changing/stopping SDKHooks is the method. m_zombieClass is much better check, class number 8 or something. Check other plugins for various methods on doing stuff.

[alcybery]

Originally Posted by xerox8521 Instead of checking the model for hulk you should just retrieve the m_zombieClass prop and check if the value is 8 ( i believe). Honestly I suggest forcing semicolons (#pragma semicolon 1 at the top of the plugin) as it is bad practice to not use them as alot of other languages require them to work.

Something like this?

PHP Code:

#include <sourcemod>
#include <sdktools>
#pragma semicolon 1 

public OnPluginStart()
HookEvent("player_hurt", EventPlayerHurt);

public Action:EventPlayerHurt(Handle:h_Event, String:s_Name[], bool:b_DontBroadcast)
{
    decl i_UserID, i_Client;
    
    i_UserID = GetEventInt(h_Event, "userid");
    i_Client = GetClientOfUserId(i_UserID);

    if(GetEntProp(i_Client, Prop_Send, "m_zombieClass") == 8)
    {
        decl String:s_Weapon[16], i_Type;
        
        i_Type = GetEventInt(h_Event, "type");
        GetEventString(h_Event, "weapon", s_Weapon, sizeof(s_Weapon));

        if (i_Type == 268435464)
        {
            ExtinguishEntity(i_Client);
            SetEntPropFloat(i_Client, Prop_Send, "m_burnPercent", 1.0);
        }
    }
} 


Originally Posted by Silvers I was going to say, for what I call hackish-type solutions this would probably work, but if you want accurate health changing/stopping SDKHooks is the method. m_zombieClass is much better check, class number 8 or something. Check other plugins for various methods on doing stuff.

Unfortunately that is above my level of knowledge. With the code that I posted I just combined two different plugins.

[Psyk0tik]

Super Tanks and Super Tanks+ show an example for how to give Tanks fire immunity.

[Silvers]

Originally Posted by alcybery Unfortunately that is above my level of knowledge.

Originally Posted by Silvers look at other plugins for example

That's how I learnt by checking other plugins until I learnt the common mistakes and enough to write without references.

[Psyk0tik]

Originally Posted by Silvers That's how I learnt by checking other plugins until I learnt the common mistakes and enough to write without references.

That's how I learned to write plugins as well. By learning from your and other people's plugins, I went from not knowing what "#include <sourcemod>" was even for to being able to write a simple plugin that creates files in specific directories without using references. It all just comes down to whether someone is determined to learn, to just copy off of others, or to just request from others.

@OP, the wiki is a good start for beginners but if you really want to get into the more complex stuff, you need to have the motivation and patience to learn. You also have to get into the habit of sort of teaching yourself along the way, and asking help in the Scripting board (if you really can't find an old thread about the same topic already).

[Silvers]

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart()
{
    // Nice and simple we have an event for tank spawning
    HookEvent("tank_spawn", Event_TankSpawn);
}

public Action Event_TankSpawn(Handle event, char[] name, bool dontBroadcast)
{
    int client = GetEventInt(event, "userid");
    client = GetClientOfUserId(client);

    if( client && IsClientInGame(client) )
    {
        // We only need to hook when the tank spawns
        SDKHook(client, SDKHook_OnTakeDamage, OnTakeDamage);
    }
}  

public Action OnTakeDamage(int client, int &attacker, int &inflictor, float &damage, int &damagetype)
{
    if( damagetype == 268435464 )
    {
        ExtinguishEntity(client);
        SetEntPropFloat(client, Prop_Send, "m_burnPercent", 1.0);

        // If you want to completely block damage caused by walking in the fire, these two lines do that:
        damage = 0.0;
        return Plugin_Changed;
    }
    return Plugin_Continue; // No changes to damage.
} 


You could remove the "return blah" and "damage = 0.0" lines if you don't want to change damage.

See Mutant Zombies plugin for more on dealing with fire and preventing the damage or you could reduce the damage etc.