[safetymoose]

Hello again,

Can anyone tell me the difference between engine's set_lights() and fakemeta's EngFunc_LightStyle ?

And can they be changed on each player separately, or does it apply to the entire map?

[hzqst]

they are the same.

PHP Code:

void PF_lightstyle_I(int style, char *val)
{
    client_t *client;
    int j;

    sv.lightstyles[style] = val;

    if (sv.state != ss_active)
        return;

    for (j = 0; j < svs.maxclientslimit; j++)
    {
        client = &svs.clients[j];

        if (!client->active && !client->spawned)
            continue;

        if (!client->fakeclient)
        {
            MSG_WriteChar(&client->netchan.message, svc_lightstyle);
            MSG_WriteChar(&client->netchan.message, style);
            MSG_WriteString(&client->netchan.message, val);
        }
    }
} 


send a style id and a lightstyle string to all active clients, if you want to send to each clients separately, you need a hook on engine, something like:

PHP Code:

    MSG_WriteChar(&svs.clients[id].netchan.message, svc_lightstyle);
    MSG_WriteChar(&svs.clients[id].netchan.message, style);
    MSG_WriteString(&svs.clients[id].netchan.message, val); 


and it's difficult to locate the address of "&svs.clients[id].netchan.message" on each version of engine, maybe you need an IDA.

[HamletEagle]

For custom light per players: no reason to complicate too much. Sending a custom message should be enough:

PHP Code:

emessage_begin(MSG_ONE, SVC_LIGHTSTYLE, _, id)
{ 
    ewrite_byte(0)
    ewrite_string("flags")
    emessage_end()
} 


Lights values are the same as when you use set_lights. Now, you should make sure that game doesn not override your custom setup, for this you need to hook PF_lightstyle_I

PF_lightstyle_I is exported to dll, so hooking it is very easy. Use orpheu/okapi.

PHP Code:

#include <amxmodx>
#include <orpheu>
#include <orpheu_stocks>
#include <fakemeta>

new OrpheuFunction:HandleSetLightStyle

public plugin_precache()
{
    HandleSetLightStyle = OrpheuGetEngineFunction("pfnLightStyle", "SetLightStyle")
    OrpheuRegisterHook(HandleSetLightStyle, "OnSetLightStyle", OrpheuHookPre)
}

//Style is an light type I guess. Should use 0 for players
//Value is light value
public OrpheuHookReturn:OnSetLightStyle(Style, const Value[])
{
        //Now send your message here again.
    return OrpheuSupercede
} 


Signature:

{
	"name" : "SetLightStyle",
	"library" : "engine",
	"arguments"  :
	[
		{
			"type" : "int"
		},
		{
			"type" : "char *"
		}
	],
	"return" :
	{
		"type" : "int"
	}
}

Name this file SetLightStyle and put it inside orpheu/functions folder.

Take a look here. I used this to test the method.

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <orpheu>
#include <orpheu_stocks>

new MaxPlayers

public plugin_precache()
{
    new OrpheuFunction:HandleSetLightStyle = OrpheuGetEngineFunction("pfnLightStyle", "SetLightStyle")
    OrpheuRegisterHook(HandleSetLightStyle, "OnSetLightStyle", OrpheuHookPre)
    
    register_event("InitHUD", "OnPlayerJoin_Event", "b")
    MaxPlayers = get_maxplayers()
    
    //Fix coloring bug
    server_cmd("sv_skycolor_r 0")
    server_cmd("sv_skycolor_g 0")
    server_cmd("sv_skycolor_b 0")
}

public OnPlayerJoin_Event(id)
{
    if(is_user_connected(id))
    {
        //Player joined, send message
        SendNewLightMessage(id)
    }
}

public OrpheuHookReturn:OnSetLightStyle(Style, const Value[])
{
    //Send a new message and supercede original call
    SendNewLightMessage(0)
    return OrpheuSupercede
}

SendNewLightMessage(id)
{
    if(id)
    {
        SendMessage(id)
    }
    else 
    {
        //According to wiki this message is send some times during connecting
        //Due to lack of time I'll just trust this
        for(new i = 1; i <= MaxPlayers; i++)
        {
            if(is_user_connecting(i))
            {
                SendMessage(i)
            }
        }
    }
}

SendMessage(id)
{
    //Send a new message
    emessage_begin(MSG_ONE, SVC_LIGHTSTYLE, _, id)
    { 
        ewrite_byte(0)
        ewrite_string("a")
        emessage_end()
    } 
} 


Did not tested in deep, but should work fine. ewrite_string("a") here you put the light string(I used "a" just for test). This is a basic example, you should add checks to see if current light value is different from the one you want to setup. As said, credits to wiki and Arkshine.

[Nextra]

Originally Posted by HamletEagle Lights values are the same as when you use set_lights. Now, you should make sure that game doesn not override your custom setup, for this you need to hook PF_lightstyle_I

set_lights() manages this automatically for you, which is why it is not equivalent to just calling the engfunc or sending a client message. You don't need to replicate it using Orpheu.

[HamletEagle]

Originally Posted by Nextra set_lights() manages this automatically for you, which is why it is not equivalent to just calling the engfunc or sending a client message. You don't need to replicate it using Orpheu.

Well, the idee is to show a possible way of how to set custom lights per player. set_lights does this for all players, since in PF_lightstyle_I the engine send message to all players. Now he can edit above code, and in SendMessage put a different light for every player or whatever he wants to do.

[Shooting King]

This ?