[benmassey]

hey guys i needa plugin that blocks switch theams
i mean , whhen player join to my server if he join ct he cant move t
and if he disconnected from the server and connect again he will be ct again

any help???

[Bacardi]

And this if or CSGO or CSS ?

[benmassey]

Originally Posted by Bacardi And this if or CSGO or CSS ?

oh im sorry csgo

[LenHard]

AddCommandListener "jointeam" and cookies (for team index)

[benmassey]

Originally Posted by LenHard AddCommandListener "jointeam" and cookies (for team index)

where do i do it

[potatoz]

untested but should do the trick, if the client is in either CT or T he will be blocked from picking another team. you could develop it further by adding the command arguments, where arg #1 is the target team, should you for instance still want to allow moving to spectators

PHP Code:

#include <sourcemod>
#include <sdktools>
#pragma semicolon 1

#define VERSION "1.0b"

public Plugin:myinfo =
{
    name = "block teamchange",
    author = "potatoz",
    description = "",
    version = VERSION,
    url = ""
};

public OnPluginStart()
{
    AddCommandListener(Command_JoinTeam, "jointeam");
}

public Action Command_JoinTeam(int client, char[] command, int args)
{
    if(!client || !IsClientInGame(client))
        return Plugin_Continue;

    if(GetClientTeam(client) > 1)
        return Plugin_Handled;

    return Plugin_Continue;
} 


[Bacardi]

I leave here my version, I have only tested in CSGO.

I was looking and testing wierd bugs or behavier when autoteambalance kick in and when player connect to server plaa plaa plaa.


This plugin is disabled by default:
sm_stop_jointeam 0

To enable type sm_cvar sm_stop_jointeam 1
- Then this plugin stay enabled until server shutdown or someone change it back 0
- To enable this plugin automatically when server launch, add cvar in server cfg file

This plugin store players by SteamID, temporary, until map end.
- After map change, player can freely join any team by himself, once (CT or T).
- When player have enter in team, he can't use jointeam command or jointeam command is used to back old team.
- When client reconnect back in same map, plugin force player back to old team just once, to avoid any conflicts later.
- When this have happen, plugin keep updating player team index on this forward, until he reconnect again.


NOTE: There is not any admin bypass. This affect to all human players.

block team change

PHP Code:

#include <cstrike>
#include <sdktools>

StringMap store;
ConVar sm_stop_jointeam;

public void OnPluginStart()
{

    sm_stop_jointeam = CreateConVar("sm_stop_jointeam", "0", "Restrict to use jointeam command", 0, true, 0.0, true, 1.0);

    store = new StringMap();

    AddCommandListener(jointeam, "jointeam");
    HookEvent("player_spawn", player_spawn);
    HookEvent("player_team", player_spawn);
}


public void OnMapStart()
{
    store.Clear();
}

public void player_spawn(Event event, const char[] name, bool dontBroadcast)
{
    static bool bChangeTeamOnce[MAXPLAYERS+1];

    // Plugin disabled
    if(!sm_stop_jointeam.BoolValue)  return;

    int client = GetClientOfUserId(event.GetInt("userid"));

    // Avoid error
    if(!IsClientInGame(client)) return;

    // Ignore bots
    if(IsFakeClient(client)) return;


    // Fail to get authentication
    char AuthId[30];
    if(!GetClientAuthId(client, AuthId_Engine, AuthId, sizeof(AuthId))) return;


    int teamnum;

    if(StrEqual(name, "player_spawn", false))
    {
        teamnum = event.GetInt("teamnum");

        // player enter in server
        if(teamnum == 0) bChangeTeamOnce[client] = true;
    }
    else
    {
        // Player disconnecting
        if(event.GetBool("disconnect")) return;

        teamnum = event.GetInt("team");
    }

    // Not valid team index
    if(teamnum <= 1 || teamnum > 3) return;




    // New 1st data saved - success
    if(store.SetValue(AuthId, teamnum, false))
    {
        bChangeTeamOnce[client] = false;
        return;
    }



    // Player data already saved in store

    int team;
    store.GetValue(AuthId, team);

    // Not valid team index - something went wrong, call 555 - 123123
    if(team <= 1 || team > 3) return;


    // Player force to back old team (once), have already done
    if(!bChangeTeamOnce[client])
    {
        // save new team index on this forward (autoteambalance ? admin change team ?)
        store.SetValue(AuthId, teamnum, true);
        return;
    }


    bChangeTeamOnce[client] = false;


    // Player enter/spawn in right team
    if(teamnum == team) return;

    // Force player to back old team;
    //PrintToServer("ChangeClientTeam %s %i", name, team);

    DataPack pack;
    CreateDataTimer(1.0, delay, pack, TIMER_FLAG_NO_MAPCHANGE);
    pack.WriteCell(GetClientUserId(client));
    pack.WriteCell(team);
    pack.Reset();

}

public Action delay(Handle timer, DataPack pack)
{
    int client = GetClientOfUserId(pack.ReadCell());
    int team = pack.ReadCell();

    if(client == 0 || !IsClientInGame(client)) return Plugin_Continue;

    ChangeClientTeam(client, team);
    return Plugin_Continue;
}

public Action jointeam(int client, const char[] command, int args)
{
    static bool FakeJoinTeamCmd[MAXPLAYERS];

    if(client == 0) return Plugin_Continue;



    // Fake client command in progress
    if(FakeJoinTeamCmd[client])
    {
        FakeJoinTeamCmd[client] = false;
        return Plugin_Continue;
    }

    // Plugin disabled
    if(!sm_stop_jointeam.BoolValue)  return Plugin_Continue;

    // avoid errors
    if(!IsClientInGame(client)) return Plugin_Handled;

    // Filter bots and failed authentication
    char AuthId[30];
    if(IsFakeClient(client) || !GetClientAuthId(client, AuthId_Engine, AuthId, sizeof(AuthId))) return Plugin_Continue;

    //PrintToServer(AuthId);

    // Player "data" not found in store
    int teamnum;
    if(!store.GetValue(AuthId, teamnum)) return Plugin_Continue;

    // Invalid team index - something went wrong
    if(teamnum <= 1 || teamnum > 3 ) return Plugin_Continue;

    // Player already in right team
    if(GetClientTeam(client) == teamnum) return Plugin_Handled;

    FakeJoinTeamCmd[client] = true;
    //PrintToServer("fake jointeam %i", teamnum);
    FakeClientCommand(client, "jointeam %i 1", teamnum);

    return Plugin_Handled;
} 


[djded]

Originally Posted by Bacardi I leave here my version, I have only tested in CSGO. I was looking and testing wierd bugs or behavier when autoteambalance kick in and when player connect to server plaa plaa plaa. This plugin is disabled by default: sm_stop_jointeam 0 To enable type sm_cvar sm_stop_jointeam 1 - Then this plugin stay enabled until server shutdown or someone change it back 0 - To enable this plugin automatically when server launch, add cvar in server cfg file This plugin store players by SteamID, temporary, until map end. - After map change, player can freely join any team by himself, once (CT or T). - When player have enter in team, he can't use jointeam command or jointeam command is used to back old team. - When client reconnect back in same map, plugin force player back to old team just once, to avoid any conflicts later. - When this have happen, plugin keep updating player team index on this forward, until he reconnect again. NOTE: There is not any admin bypass. This affect to all human players. block team change PHP Code: #include <cstrike> #include <sdktools> StringMap store; ConVar sm_stop_jointeam; public void OnPluginStart() {     sm_stop_jointeam = CreateConVar("sm_stop_jointeam", "0", "Restrict to use jointeam command", 0, true, 0.0, true, 1.0);     store = new StringMap();     AddCommandListener(jointeam, "jointeam");     HookEvent("player_spawn", player_spawn);     HookEvent("player_team", player_spawn); } public void OnMapStart() {     store.Clear(); } public void player_spawn(Event event, const char[] name, bool dontBroadcast) {     static bool bChangeTeamOnce[MAXPLAYERS+1];     // Plugin disabled     if(!sm_stop_jointeam.BoolValue)  return;     int client = GetClientOfUserId(event.GetInt("userid"));     // Avoid error     if(!IsClientInGame(client)) return;     // Ignore bots     if(IsFakeClient(client)) return;     // Fail to get authentication     char AuthId[30];     if(!GetClientAuthId(client, AuthId_Engine, AuthId, sizeof(AuthId))) return;     int teamnum;     if(StrEqual(name, "player_spawn", false))     {         teamnum = event.GetInt("teamnum");         // player enter in server         if(teamnum == 0) bChangeTeamOnce[client] = true;     }     else     {         // Player disconnecting         if(event.GetBool("disconnect")) return;         teamnum = event.GetInt("team");     }     // Not valid team index     if(teamnum <= 1 || teamnum > 3) return;     // New 1st data saved - success     if(store.SetValue(AuthId, teamnum, false))     {         bChangeTeamOnce[client] = false;         return;     }     // Player data already saved in store     int team;     store.GetValue(AuthId, team);     // Not valid team index - something went wrong, call 555 - 123123     if(team <= 1 || team > 3) return;     // Player force to back old team (once), have already done     if(!bChangeTeamOnce[client])     {         // save new team index on this forward (autoteambalance ? admin change team ?)         store.SetValue(AuthId, teamnum, true);         return;     }     bChangeTeamOnce[client] = false;     // Player enter/spawn in right team     if(teamnum == team) return;     // Force player to back old team;     //PrintToServer("ChangeClientTeam %s %i", name, team);     DataPack pack;     CreateDataTimer(1.0, delay, pack, TIMER_FLAG_NO_MAPCHANGE);     pack.WriteCell(GetClientUserId(client));     pack.WriteCell(team);     pack.Reset(); } public Action delay(Handle timer, DataPack pack) {     int client = GetClientOfUserId(pack.ReadCell());     int team = pack.ReadCell();     if(client == 0 || !IsClientInGame(client)) return Plugin_Continue;     ChangeClientTeam(client, team);     return Plugin_Continue; } public Action jointeam(int client, const char[] command, int args) {     static bool FakeJoinTeamCmd[MAXPLAYERS];     if(client == 0) return Plugin_Continue;     // Fake client command in progress     if(FakeJoinTeamCmd[client])     {         FakeJoinTeamCmd[client] = false;         return Plugin_Continue;     }     // Plugin disabled     if(!sm_stop_jointeam.BoolValue)  return Plugin_Continue;     // avoid errors     if(!IsClientInGame(client)) return Plugin_Handled;     // Filter bots and failed authentication     char AuthId[30];     if(IsFakeClient(client) || !GetClientAuthId(client, AuthId_Engine, AuthId, sizeof(AuthId))) return Plugin_Continue;     //PrintToServer(AuthId);     // Player "data" not found in store     int teamnum;     if(!store.GetValue(AuthId, teamnum)) return Plugin_Continue;     // Invalid team index - something went wrong     if(teamnum <= 1 || teamnum > 3 ) return Plugin_Continue;     // Player already in right team     if(GetClientTeam(client) == teamnum) return Plugin_Handled;     FakeJoinTeamCmd[client] = true;     //PrintToServer("fake jointeam %i", teamnum);     FakeClientCommand(client, "jointeam %i 1", teamnum);     return Plugin_Handled; }

Nice plugin, but, if some auto team balancer plugin, trying to move player from team A to team B, player stay in team A, because he can't moved to another team
Also admins can't switch players from admin panel.
Some solution to fix tahat?
Thanks
Game Cs:s v91
Sm 1.9

[Bacardi]

Originally Posted by djded Game Cs:s v91 Sm 1.9

Are there other versions of cs:s ?

[djded]

Originally Posted by Bacardi Are there other versions of cs:s ?

No, I have latest Counter-Strike Source server. And tested on it only. Will be perfect, if admins can have imunity from blocking swith(configured in some cars) and blocking team change expire In about 10-15 min for all players. If it possible. And need autoteambalance can move players to.
Sorry for my English.