[ImYourBro]

Hello!

I tried to make a this mod and i finally finished it!

<Description>:
This is a gamemode. Its Human(CT) vs. Furien(T). Furiens have some nice features (Features below). Human is team which have to defeat the furiens with guns.

<Features>:

• Shop Included for Humans and Furiens
• Furien Invisible while not moving and knife in hand.
• Furien Increased movement speed and gravity.
• Round Start kit for Humans and Furiens.
  - Humans = Gun Menu
  - Furiens = Grenades
• Round Start Money

<CVARS>:

• furien_Invisible_Enable(Deafult: 1) - Enables/Disables the invisible ability for Furiens.
• furien_roundmoney(Default: 16000) - The amount of money you get each round.
• furien_maxspeed(Default: 800.0) - Sets the speed of furiens (ALWAYS BE A FLOAT VALUE)
• furien_gravity(Default: 0.3) - Sets the gravity of furiens (ALWAYS BE A FLOAT VALUE)
  
  Shop:
  
• furienshop_enable(Default: 1) - Enables/Disables the shop for humans and furiens.
• furienshop_HEcost(Default: 4000) - Sets the cost of HE Grenade
• furienshop_Flashcost(Default: 2000) - Sets the cost of Flashbang
• furienshop_Smokecost(Default: 1000) - Sets the cost of Smoke Grenade
• furienshop_SuperKnifecost(Default: 12000) - Sets the cost of SuperKnife for Furiens
• furienshop_SuperDeaglecost(Default: 12000) - Sets the cost of Super Deagle for Humans
• furienshop_m249cost(Default: 12000) - Sets the cost of M249 for Humans
• furienshop_HPT25cost(Default: 2000) - Sets the cost of 25+ HP for Furiens
• furienshop_HPT50cost(Default: 4000) - Sets the cost of 50+ HP for Furiens
• furienshop_HPCT25cost(Default: 2000) - Sets the cost of 25+ HP for Humans
• furienshop_HPCT50cost(Default: 4000) - Sets the cost of 50+ HP for Humans
• furienshop_Armorcost(Default: 4000) - Sets the cost of Armor.
  

<CREDITS>:

• OciXCrom for explaining fix in my codes.
• Bugsy for explaining fix in my codes.
• Napoleon_be for helping with codes and explaining.
• indraraj striker for helping with codes and explaining
• Hamlet Eagle for inspiration for Invisible code.
• EFFx for detecting some unnecessary code.

<CHANGELOG>:

Spoiler

v0.1: Code made and fixed errors and warnings.
v0.2: Code updated and removed some unnecessary code. Thanks to EFFx
v0.3: Fixed the Super Knife and Super Deagle damage.

[EFFx]

PHP Code:

SetHamParamFloat(4, damage * 20.4) 


LOL

[ImYourBro]

Originally Posted by EFFx PHP Code: SetHamParamFloat(4, damage * 20.4)  LOL

Didnt even notice that lol.

Code updated.

[EFFx]

I'll give suggestions for you, but they will not make the plugin be approved.

1.

PHP Code:

public Player_Spawn(id)
{    
    if (!is_user_alive(id))
    {
        return HAM_IGNORED;
    }
    else
    {
        ColorChat(id, DontChange, "%s ^1Write ^4/shop ^1to open the shop menu!", prefix)
        g_bHasSuperKnife[id] = false;
        g_bHasSuperDeagle[id] = false;
        if(cs_get_user_team(id) == CS_TEAM_T)
        {
            set_user_maxspeed(id , get_pcvar_float(pMaxSpeed))
            set_user_gravity(id, get_pcvar_float(pGravity))
            set_user_footsteps(id, 0)
        }
    }
    return HAM_SUPERCEDE
} 


- >

PHP Code:

public Player_Spawn(id)
{    
    if(is_user_alive(id))
    {
        ColorChat(id, DontChange, "%s ^1Write ^4/shop ^1to open the shop menu!", prefix)
        g_bHasSuperKnife[id] = false;
        g_bHasSuperDeagle[id] = false;
    }
} 


2.

PHP Code:

public gunMenu(id)
{
    new Players[32], iNum, id;
    get_players(Players, iNum, "ah")
    while ( --iNum >= 0)
    {
        id = Players[iNum]
        switch(cs_get_user_team(id))
        {
            case CS_TEAM_CT:
            {
                strip_user_weapons(id)
                give_item(id, "weapon_knife")
                
                primaryguns(id)
            }
            case CS_TEAM_T:
            {
                strip_user_weapons(id)
                give_item(id, "weapon_knife")
                give_item(id, "weapon_hegrenade")
                give_item(id, "weapon_flashbang")
                give_item(id, "weapon_smokegrenade")
            }
        }
    } 
} 


For what (id) at the public if you has created new id = Players[iNum] ?

Do it:

Delete this

PHP Code:

register_logevent("gunMenu", 2, "1=Round_Start") 


And at Player_Spawn()

PHP Code:

        strip_user_weapons(id)
        give_item(id, "weapon_knife")
        switch(cs_get_user_team(id))
        {
            case CS_TEAM_CT:
            {
                primaryguns(id)
                set_user_footsteps(id, 1)
            }
            case CS_TEAM_T:
            {
                give_item(id, "weapon_hegrenade")
                give_item(id, "weapon_flashbang")
                give_item(id, "weapon_smokegrenade")
            }
        } 


Like this

PHP Code:

public Player_Spawn(id)
{    
    if(is_user_alive(id))
    {
        strip_user_weapons(id)
        give_item(id, "weapon_knife")
        switch(cs_get_user_team(id))
        {
            case CS_TEAM_CT:
            {
                primaryguns(id)
                set_user_footsteps(id, 1)
            }
            case CS_TEAM_T:
            {
                give_item(id, "weapon_hegrenade")
                give_item(id, "weapon_flashbang")
                give_item(id, "weapon_smokegrenade")
                set_user_maxspeed(id , get_pcvar_float(pMaxSpeed))
                set_user_gravity(id, get_pcvar_float(pGravity))
                set_user_footsteps(id, 0)
            }
        }
        ColorChat(id, DontChange, "%s ^1Write ^4/shop ^1to open the shop menu!", prefix)
        g_bHasSuperKnife[id] = false;
        g_bHasSuperDeagle[id] = false;
    }
} 


3.

Add checks for see if the player has already X item.
If they will buy HP but has selected the Super Knife ? Add a check for it.

PHP Code:

            if ( iMoney >= get_pcvar_num(g_pCvarSuperCutCost))
            {
                cs_set_user_money(id, iMoney - get_pcvar_num(g_pCvarSuperCutCost));
                g_bHasSuperKnife[id] = true;
                give_item(id, "weapon_knife");
                ColorChat(id, DontChange, "%s ^1You just bought ^3SuperKnife ^1for ^4%d", prefix, get_pcvar_num(g_pCvarSuperCutCost))
            }
            else
            {
                ColorChat(id, DontChange, "%s You do not have enough ^4money!", prefix)
            } 


- >

PHP Code:

            if ( iMoney >= get_pcvar_num(g_pCvarSuperCutCost))
            {
                if(!g_bHasSuperKnife[id])
                {
                    cs_set_user_money(id, iMoney - get_pcvar_num(g_pCvarSuperCutCost));
                    g_bHasSuperKnife[id] = true;
                    give_item(id, "weapon_knife");
                    ColorChat(id, DontChange, "%s ^1You just bought ^3SuperKnife ^1for ^4%d", prefix,         get_pcvar_num(g_pCvarSuperCutCost))
                }
                else
                {
                    ColorChat(id,DontChange,"%s ^1You already have ^3SuperKnife^1",prefix)
                }
            }
            else
            {
                ColorChat(id, DontChange, "%s You do not have enough ^4money!", prefix)
            } 


Make the same for Deagle.

4. I think the roundMoney(id) will not be good in your furien. I suggest to you delete it too and update your code. I cant understand the invisibility o.O

PHP Code:

public CBaseEntity_Think(Entity)
{
    if(get_pcvar_num(g_CvarInvisEnable) == 1 && pev_valid(Entity))
    {
        static Players[32], Num, id, bool:RestorePlayerVisibility, i
        static Float:PlayerVelocity[3], Float:PlayerSpeed
        
        get_players(Players, Num, "ach")
        
        for(i = 0; i < Num; i++)
        {
            RestorePlayerVisibility = false
            id = Players[i]
            
            if(get_user_weapon(id) == CSW_KNIFE && cs_get_user_team(id) == CS_TEAM_T)
            {
                pev(id, pev_velocity, PlayerVelocity)
                PlayerSpeed = vector_length(PlayerVelocity)
                
                if(!PlayerSpeed)
                {
                    set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransTexture, 0)
                }
                else 
                {
                    RestorePlayerVisibility = true
                }
            }
            else 
            {
                RestorePlayerVisibility = true 
            }
            if(RestorePlayerVisibility)
            {
                set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
            }
        }
        set_pev(Entity, pev_nextthink, get_gametime() + 0.1)
    }
} 


For what the RestorePlayerVisibility ?? Just add the set_user_rendering() to normal and gg.
->

PHP Code:

public CBaseEntity_Think(Entity)
{
    if(pev_valid(Entity))
    {
        static Players[32], Num, id, i
        static Float:PlayerVelocity[3], Float:PlayerSpeed
        
        get_players(Players, Num, "ach")
        
        for(i = 0; i < Num; i++)
        {
            id = Players[i]
            
            if(get_user_weapon(id) == CSW_KNIFE && cs_get_user_team(id) == CS_TEAM_T)
            {
                pev(id, pev_velocity, PlayerVelocity)
                PlayerSpeed = vector_length(PlayerVelocity)
                
                if(!PlayerSpeed)
                {
                    set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransTexture, 0)
                }
                else 
                {
                    set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
                }
            }
            else 
            {
                set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)
            }
        }
        set_pev(Entity, pev_nextthink, get_gametime() + 0.1)
    }
} 


5. For what cvar for deactive/active invisibility? What's the chance for it be good? Without it, the mod will not be furien mod.

[ImYourBro]

Originally Posted by EFFx I'll give suggestions for you, but they will not make the plugin be approved. 1. PHP Code: public Player_Spawn(id) {         if (!is_user_alive(id))     {         return HAM_IGNORED;     }     else     {         ColorChat(id, DontChange, "%s ^1Write ^4/shop ^1to open the shop menu!", prefix)         g_bHasSuperKnife[id] = false;         g_bHasSuperDeagle[id] = false;         if(cs_get_user_team(id) == CS_TEAM_T)         {             set_user_maxspeed(id , get_pcvar_float(pMaxSpeed))             set_user_gravity(id, get_pcvar_float(pGravity))             set_user_footsteps(id, 0)         }     }     return HAM_SUPERCEDE }  - > PHP Code: public Player_Spawn(id) {         if(is_user_alive(id))     {         ColorChat(id, DontChange, "%s ^1Write ^4/shop ^1to open the shop menu!", prefix)         g_bHasSuperKnife[id] = false;         g_bHasSuperDeagle[id] = false;     } }  2. PHP Code: public gunMenu(id) {     new Players[32], iNum, id;     get_players(Players, iNum, "ah")     while ( --iNum >= 0)     {         id = Players[iNum]         switch(cs_get_user_team(id))         {             case CS_TEAM_CT:             {                 strip_user_weapons(id)                 give_item(id, "weapon_knife")                                  primaryguns(id)             }             case CS_TEAM_T:             {                 strip_user_weapons(id)                 give_item(id, "weapon_knife")                 give_item(id, "weapon_hegrenade")                 give_item(id, "weapon_flashbang")                 give_item(id, "weapon_smokegrenade")             }         }     }  }  For what (id) at the public if you has created new id = Players[iNum] ? Do it: Delete this PHP Code: register_logevent("gunMenu", 2, "1=Round_Start")  And at Player_Spawn() PHP Code:         strip_user_weapons(id)         give_item(id, "weapon_knife")         switch(cs_get_user_team(id))         {             case CS_TEAM_CT:             {                 primaryguns(id)                 set_user_footsteps(id, 1)             }             case CS_TEAM_T:             {                 give_item(id, "weapon_hegrenade")                 give_item(id, "weapon_flashbang")                 give_item(id, "weapon_smokegrenade")             }         }  Like this PHP Code: public Player_Spawn(id) {         if(is_user_alive(id))     {         strip_user_weapons(id)         give_item(id, "weapon_knife")         switch(cs_get_user_team(id))         {             case CS_TEAM_CT:             {                 primaryguns(id)                 set_user_footsteps(id, 1)             }             case CS_TEAM_T:             {                 give_item(id, "weapon_hegrenade")                 give_item(id, "weapon_flashbang")                 give_item(id, "weapon_smokegrenade")                 set_user_maxspeed(id , get_pcvar_float(pMaxSpeed))                 set_user_gravity(id, get_pcvar_float(pGravity))                 set_user_footsteps(id, 0)             }         }         ColorChat(id, DontChange, "%s ^1Write ^4/shop ^1to open the shop menu!", prefix)         g_bHasSuperKnife[id] = false;         g_bHasSuperDeagle[id] = false;     } }  3. Add checks for see if the player has already X item. If they will buy HP but has selected the Super Knife ? Add a check for it. PHP Code:             if ( iMoney >= get_pcvar_num(g_pCvarSuperCutCost))             {                 cs_set_user_money(id, iMoney - get_pcvar_num(g_pCvarSuperCutCost));                 g_bHasSuperKnife[id] = true;                 give_item(id, "weapon_knife");                 ColorChat(id, DontChange, "%s ^1You just bought ^3SuperKnife ^1for ^4%d", prefix, get_pcvar_num(g_pCvarSuperCutCost))             }             else             {                 ColorChat(id, DontChange, "%s You do not have enough ^4money!", prefix)             }  - > PHP Code:             if ( iMoney >= get_pcvar_num(g_pCvarSuperCutCost))             {                 if(!g_bHasSuperKnife[id])                 {                     cs_set_user_money(id, iMoney - get_pcvar_num(g_pCvarSuperCutCost));                     g_bHasSuperKnife[id] = true;                     give_item(id, "weapon_knife");                     ColorChat(id, DontChange, "%s ^1You just bought ^3SuperKnife ^1for ^4%d", prefix,         get_pcvar_num(g_pCvarSuperCutCost))                 }                 else                 {                     ColorChat(id,DontChange,"%s ^1You already have ^3SuperKnife^1",prefix)                 }             }             else             {                 ColorChat(id, DontChange, "%s You do not have enough ^4money!", prefix)             }  Make the same for Deagle. 4. I think the roundMoney(id) will not be good in your furien. I suggest to you delete it too and update your code. I cant understand the invisibility o.O PHP Code: public CBaseEntity_Think(Entity) {     if(get_pcvar_num(g_CvarInvisEnable) == 1 && pev_valid(Entity))     {         static Players[32], Num, id, bool:RestorePlayerVisibility, i         static Float:PlayerVelocity[3], Float:PlayerSpeed                  get_players(Players, Num, "ach")                  for(i = 0; i < Num; i++)         {             RestorePlayerVisibility = false             id = Players[i]                          if(get_user_weapon(id) == CSW_KNIFE && cs_get_user_team(id) == CS_TEAM_T)             {                 pev(id, pev_velocity, PlayerVelocity)                 PlayerSpeed = vector_length(PlayerVelocity)                                  if(!PlayerSpeed)                 {                     set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransTexture, 0)                 }                 else                  {                     RestorePlayerVisibility = true                 }             }             else              {                 RestorePlayerVisibility = true              }             if(RestorePlayerVisibility)             {                 set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)             }         }         set_pev(Entity, pev_nextthink, get_gametime() + 0.1)     } }  For what the RestorePlayerVisibility ?? Just add the set_user_rendering() to normal and gg. -> PHP Code: public CBaseEntity_Think(Entity) {     if(pev_valid(Entity))     {         static Players[32], Num, id, i         static Float:PlayerVelocity[3], Float:PlayerSpeed                  get_players(Players, Num, "ach")                  for(i = 0; i < Num; i++)         {             id = Players[i]                          if(get_user_weapon(id) == CSW_KNIFE && cs_get_user_team(id) == CS_TEAM_T)             {                 pev(id, pev_velocity, PlayerVelocity)                 PlayerSpeed = vector_length(PlayerVelocity)                                  if(!PlayerSpeed)                 {                     set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderTransTexture, 0)                 }                 else                  {                     set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)                 }             }             else              {                 set_user_rendering(id, kRenderFxNone, 0, 0, 0, kRenderNormal, 0)             }         }         set_pev(Entity, pev_nextthink, get_gametime() + 0.1)     } }  5. For what cvar for deactive/active invisibility? What's the chance for it be good? Without it, the mod will not be furien mod.

Im learning it right now, but thanks for seeing these things.

Code updated

[EFFx]

Originally Posted by ImYourBro Im learning it right now, but thanks for seeing these things. Code updated

Where is the update?

[Napoleon_be]

Does everything work as it should be? Not to be rude, but i doubt it.

1) As EFFx said, you don't use checks to see wether a player already has selected something from the menu or not...

2) Also, menu items should start with the key string "1", allthough entering a key is not even nessecary. also i don't see why you formatex for things like this

PHP Code:

formatex(Text, charsmax(Text), "\wAK47") 


You could easily save CPU usage by deleting an array and just add the item like this

PHP Code:

menu_additem(menuPrim, "\wAK47") 


3) Secondguns can easily be called at the end of your handler and not in every case.

4) I see you have some indentation problems in your plugin initiate which leads to a copy/paste action in my eyes

5) Your public ShopHandle(id) function contains 2 menu's. I think they could be stored in a constant two-dimensional array and loop trough them to add these items..

example:

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "New Plug-In"
#define VERSION "1.0"
#define AUTHOR "author"

new const szMenuItems[][] = {
    "Item 1",
    "Item 2",
    "Item 3",
    "Item 4",
    "Item 5"
}

new const iMenuCosts[][] = {
    50,
    100,
    200,
    300,
    400
}

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_clcmd("say /menu", "CmdMenu")
}

public CmdMenu(id) {
    new szTemp[150]
    
    new menu = menu_create("Menu Title", "menu_handler")
    
    for(new i; i < sizeof(szMenuItems); i++) {
        formatex(szTemp, charsmax(szTemp), "%s [%i]", szMenuItems[i], iMenuCosts[i])
        menu_additem(menu, szTemp)
    }
    menu_display(id, menu)
}

public menu_handler(id, menu, item) {
    // Handle it
} 


[EFFx]

Removing Kb from your code Napoleon:

PHP Code:

enum _:MenuSett
{
     ItemName[50],
     ItemCost
}
new const szMenuItems[][MenuSett] = 
{
    { "Item 1", 3000 },
    { "Item 2", 4000 },
    { "Item 3", 2000 },
    { "Item 4", 1000 },
    { "Item 5", 6000 }
} 


Will be like this

PHP Code:

#include <amxmodx>
#include <cstrike>

#define PLUGIN "Menu Sett"
#define VERSION "1.0"
#define AUTHOR "EFFx"

enum _:MenuSett
{
     ItemName[50],
     ItemCost
}
new const szMenuItems[][MenuSett] = 
{
    { "Item 1", 3000 },
    { "Item 2", 4000 },
    { "Item 3", 2000 },
    { "Item 4", 1000 },
    { "Item 5", 6000 }
}


public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /Item","szItem")
}
public szItem(id)
{
    new szItems[45], menu
    
    menu = menu_create("Menu Settings","menu_set_handler")
    
    for(new i; i < sizeof szMenuItems;i++)
    {
        formatex(szItems,charsmax(szItems),"%s",szMenuItems[i][ItemName])
        menu_additem(menu,szItems)
    }
    
    menu_display(id,menu)
}
public menu_set_handler(id,menu,item)
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu)
        return 0
    }
    new iMoney = cs_get_user_money(id)
    if(iMoney >= szMenuItems[item][ItemCost])
    {
        switch(item)
        {
            case 0: // Item 1
            {
                cs_set_user_money(id, iMoney - szMenuItems[item][ItemCost])
            }
            case 1: // Item 2
            {
                cs_set_user_money(id, iMoney - szMenuItems[item][ItemCost])
            }
            case 2: // Item 3
            {
                cs_set_user_money(id, iMoney - szMenuItems[item][ItemCost])
            }
            case 3: // Item 4
            {
                cs_set_user_money(id, iMoney - szMenuItems[item][ItemCost])
            }
            case 4: // Item 5
            {
                cs_set_user_money(id, iMoney - szMenuItems[item][ItemCost])
            }
        }
        szItem(id)
    }
    else
    {
        client_print(id,print_chat,"[AMXX]: You have not money!")
    }
    return 0
} 


[Napoleon_be]

Originally Posted by EFFx Removing Kb from your code Napoleon: PHP Code: enum _:MenuSett {      ItemName[50],      ItemCost } new const szMenuItems[][MenuSett] =  {     { "Item 1", 3000 },     { "Item 2", 4000 },     { "Item 3", 2000 },     { "Item 4", 1000 },     { "Item 5", 6000 } }  For check if the player have money to buy: PHP Code: if(cs_get_user_money(id) >= szMenuItems[item][ItemCost])  For take price: PHP Code: cs_set_user_money(id, cs_get_user_money(id) - szMenuItems[item][ItemCost])

You should also explain how you're going to format this.

[EFFx]

Updated my suggest, look again.