[SM9]

Hello, I have tried creating my own method of changing a clients team in TF2, My aim here is to be able to move a player to another team safely without killing him.

I have already tried SetEntProp but that messes up team counts.

I am trying to use CTFPlayer::ChangeTeam(int) 91 92 92 0x00B6F500
So here is my failed attempt:

Errors:

PHP Code:

L 07/06/2014 - 15:25:16: SourceMod error session started
L 07/06/2014 - 15:25:16: Info (map "dr_safety_first_final") (file "errors_20140706.log")
L 07/06/2014 - 15:25:16: [SM] Native "SDKCall" reported: Invalid Handle 0 (error 4)
L 07/06/2014 - 15:25:16: [SM] Displaying call stack trace for plugin "teamswitchtest.smx":
L 07/06/2014 - 15:25:16: [SM]   [0]  Line 61, C:\Users\Michael\Desktop\teamswitchtest.sp::SetTeam()
L 07/06/2014 - 15:25:16: [SM]   [1]  Line 42, C:\Users\Michael\Desktop\teamswitchtest.sp::SwitchPlayers()
L 07/06/2014 - 15:25:16: [SM]   [2]  Line 24, C:\Users\Michael\Desktop\teamswitchtest.sp::OnRoundStart() 


gamedata (plugin.switchteam.txt)

PHP Code:

"Games"
{
    /* Team Fortress 2 */
    "tf"
    {
        "Offsets"
        {
            "switchteam"
            {
                "windows"    "91"
                "linux"        "92"
                "mac"        "92"
            }
        }
    }
} 


Plugin Source:

PHP Code:

#include <sourcemod>
#include <tf2_stocks>

new Handle:hGameConf;
new Handle:hSwitchTeam;

public Plugin:myinfo = 
{
    name = "Team Switcher Test"
}

public OnPluginStart()
{
    hGameConf = LoadGameConfigFile("plugin.switchteam");
    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(hGameConf, SDKConf_Signature, "switchteam");
    hSwitchTeam = EndPrepSDKCall();
    
    HookEvent("arena_round_start", OnRoundStart);
}

public Action:OnRoundStart(Handle:event, const String:name[], bool:dontBroadcast)
{
    SwitchPlayers();
} 

SwitchPlayers()
{
    for (new client = 1; client <= MaxClients; client++)
    {
        if(Client_IsValid(client))
        {
            switch(GetClientTeam(client))
            {
                case 2: // Red
                {
                    SetTeam(client, 3);
                }
            
                case 3: // Blue
                {
                    SetTeam(client, 2);
                }
            }
        }
    }
}

stock bool:Client_IsValid(client, bool:checkConnected=true) 
{
    if (client > 4096) client = EntRefToEntIndex (client);
    if (client < 1 || client > MaxClients) return false;
    if ( ! (1 <= client <= MaxClients) || ! IsClientInGame (client)) return false;
    if (checkConnected && ! IsClientConnected (client)) return false
    
    return true
}

stock SetTeam(client, TeamNum)
{
    SDKCall(hSwitchTeam, client, TeamNum);
} 


[Pelipoika]

This TFCond_Reprogrammed condition used to switch a players team to the opposing team on the spot for the duration of the condition, dunno if it still does

[SM9]

Originally Posted by Pelipoika This TFCond_Reprogrammed condition used to switch a players team to the opposing team on the spot for the duration of the condition, dunno if it still does

So do you know possible way to achieve this?

Cheers

[Pelipoika]

Originally Posted by xCoderx So do you know possible way to achieve this? Cheers

What? Just apply the condition i mentioned

[Powerlord]

ChangeClientTeam already calls CTFPlayer::ChangeTeam. The version of ChangeTeam that doesn't kill players seems to be CTFPlayer::ChangeTeam(int, bool, bool) which can only be called via a signature.

Incidentally, the full function name (including arg names) is

void CBasePlayer::ChangeTeam( int iTeamNum, bool bAutoTeam, bool bSilent)

(Note: That's actually the parent of CTFPlayer's version)

[SM9]

Originally Posted by Powerlord ChangeClientTeam already calls CTFPlayer::ChangeTeam. The version of ChangeTeam that doesn't kill players seems to be CTFPlayer::ChangeTeam(int, bool, bool) which can only be called via a signature. Incidentally, the full function name (including arg names) is void CBasePlayer::ChangeTeam( int iTeamNum, bool bAutoTeam, bool bSilent) (Note: That's actually the parent of CTFPlayer's version)

So how would I go about using this? (If possible, I'm not understanding very well)

Thanks

[Bacardi]

Originally Posted by Powerlord void CBasePlayer::ChangeTeam( int iTeamNum, bool bAutoTeam, bool bSilent)

Originally Posted by xCoderx So how would I go about using this? (If possible, I'm not understanding very well) Thanks

When set last bool "silent", it will hide chat announce when player change team.
And yes, this also kill player when change team.

PHP Code:

#include <sdktools>

public OnPluginStart()
{
    RegConsoleCmd("sm_test", test);
}

public Action:test(client, args)
{
// server.so (Linux)    418    CBasePlayer::ChangeTeam(int,bool,bool)

    // CBasePlayer::
    StartPrepSDKCall(SDKCall_Player);

    // 418 (Linux ?) (seems work in Win)
    PrepSDKCall_SetVirtual(418);

    // int
    PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_ByValue);
    // bool
    PrepSDKCall_AddParameter(SDKType_Bool, SDKPass_ByValue);
    // bool
    PrepSDKCall_AddParameter(SDKType_Bool, SDKPass_ByValue);

    // End
    new Handle:hCall= EndPrepSDKCall();

    new team = GetClientTeam(client) == 2 ? 3:2;

    //Call
    //SDKCall(hCall, client, team, false, true);
    SDKCall(hCall, client, team, true, true);

    CloseHandle(hCall);
    return Plugin_Handled;
} 


[Powerlord]

My mistake, it's CTFPlayer::ForceChangeTeam(int, bool) that doesn't kill the player and requires a signature. The int is the team number, the bool is whether to clear dominations or not.

I have some test code for it and some Linux gamedata, but no Windows gamedata. I also haven't touched that in months, so the Linux gamedata may be out of date.

[SM9]

Originally Posted by Powerlord My mistake, it's CTFPlayer::ForceChangeTeam(int, bool) that doesn't kill the player and requires a signature. The int is the team number, the bool is whether to clear dominations or not. I have some test code for it and some Linux gamedata, but no Windows gamedata. I also haven't touched that in months, so the Linux gamedata may be out of date.

This works perfectly! Thankyou.

Also I have found another method here:

PHP Code:

stock ChangeTeam(client, TeamNum)
{
    new EntProp = GetEntProp(client, Prop_Send, "m_lifeState");
    SetEntProp(client, Prop_Send, "m_lifeState", 2);
    ChangeClientTeam(client, TeamNum);
    SetEntProp(client, Prop_Send, "m_lifeState", EntProp);
    
    //SDKCall(g_hForceChangeTeam, client, TeamNum, false);
}