[edon1337]

Hi,

What needs to be done so an entity can levitate in the sky and move towards a destination and all the players to be in that entity and move along with it? Basically the entity is an airplane.

Just as new round starts the entity should be spawned and all the players put in it and to follow it.
Here's a demonstration picture: https://ibb.co/e6RVUJ

Here's the code I made but it just spawns the Airplane but it doesn't move, and I don't get attached to the airplane, so I just fall down.

PHP Code:

#include < amxmodx >
#include < hamsandwich >
#include < fakemeta >
#include < engine >

#define AIRPLANE_CLASSNAME "ent_airplane"

new bool:g_bPlayerInPlane[ 33 ];

new g_iAirPlaneEnt;

public plugin_init( )
{
    register_logevent( "OnNewRound", 2, "1=Round_Start" );

    RegisterHam( Ham_Think, "info_target", "@HamThinkInfoTarget_Pre", 0 );
    RegisterHam( Ham_Player_Jump, "player", "@HamPlayerJump_Post", 1 );
    RegisterHam( Ham_Player_PreThink, "player", "@HamThinkPlayer_Pre", 0 );
}

public @HamPlayerJump_Post( id )
{
    if( ! g_bPlayerInPlane[ id ] )
    return HAM_IGNORED;

    set_pev( id, pev_movetype, MOVETYPE_TOSS );
    set_pev( id, pev_gravity, 10.0 );

    g_bPlayerInPlane[ id ] = false;
        
    return HAM_IGNORED;
}


public OnNewRound( )
{
    MakeAirPlane( );
}

public @HamThinkInfoTarget_Pre( iEnt )
{
    if( ! pev_valid( iEnt ) )
    return HAM_IGNORED;
    
    new szClassName[ 32 ];
    pev( iEnt, pev_classname, szClassName, charsmax( szClassName ) );

    static Float:fVelocity[ 3 ]; 
    pev( iEnt, pev_velocity, fVelocity );
    
    if( equal( szClassName, AIRPLANE_CLASSNAME ) )
    {
        set_pev( iEnt, pev_nextthink, get_gametime( ) + 0.01 );
        
        velocity_by_aim( iEnt, 1, fVelocity );
    }
    
    return HAM_IGNORED;
}

public @HamThinkPlayer_Pre( id )
{
    if( ! is_user_alive( id ) )
    return HAM_IGNORED;
        
    if( g_bPlayerInPlane[ id ] )
    {
        new Float:fAirPlaneLocation[ 3 ];
        pev( g_iAirPlaneEnt, pev_origin, fAirPlaneLocation );
        
        set_pev( id, pev_origin, fAirPlaneLocation );
    }
    
    return HAM_IGNORED;
}

MakeAirPlane( )
{  
    new Float:fOrigin[ 3 ] = { 3753.0, -23.0, 3316.0 };
    new Float:fAngle[ 3 ] = { -20.3, -175.9, 0.0 };
    
    g_iAirPlaneEnt = create_entity( "info_target" );
    
    set_pev( g_iAirPlaneEnt, pev_classname, AIRPLANE_CLASSNAME );
    engfunc( EngFunc_SetModel, g_iAirPlaneEnt, "models/AirPlane.mdl" );
    set_pev( g_iAirPlaneEnt, pev_solid, SOLID_BBOX );
    set_pev( g_iAirPlaneEnt, pev_movetype, MOVETYPE_NOCLIP );
    set_pev( g_iAirPlaneEnt, pev_origin, fOrigin );
    
    engfunc( EngFunc_DropToFloor, g_iAirPlaneEnt );
    
    set_pev( g_iAirPlaneEnt, pev_nextthink, get_gametime( ) + 0.01 );
    
    new szPlayers[ 32 ], iNum, iTempID;
    get_players( szPlayers, iNum, "a" );
    
    for( new i; i < iNum; i++ )
    {
        iTempID = szPlayers[ i ];
        
        set_pev( iTempID, pev_solid, SOLID_NOT );
        set_pev( iTempID, pev_origin, fOrigin );
        set_pev( iTempID, pev_angles, fAngle );
    }
} 


Thanks for any help!

[Ghosted]

You fall cause that airplane is BBOX but has not set size and if u set size you get cube like box. And if your airplane has interior than making such thing is impossible (let players in) except making it with bsp model (maybe).

[Natsheh]

Movetype_noclip

>>

movetype_fly


Also remove EngFunc_DropToFloor

[edon1337]

Originally Posted by Ghosted You fall cause that airplane is BBOX but has not set size and if u set size you get cube like box. And if your airplane has interior than making such thing is impossible (let players in) except making it with bsp model (maybe).

Yeah, you're right. I'm not planning to actually let players get in the plane, they should just be somewhere attached to it and move along with it.
This is what I'm trying to achieve
https://ibb.co/muCw3d

Originally Posted by Natsheh Movetype_noclip >> movetype_fly Also remove EngFunc_DropToFloor

Still the same

[maqi]

The entity won't move on it's own, you have to set it's velocity. Also do what Natsheh said, or nothing will probably work

For attaching the players:
You can try something like attach_view() to simulate what you are trying to achieve. It's a good solution, except the camera won't be movable before jumping ( seet the player origin to the plane and reset the view ). The alternative would be to match the player origin and velocity with the plane, that should work. ( not 100% sure ). Other than that you can try to set the view manually somehow or actually set the origin of a player, but i figure those would be clunky if not done properly.

Also, demonstration 10/10

[EFFx]

I don't know what you mean with levitate, but you can just set the plane:

- Origin
- View angle (to the direction)
- And pev_velocity

For make players follow the plane, you just need set them the same vectors of the plane and set their gravity and maxspeed to 0. (can't fall and can't move inside the plane).

That's the code I'm using on my Battleground to create the plane:

PHP Code:

public createPlane()
{
    new Float:fOrigin[3], Float:fAngle[3], Float:fVelocity[3]
    getRandomPlaneDirection(fOrigin, fAngle, fVelocity) //the code that gets four random directions

    new iEnt = fm_create_entity("info_target")
    fm_create_ent
    (
        iEnt, 
        g_szClassNamesData[cTransporter], 
        g_szModelsData[mTransporter], 
        fOrigin,
        fVelocity,
        fAngle
    ) // code to create the plane
    
    g_bPlaneSpanwed = true
    g_iEnt[pPlaneTransporter] = iEnt
    fOrigin[2] -= 40.0 // players under the plane.
    
    new iPlayers[MAX_PLAYERS], iNum
    get_players(iPlayers, iNum, "ach")
    for(new i, id;i < iNum;i++)
    {
        id = iPlayers[i]
        
        setInvisibility(id, true) // for players can't be seen by their enemies.
        client_cmd(id, "spk ^"%s^"", g_szSoundsData[sTransporter]) // sound of the plane
        
                //here are all vectors for players be able to follow the plane
        set_pev(id, pev_origin, fOrigin) // Same origin of the plane
        set_pev(id, pev_angles, fAngle) // Same direction of the plane
        set_pev(id, pev_fixangle, 1) // Fix the angle 
        set_pev(id, pev_velocity, fVelocity) // Same velocity of the plane
        set_pev(id, pev_gravity, 0.000001) //Can't fall
        set_pev(id, pev_maxspeed, 0.000001) //Can't move

              // some booleans to use later.
        g_dUserData[id][bIsOnPlane] = true
        g_dUserData[id][bCanUseParachute] = false
    }
    
        // to remove the plane
    set_task(PLANE_REMOVE_TIME, "checkPlaneOrigin", TASK_PLANE)
} 


[edon1337]

Originally Posted by maqi The entity won't move on it's own, you have to set it's velocity. Also do what Natsheh said, or nothing will probably work For attaching the players: You can try something like attach_view() to simulate what you are trying to achieve. It's a good solution, except the camera won't be movable before jumping ( seet the player origin to the plane and reset the view ). The alternative would be to match the player origin and velocity with the plane, that should work. ( not 100% sure ). Other than that you can try to set the view manually somehow or actually set the origin of a player, but i figure those would be clunky if not done properly. Also, demonstration 10/10

If you checked the code, you'd see I'm constantly changing the velocity.
I don't need to attach the view, I need to attach the entire entity.
Again, if you checked the code you'd see I'm settings players' origin at plane's origin.

Originally Posted by EFFx I don't know what you mean with levitate, but you can just set the plane: - Origin - View angle (to the direction) - And pev_velocity For make players follow the plane, you just need set them the same vectors of the plane and set their gravity and maxspeed to 0. (can't fall and can't move inside the plane). That's the code I'm using on my Battleground to create the plane: PHP Code: public createPlane() {     new Float:fOrigin[3], Float:fAngle[3], Float:fVelocity[3]     getRandomPlaneDirection(fOrigin, fAngle, fVelocity) //the code that gets four random directions     new iEnt = fm_create_entity("info_target")     fm_create_ent     (         iEnt,          g_szClassNamesData[cTransporter],          g_szModelsData[mTransporter],          fOrigin,         fVelocity,         fAngle     ) // code to create the plane          g_bPlaneSpanwed = true     g_iEnt[pPlaneTransporter] = iEnt     fOrigin[2] -= 40.0 // players under the plane.          new iPlayers[MAX_PLAYERS], iNum     get_players(iPlayers, iNum, "ach")     for(new i, id;i < iNum;i++)     {         id = iPlayers[i]                  setInvisibility(id, true) // for players can't be seen by their enemies.         client_cmd(id, "spk ^"%s^"", g_szSoundsData[sTransporter]) // sound of the plane                          //here are all vectors for players be able to follow the plane         set_pev(id, pev_origin, fOrigin) // Same origin of the plane         set_pev(id, pev_angles, fAngle) // Same direction of the plane         set_pev(id, pev_fixangle, 1) // Fix the angle          set_pev(id, pev_velocity, fVelocity) // Same velocity of the plane         set_pev(id, pev_gravity, 0.000001) //Can't fall         set_pev(id, pev_maxspeed, 0.000001) //Can't move               // some booleans to use later.         g_dUserData[id][bIsOnPlane] = true         g_dUserData[id][bCanUseParachute] = false     }              // to remove the plane     set_task(PLANE_REMOVE_TIME, "checkPlaneOrigin", TASK_PLANE) }

Levitate = stay in air

Thanks I'll check it out

[Natsheh]

Edon

"constantly changing the velocity."

This doesnt make sense.

[edon1337]

Originally Posted by Natsheh Edon "constantly changing the velocity." This doesnt make sense.

Don't you need to keep adding velocity to something that you want to move?

[klippy]

You aren't changing it though. velocity_by_aim doesn't set the velocity. Also to change entity's (and player's) position use EngFunc_SetOrigin, not pev_origin.
Whether you need to keep adding velocity depends on the movetype. I believe that for MOVETYPE_FLY you don't as it isn't affected by friction, setting it once should be alright.