[Bacardi]

I became interested in this conversation and about psychonic answer.

Originally Posted by Bubka3 I don't understand this. What I do understand is I'd have to figure out the default value for each gun which would be annoying at best.

Originally Posted by psychonic Or do an SDKCall to GetMaxClip1 on the weapon.

I haven't use before any SDKCall and don't have knowledge how to set those parameters.
I could have just ask from @psychonic, "How to do it ? Show us !"
Instead of easier way to get answer, I search for it.

Require! Sticky: New IDA VTable Script
examples sm_getkey, GetEyePosition Example

SM plugin source code

PHP Code:

#include <sdktools>

public OnPluginStart()
{
    RegConsoleCmd("sm_test", sm_test);
}

public Action:sm_test(client, args)
{
    if(client == 0 || !IsClientInGame(client))
    {
        return Plugin_Handled;
    }
//        Linux offsets
//        hl2mp
//        311    CBaseCombatWeapon::GetMaxClip1(void)const
//        css
//        311    CBaseCombatWeapon::GetMaxClip1(void)const
//        dod
//        311    CBaseCombatWeapon::GetMaxClip1(void)const
//        tf
//        320    CTFWeaponBase::GetMaxClip1(void)const


    new Handle:gameconf; // gamedata config

    if( (gameconf = LoadGameConfigFile("plugin.test")) == INVALID_HANDLE )
    {
        PrintToServer("LoadGameConfigFile \"plugin.test\" INVALID_HANDLE");
        return Plugin_Handled;
    }

    if(GameConfGetOffset(gameconf, "GetMaxClip1") == -1)
    {
        CloseHandle(gameconf);
        PrintToServer("GameConfGetOffset \"GetMaxClip1\" -1");
        return Plugin_Handled;
    }

    // CBaseCombatWeapon::
    // First SDKCall parameter, entity index (weapon).
    StartPrepSDKCall(SDKCall_Entity);

    // virtual function index (offset)
    //PrepSDKCall_SetVirtual(310); // Use gamedata file instead, OS Win/Linux/Mac
    if(!PrepSDKCall_SetFromConf(gameconf, SDKConf_Virtual, "GetMaxClip1"))
    {
        SetFailState("PrepSDKCall_SetFromConf false, nothing found");
    }
    CloseHandle(gameconf);

    // GetMaxClip1(void)const
    // SDKCall return as integer value.
    PrepSDKCall_SetReturnInfo(SDKType_PlainOldData, SDKPass_ByValue);

    new Handle:hCall= EndPrepSDKCall();

    new weapon_entity_index = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");

    if( weapon_entity_index != -1 )
    {
        new value;
    
        value = SDKCall(hCall, weapon_entity_index);
        PrintToChat(client, "weapon index %i SDKCall GetMaxClip1 return value %i", weapon_entity_index, value);
    }

    CloseHandle(hCall);
    return Plugin_Handled;
} 


- What I quick test, HL2DM, CS:S and DOD:S return right value.
- CSGO and TF2 instead return random value.

This is one method to get weapon max ammount ammo in Clip1.
Another way can be done also..
- when entity created, store in global variable weapon clip1 ammo.
- read weapon script file from server (loose file or inside VPK pack)
- use extensions

Hope one SDKCall tutorial more not cause disapproval

[Powerlord]

Did you check the return value of CBaseCombatWeapon::UsesClipsForAmmo1 before checking CBaseCombatWeapon::GetMaxClip1 / CBaseCombatWeapon::GetDefaultClip1?

[Bacardi]

Originally Posted by Powerlord Did you check the return value of CBaseCombatWeapon::UsesClipsForAmmo1 before checking CBaseCombatWeapon::GetMaxClip1 / CBaseCombatWeapon::GetDefaultClip1?

Nope. I was interested only this, GetMaxClip1 will return -1 if not use any ammo type. (Knife, grenades)

These can be check also with GetEntProp "m_iPrimaryAmmoType"
But if I remember rigth, grenades ammotype clip1 return as 255.

If you meant that ?

*edit
There is also Clip2 which HL2MP weapons use. Maybe dod also. And in cs:s mp5navy use both clip with same ammo (bug)

[h3bus]

Where did you find those functions?

I would be interested in using it, but they aren't listed in the vtable dumper I use http://www.sourcemodplugins.org/vtableoffsets/csgo

Maybe they just don't exist in CSGO

[psychonic]

Originally Posted by h3bus Where did you find those functions? I would be interested in using it, but they aren't listed in the vtable dumper I use http://www.sourcemodplugins.org/vtableoffsets/csgo Maybe they just don't exist in CSGO

They are in the weapon vtable. That site only shows the player vtable.

[Bubka3]

Oh wow, glad I saw this -- I don't know how to do SDK calls