[XMateiXGO]

Hi,i need ca guns menu only for terrorist,if a CT want to type for exemple !guns ,the server say: You are not terrorist.I need the menu to be just for the terrorists please.
In guns menu i just want you to add:
AK47
M4A1
AWP
Deagle

And the terrorist to can open the menu just for 2 times in the round.

[ladaladik]

edit : just use the bascardis one.

[Bacardi]

Spoiler

PHP Code:

char weapons_list[][] = {
    "ak47",
    "m4a1",
    "awp",
    "deagle"
};

#include <cstrike>
#include <sdktools>

#define GUNS_LIMIT  2
int playergunscount[MAXPLAYERS+1];

public void OnPluginStart()
{
    HookEvent("round_start", round_start);
    RegConsoleCmd("sm_guns", guns, "Open guns menu (if available)");
}

public void round_start(Event event, char[] name, bool dontBroadcast)
{
    for(int x = 0; x <= MaxClients; x++) playergunscount[x] = 0;
}

public Action guns(int client, int args)
{
    if(client == 0 || !IsClientInGame(client)) return Plugin_Handled;

    if(GetClientTeam(client) != CS_TEAM_T)
    {
        ReplyToCommand(client, "[SM] You need to be in Terrorist team");
        return Plugin_Handled;
    }

    if(!IsPlayerAlive(client))
    {
        ReplyToCommand(client, "[SM] You need to be alive");
        return Plugin_Handled;
    }

    if(playergunscount[client] >= GUNS_LIMIT)
    {
        PrintToChat(client, "[SM] Limit of guns have used.");
        return Plugin_Handled;
    }

    Menu menu = new Menu(menu_handler, MENU_ACTIONS_DEFAULT);
    menu.SetTitle("Menu GUNS!");

    char alias[MAX_TARGET_LENGTH];
    CSWeaponID weaponID;

    for(int x = 0; x < sizeof(weapons_list); x++)
    {
        // clear weapon_prefix
        CS_GetTranslatedWeaponAlias(weapons_list[x], alias, sizeof(alias));

        weaponID = CS_AliasToWeaponID(alias);
        
        // Incorrect weapon name
        if(weaponID == CSWeapon_NONE)
        {
            LogError("Incorrect weapon %s %s", weapons_list[x], alias);
            continue;
        }

        // Wrong game
        if(!CS_IsValidWeaponID(weaponID))
        {
            LogError("Game not have weapon %s %s", weapons_list[x], alias);
            continue;
        }

        if(!menu.AddItem(alias, alias))
        {
            LogError("AddItem %s failed", alias);
        }
    }

    if(!menu.Display(client, 10))
    {
        LogError("Failed display menu to player");
    }

    return Plugin_Handled;
}

public int menu_handler(Menu menu, MenuAction action, int param1, int param2)
{
    switch(action)
    {
        case MenuAction_End:
        {
            delete menu;
        }
        case MenuAction_Select:
        {
            if(!IsClientInGame(param1) || GetClientTeam(param1) != CS_TEAM_T || !IsPlayerAlive(param1)) return;


            char info[MAX_NAME_LENGTH];

            if(menu.GetItem(param2, info, sizeof(info)))
            {
                Format(info, sizeof(info), "weapon_%s", info);
                GivePlayerItem(param1, info);
                playergunscount[param1]++;
            }            
        }
    }
}