[kevinhandoko]

Hi guys, before that. sorry for my bad english. i live in indonesia. and i still newbie
so. i have problem with my class in COD MOD. i made class name [Premium] Hunter.. and i add knife model in my class. Tomahawk.
Then, in compile, my class succes to compile my plugin. but in game, if i change my weapon to knife in Hunter class. CS close and i get error message "SV_ModelIndex: model V_MODEL not precached" how to fix it? thanks lot 4 you guys
and, its my Code

#include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <engine>
#include <hamsandwich>
#include <fakemeta>
#include <cstrike>
#include <fun>
        
new const nazwa[]   = "[Premium] \r Hunter";
new const opis[]    = "Mempunyai Low Gravity, Multijump (x5) Kill instant dengan Klik kanan dengan Hatchet";
new const bronie    = (1<<CSW_HEGRENADE)|(1<<CSW_FLASHBANG) | (CSW_KNIFE);
new const zdrowie   = 10;
new const kondycja  = 95;
new const inteligencja = 10;
new const wytrzymalosc = 5;
    
new const modelMiny[] = "models/QTM_CodMod/mine.mdl"
new const V_MODEL[] = "models/knife/v_knife.mdl"
new const P_MODEL[] = "models/knife/p_knife.mdl"

new sprite_blast_miny;
new ilosc_min_gracza[33];

new skoki[33];

new ostatnio_prawym[33];

new ma_klase[33];

public plugin_precache()
{
    precache_model(modelMiny);
    sprite_blast_miny = precache_model("sprites/dexplo.spr");
    precache_model(V_MODEL);
    precache_model(P_MODEL);
}


public plugin_init()
{
    register_plugin(nazwa, "1.0", "Kevin Handoko");

    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);   
    RegisterHam(Ham_Spawn, "player", "fwSpawn_Grawitacja", 1);

    register_touch("mine", "player",  "DotykMiny");

    register_event("HLTV", "NowaRunda_Miny", "a", "1=0", "2=0");

    RegisterHam(Ham_Spawn, "player", "fwSpawn_Miny", 1);

   
    register_forward(FM_CmdStart, "fwCmdStart_MultiJump");


    register_event("Damage", "Damage_Wyrzucenie", "b", "2!=0");


    RegisterHam(Ham_TakeDamage, "player", "fwTakeDamage_JedenCios");
    RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_knife", "fwPrimaryAttack_JedenCios");
    RegisterHam(Ham_Weapon_SecondaryAttack, "weapon_knife", "fwSecondaryAttack_JedenCios");

    register_event("CurWeapon", "ModelBroni_CurWeapon", "be", "1=1");
    register_forward(FM_SetModel, "ModelBroni_fw_SetModel");
}

public client_disconnect(id)
{

    new entMiny = find_ent_by_class(0, "mine");
    while(entMiny > 0)
    {
        if(entity_get_edict(entMiny, EV_ENT_owner) == id)
            remove_entity(entMiny);
        entMiny = find_ent_by_class(entMiny, "mine");
    }

}

public cod_class_enabled(id)
{
    if(!(get_user_flags(id) & ADMIN_LEVEL_H))
    {
        client_print(id, print_chat, "[Hunter] Kamu tidak memiliki izin untuk menggunakan kelas ini!")
        return COD_STOP;
    }

     entity_set_float(id, EV_FL_gravity, 500.0/800.0);

    ilosc_min_gracza[id] = 3;
    give_item(id, "weapon_hegrenade");
    give_item(id, "weapon_flashbang");
    ma_klase[id] = true;
   
    return COD_CONTINUE;
}

public cod_class_disabled(id)
{

     entity_set_float(id, EV_FL_gravity, 1.0);
    ma_klase[id] = false;

}

public cod_class_skill_used(id)
{
        
    if (!ilosc_min_gracza[id])
    {
        client_print(id, print_center, "Ranjau mu sudah habis!");
    }
    else
    {

        ilosc_min_gracza[id]--;

        new Float: origin[3]; (without space in beside origin)
        entity_get_vector(id, EV_VEC_origin, origin);

        new ent = create_entity("info_target");
        entity_set_string(ent ,EV_SZ_classname, "mine");
        entity_set_edict(ent ,EV_ENT_owner, id);
        entity_set_int(ent, EV_INT_movetype, MOVETYPE_TOSS);
        entity_set_origin(ent, origin);
        entity_set_int(ent, EV_INT_solid, SOLID_BBOX);

        entity_set_model(ent, modelMiny);
        entity_set_size(ent,Float:{-16.0,-16.0,0.0},Float:{16.0,16.0,2.0});

        drop_to_floor(ent);

        set_rendering(ent,kRenderFxNone, 0,0,0, kRenderTransTexture,50);
    }
}

public fwSpawn_Grawitacja(id)
{
    if(ma_klase[id])
        entity_set_float(id, EV_FL_gravity, 500.0/800.0);
}


public fwSpawn_Miny(id)
{
    if(is_user_alive(id))
        ilosc_min_gracza[id] = 3;
}

public DotykMiny(ent, id)
{
    if(!is_valid_ent(ent))
        return;

    new attacker = entity_get_edict(ent, EV_ENT_owner);
    if (get_user_team(attacker) != get_user_team(id))
    {
        new Float:fOrigin[3];
        entity_get_vector( ent, EV_VEC_origin, fOrigin);

        new iOrigin[3];
        for(new i=0;i<3;i++)
            iOrigin[i] = floatround(fOrigin[i]);

        message_begin(MSG_BROADCAST,SVC_TEMPENTITY, iOrigin);
        write_byte(TE_EXPLOSION);
        write_coord(iOrigin[0]);
        write_coord(iOrigin[1]);
        write_coord(iOrigin[2]);
        write_short(sprite_blast_miny);
        write_byte(32);
        write_byte(20);
        write_byte(0);
        message_end();

        new entlist[33];
        new numfound = find_sphere_class(ent,"player", 90.0 ,entlist, 32);

        for (new i=0; i < numfound; i++)
        {
            new pid = entlist[i];

            if (!is_user_alive(pid) || get_user_team(attacker) == get_user_team(pid))
                continue;

            cod_inflict_damage(attacker, pid, 70.0, 0.8, ent, (1<<24));
        }
        remove_entity(ent);
    }
}

public NowaRunda_Miny()
{
    new entMiny = find_ent_by_class(-1, "mine");
    while(entMiny > 0)
    {
        remove_entity(entMiny);
        entMiny = find_ent_by_class(entMiny, "mine");
    }
}

public fwCmdStart_MultiJump(id, uc_handle)
{
    if(!is_user_alive(id) || !ma_klase[id])
        return FMRES_IGNORED;

    new flags = pev(id, pev_flags);

    if((get_uc(uc_handle, UC_Buttons) & IN_JUMP) && !(flags & FL_ONGROUND) && !(pev(id, pev_oldbuttons) & IN_JUMP) && skoki[id])
    {
        skoki[id]--;
        new Float:velocity[3];
        pev(id, pev_velocity,velocity);
        velocity[2] = random_float(265.0,285.0);
        set_pev(id, pev_velocity,velocity);
    }
    else if(flags & FL_ONGROUND)
        skoki[id] = 5;

    return FMRES_IGNORED;
}

public Damage_Wyrzucenie(id)
{
    new idattacker = get_user_attacker(id);

    if(!is_user_alive(idattacker))
        return;

    if(!ma_klase[idattacker])
        return;

    if(random_num(1, 5) != 1)
        return;

    client_cmd(id, "drop");
}

public fwTakeDamage_JedenCios(id, ent, attacker)
{
    if(is_user_alive(attacker) && ma_klase[attacker] && get_user_weapon(attacker) == CSW_KNIFE && ostatnio_prawym[id])
    {
        cs_set_user_armor(id, 0, CS_ARMOR_NONE);
        SetHamParamFloat(4, float(get_user_health(id) + 1));
        return HAM_HANDLED;
    }
    return HAM_IGNORED;
}

public fwPrimaryAttack_JedenCios(ent)
{
    new id = pev(ent, pev_owner);
    ostatnio_prawym[id] = 1;
}

public fwSecondaryAttack_JedenCios(ent)
{
    new id = pev(ent, pev_owner);
    ostatnio_prawym[id] = 0;
}

public ModelBroni_CurWeapon(id)
{
        new weapon = read_data(2);

        if(ma_klase[id])
        {
                if(weapon == CSW_KNIFE)
                {
                        set_pev(id, pev_viewmodel2, "V_MODEL")
                        set_pev(id, pev_weaponmodel2, "P_MODEL")
                }
        }
}

public ModelBroni_fw_SetModel(entity, model[])
{
        if(!pev_valid(entity))
                return FMRES_IGNORED

        if(!equali(model, "models/w_knife.mdl"))
                return FMRES_IGNORED;

        new entityowner = pev(entity, pev_owner);

        if(!ma_klase[entityowner])
                return FMRES_IGNORED;

        engfunc(EngFunc_SetModel, entity, "")
        return FMRES_SUPERCEDE
}

[YamiKaitou]

Your error is caused by you putting quotes around the variable name

[kevinhandoko]

hmm i see, so i must deleted quote in variable name. thanks a lot