[anssik]

Very simple addon to use the CS 1.5 knife model in CS 1.6.

Note that only the p_knife_r.mdl needs to be downloaded from server, since v_knife_r.mdl already exist by default in CS1.6 installation but is unused. The w_knife.mdl is still the same 1.5 model in 1.6, so it doesn't need to be changed.

edit: use the code from the post below, as it is more efficient

Also note that while it's supposedly better to hook v_ / p_ model using

PHP Code:

RegisterHam(Ham_Item_Deploy, "weapon_knife", "OnKnifeDeploy", 1) 


It doesn't work with bots or on knife maps. While the event method below always works.

PHP Code:

#include <amxmodx>
#include <engine>

#define PLUGIN "CS 1.5 Knife"
#define VERSION "1.0"
#define AUTHOR "kebabstorm"

#pragma semicolon 1

new const V_KNIFE_R[] = "models/v_knife_r.mdl";
new const P_KNIFE_R[] = "models/p_knife_r.mdl";

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    register_event("CurWeapon", "EV_CurWeapon", "be", "1=1");
}

public plugin_precache()
{
    precache_model(V_KNIFE_R);
    precache_model(P_KNIFE_R);
}

public EV_CurWeapon(player)
{
    if (get_user_weapon(player) == CSW_KNIFE) {
        entity_set_string(player, EV_SZ_viewmodel, V_KNIFE_R);
        entity_set_string(player, EV_SZ_weaponmodel, P_KNIFE_R);
    }
} 


[WATCH_D0GS UNITED]

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "CS 1.5 Knife"
#define VERSION "1.1"
#define AUTHOR "kebabstorm"

new const V_KNIFE_R[] = "models/v_knife_r.mdl"
new const P_KNIFE_R[] = "models/p_knife_r.mdl"

static iPlayer
static iWeapon

public plugin_init() {
        register_plugin(PLUGIN, VERSION, AUTHOR);
        RegisterHam(Ham_Item_Deploy,"weapon_knife","OnKnifeDeployPost",1)
}

public plugin_precache() {
        precache_model(V_KNIFE_R)
        precache_model(P_KNIFE_R)
}

public OnKnifeDeployPost(ent) {
        iPlayer = get_pdata_cbase(ent,41)
        iWeapon = get_pdata_int(ent,43)
        if(iWeapon == CSW_KNIFE) {
                set_pev(iPlayer, pev_viewmodel2, V_KNIFE_R)
                set_pev(iPlayer, pev_weaponmodel2, P_KNIFE_R)
        }
} 


Thanks for sharing!
Have a nice day.

[HamletEagle]

Please do not use CurWeapon to set weapon models. Use Ham_Item_Deploy.

To make it work with bots, look into RegisterHamFromEntity and provide a bot id, or if you are using amxx 1.9+, there are two easier solutions: set the last argument of RegisterHam called specialbot to true or use RegisterHamPlayer.

There should be no difference for knife maps, a knife is a knife and it is deployed in the same way no matter the map.

[Jhob94]

There are some problems that will cause the model not change on item deploy but it’s always a programmer mistake.

If you use multiple model plugins to change the model of the same weapon you may encounter this “bug”. It isn’t really a bug just a bad server management.

Also, and derailing topic, i guy once asked me help because on Basebuilder a m4 model would display on Knife model. I guess it’s the fast weapon change that bb plugin causes on build time. At the time I didn’t had the opportunity to help the guy fixing but yeah. Item deploy despite reliable must be used carefully if you run multiple plugins with it.

[anssik]

@WATCH_D0GS UNITED

This version seems to indeed work correctly, even with bots and on knife maps.
So the problem was using Ham_Item_Deploy and then entity_set_string, which doesn't work correctly; by using set_pev it works. Thanks.

[metal_upa]

ReAPI method:

PHP Code:

#include <amxmodx>
#include <reapi>

new const szModelP[] = "models/p_knife_r.mdl";
new const szModelV[] = "models/v_knife_r.mdl";

public plugin_precache()
{
    precache_model(szModelP);
    precache_model(szModelV);
}

public plugin_init()
{
    register_plugin("Knife Skin", "0.0.1", "metal_upa");
    RegisterHookChain(RG_CBasePlayerWeapon_DefaultDeploy, "OnDefaultDeployPre", 0);
}

public OnDefaultDeployPre(const ent, szViewModel[], szWeaponModel[], iAnim, szAnimExt[], skiplocal)
{
    #pragma unused iAnim, szAnimExt, skiplocal
    if(!is_entity(ent)) return HC_CONTINUE;

    if(get_member(ent, m_iId) == WEAPON_KNIFE)
    {
        SetHookChainArg(2, ATYPE_STRING, szModelV);
        SetHookChainArg(3, ATYPE_STRING, szModelP);
    }

    return HC_CONTINUE;
}