[Spirit_12]

I'm trying to write all the weapon names onto a keyvalues file. I just can't seem to figure how can I bring the tree position back one level within a loop.

Here is the code.

PHP Code:

char sWeaponAssault[5][32] = 
{
    "rifle",
    "rifle_desert",
    "rifle_ak47",
    "rifle_sg552",
    "rifle_m60",
};

WeaponNamesToFile()
{
    // Build file path.
    BuildPath(Path_SM, kv_Path, sizeof(kv_Path), "../../cfg/sourcemod/weapon_prefs.txt");
    
    KeyValues kv = new KeyValues("Weapon Prefs");
    
    if(kv.JumpToKey("Assault", true))
    {
        for(int i; i < sizeof(sWeaponAssault); i++)
        {
            PrintToServer("Weapon Name %s", sWeaponAssault[i]);
            kv.JumpToKey(sWeaponAssault[i], true);
            kv.GoBack();
        }
    }
    kv.ExportToFile(kv_Path);
} 


This gives me back just the second last array value.

PHP Code:

"rifle_sg552"
{
} 


I know, I need to close the handle, but this need to be fixed before hand. Who can help me?

[Drixevel]

void WeaponNamesToFile()
{
	// Build file path.
	BuildPath(Path_SM, kv_Path, sizeof(kv_Path), "../../cfg/sourcemod/weapon_prefs.txt");
	
	KeyValues kv = new KeyValues("Weapon Prefs");
	
	if(kv.JumpToKey("Assault", true))
	{
		for (int i = 0; i < sizeof(sWeaponAssault); i++)
		{
			PrintToServer("Weapon Name %s", sWeaponAssault[i]);
			
			if (kv.JumpToKey(sWeaponAssault[i], true))
			{
				kv.SetString("key", "value");
				kv.GoBack();
			}
		}
		
		kv.Rewind();
	}
	
	kv.ExportToFile(kv_Path);
	delete kv;
}

3 primary issues you ran into:

1. Sourcemod skips sections that have no data when saving. (There maybe another method of creating sections that works?)
2. You have to rewind the KeyValues handle before you export it if you've changed it.
3. Be sure to check if JumpToKey returns true before you GoBack.

"Weapon Prefs"
{
	"Assault"
	{
		"rifle"
		{
			"key"		"value"
		}
		"rifle_desert"
		{
			"key"		"value"
		}
		"rifle_ak47"
		{
			"key"		"value"
		}
		"rifle_sg552"
		{
			"key"		"value"
		}
		"rifle_m60"
		{
			"key"		"value"
		}
	}
}

[Spirit_12]

Your answer was quick and to the point. Have this