[=MaTi=]

I'm trying to write a plugin that spawns entities in front of player. Everything works fine, except... Native GetClientAbsAngles updates the angle way too slowly. There is about 5 seconds (or even more) delay before it updates the angle. Because of this, players would end up spawning items in walls or other props. Is there a way to make it always retrieve the actual angle?

Here is the source code:

public Action:Command_TestSpawn(client, params)
{
    new Float:location[3];
    GetClientAbsOrigin(client, location);
    new Float:ang[3];
    GetClientAbsAngles(client, ang);
    new Float:location2[3];
    location2[0] = (location[0]+(150*(Cosine(DegToRad(ang[1]))))); //item spawns a little further, for testing purposes
    location2[1] = (location[1]+(150*(Sine(DegToRad(ang[1])))));
    location2[2] = location[2];
    PrintToChat(client,"Location1: %f, %f, %f", location[0], location[1], location[2]);
    PrintToChat(client,"Location2: %f, %f, %f", location2[0], location2[1], location2[2]);
    PrintToChat(client,"Angles: %f, %f, %f", ang[0], ang[1], ang[2]); 
    new EntitySpawnIndex = CreateEntityByName("weapon_zm_rifle");
    DispatchSpawn(EntitySpawnIndex);
    TeleportEntity(EntitySpawnIndex, location2, NULL_VECTOR, NULL_VECTOR);
}

[Flynn]

Originally Posted by =MaTi= Is there a way to make it always retrieve the actual angle?

Of what exactly? The client, or the entity being spawned?

[=MaTi=]

The client, entity angle doesn't really matter.

[Flynn]

In my barrel launcher plugin, I used GetClientEyeAngles(client,ang);

Assuming you don't want up or down co-ords, just set ang[2] = 0.0;

That should hopefully solve your problem.

Edit: Also, my mathmatics is a bit rusty, but...

location2[0] = (location[0]+(150*(Cosine(DegToRad(ang[1]))))); //item spawns a little further, for testing purposes
    location2[1] = (location[1]+(150*(Sine(DegToRad(ang[1])))));

Did you intend for both of them to be ang[1]?

I actually know nothing of Cosine, Sine, Rad etc.

[=MaTi=]

Originally Posted by Flynn In my barrel launcher plugin, I used GetClientEyeAngles(client,ang); Assuming you don't want up or down co-ords, just set ang[2] = 0.0; That should hopefully solve your problem.

Yup, it works perfectly now

Originally Posted by Flynn Did you intend for both of them to be ang[1]? I actually know nothing of Cosine, Sine, Rad etc.

Yes, since I calculate the entitys position basing on client's horizontal angle. For instance, if client's looking in the sky, the item will spawn in front of him, not over him

Anyway, thanks for help!

[meng]

Originally Posted by =MaTi= Yes, since I calculate the entitys position basing on client's horizontal angle. For instance, if client's looking in the sky, the item will spawn in front of him, not over him

do you know how i can do this? spawn the item right in front of their view? even if they are looking to the sky. i am terrible at math. i just want to get the location of about 32 units in front of their view, regardless where they are looking.

[meng]

would still love to be able to do this. but im beginning to think its not possible. i have no idea how to include the z axis in these calculations. could somebody give it a try?

[AtomicStryker]

PHP Code:

    decl Float:location[3], Float:ang[3], Float:location2[3];
    GetClientAbsOrigin(client, location);
    GetClientEyeAngles(client, ang);
    
    location2[0] = (location[0]+(50*(Cosine(DegToRad(ang[1])))));
    location2[1] = (location[1]+(50*(Sine(DegToRad(ang[1])))));
    location2[2] = (location[2]+(50*(Sine(DegToRad(ang[2]))))); 


Like this - maybe you need a Cosine for the z coordinate though

[meng]

thx, but that didnt seem to have the effect. it still spawns 50 units in front of their position in the map. this is why its so confusing. that z coordinate needs to be included in the early calculations somehow. for example, i try and spawn a grenade and hurl it towards where the player is looking. if they are looking up or down, it spawns 50 units away from their position and looks bad both first person and world view. if they are looking relatively parallel to the ground, it looks just fine. thx again though, this would be really key to getting a custom projectile to look a little more acceptable.

[=MaTi=]

Sorry, I didn't notice that somebody has replied to this old topic. If you want to spawn the object right in front of player, you need to take client's vertical angle (ang[0]) into account as well. Here is the code:

PHP Code:

#pragma semicolon 1

#include <sourcemod>
#include <sdktools>

public Plugin:myinfo = 
{
    name = "Spawn entity",
    author = "MaTi",
    description = "Spawn entity",
    version = "1.0",
    url = "none"
}

public OnPluginStart()
{
    PrecacheModel("models/props_c17/oildrum001_explosive.mdl");
    RegConsoleCmd("sm_spawntest", Command_TestSpawn);
}

public Action:Command_TestSpawn(client, params)
{
    new Float:location[3];
    GetClientEyePosition(client, location);
    new Float:ang[3];
    GetClientEyeAngles(client, ang);
    new Float:location2[3];
    location2[0] = (location[0]+(100*((Cosine(DegToRad(ang[1]))) * (Cosine(DegToRad(ang[0]))))));
    location2[1] = (location[1]+(100*((Sine(DegToRad(ang[1]))) * (Cosine(DegToRad(ang[0]))))));
    ang[0] -= (2*ang[0]);
    location2[2] = (location[2]+(100*(Sine(DegToRad(ang[0])))));
    PrintToChat(client,"Location1: %f, %f, %f", location[0], location[1], location[2]);
    PrintToChat(client,"Location2: %f, %f, %f", location2[0], location2[1], location2[2]);
    PrintToChat(client,"Angles: %f, %f, %f", ang[0], ang[1], ang[2]); 
    new EntitySpawnIndex = CreateEntityByName("prop_physics");
    SetEntityModel(EntitySpawnIndex,"models/props_c17/oildrum001_explosive.mdl");
    DispatchSpawn(EntitySpawnIndex);
    SetEntityMoveType(EntitySpawnIndex, MOVETYPE_VPHYSICS);
    SetEntProp(EntitySpawnIndex, Prop_Data, "m_CollisionGroup", 5);
    SetEntProp(EntitySpawnIndex, Prop_Data, "m_nSolidType", 6);
    TeleportEntity(EntitySpawnIndex, location2, NULL_VECTOR, NULL_VECTOR);
} 


Just change the code to spawn the entity you want and it should work