[SpirT]

Hey guys.

If possible I want to know:
- Where the TA Grenade explodes, I want to get the TA Grenade position, as well I would need to get Client Angles,

- Then when it explodes check if client as access to ADMFLAG_RESERVATION

- If yes, then teleport the client to the Grenade position.

Is that possible?

Waiting for your reply and wish you all the best,

SpirT.

[FrAgOrDiE]

yes, you can hook event "tagrenade_detonate": https://wiki.alliedmods.net/Counter-...enade_detonate
you can retreive the position getting x, y and z positions in the event callback: https://sm.alliedmods.net/new-api/events/Event/GetFloat
https://sm.alliedmods.net/new-api/cl...etUserFlagBits for getting user flags. (Check if flag & ADMFLAG_RESERVATION)
then simply teleport with: https://sm.alliedmods.net/new-api/sd...TeleportEntity
Get client angles with https://sm.alliedmods.net/new-api/sd...lientEyeAngles

[Bacardi]

- I don't see event in game when tagrenade_projectile explode or destroyed.
*edit
This is odd. When I hooked event, then it start working in net_showevents 2 :S

Spoiler

PHP Code:

Game Event Fired: tagrenade_detonate
Server event "tagrenade_detonate", Tick 110583:
- "userid" = "12"
- "entityid" = "312"
- "x" = "1442.03"
- "y" = "-1072.23"
- "z" = "-203.54" 


- Start use CheckCommandAccess, it's flexible, not need re-compile plugin or create Convars for "flags".


updated, using event.

PHP Code:

#include <sdktools>


public void OnPluginStart()
{
    HookEventEx("tagrenade_detonate", tagrenade_detonate);
}

public void tagrenade_detonate(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(event.GetInt("userid"));

    if(client == 0) return;

    if(!IsClientInGame(client) || IsFakeClient(client) || GetClientTeam(client) <= 1 || !IsPlayerAlive(client)) return;

    if(!CheckCommandAccess(client, "weapon_tagrenade_teleport", ADMFLAG_RESERVATION)) return;


    // Player eye angle ?
    //float ang[3];
    //GetClientEyeAngles(client, ang);

    float pos[3];
    pos[0] = event.GetFloat("x");
    pos[1] = event.GetFloat("y");
    pos[2] = event.GetFloat("z");
    
    TeleportEntity(client, pos, NULL_VECTOR, NULL_VECTOR);

} 


old

This use SDKHooks. OnEntityDestroyed

PHP Code:

#include <sdkhooks>
#include <sdktools>


public void OnEntityDestroyed(int entity)
{
    if(!HasEntProp(entity, Prop_Send, "m_hThrower")) return;

    char clsname[30];
    if(!GetEntityClassname(entity, clsname, sizeof(clsname))) return;

    if(!StrEqual(clsname, "tagrenade_projectile", false)) return;


    // tagrenade_projectile destroyed

    int client = GetEntPropEnt(entity, Prop_Send, "m_hThrower");

    if(client <= 0 || client > MaxClients) return;

    if(!IsClientInGame(client) || IsFakeClient(client) || GetClientTeam(client) <= 1 || !IsPlayerAlive(client)) return;

    if(!CheckCommandAccess(client, "weapon_tagrenade_teleport", ADMFLAG_RESERVATION)) return;


    // Player eye angle ?
    //float ang[3];
    //GetClientEyeAngles(client, ang);

    float m_vecOrigin[3];
    GetEntPropVector(entity, Prop_Send, "m_vecOrigin", m_vecOrigin);
    
    TeleportEntity(client, m_vecOrigin, NULL_VECTOR, NULL_VECTOR);


}