[khashayar007]

Cause when server shuts down the playtime for all players resets.

[Bugsy]

The play time should never reset.

[Bugsy]

Made a small fix where the previous players play time would be given to the next player if the player has never been to the server before.

[khashayar007]

How to remove a player if it's vip? So the player must play again to be vip.

[Bugsy]

I can add a command for that, too.

[khashayar007]

Ok add it.

[Bugsy]

Added blacklist and remove commands. Untested.

PHP Code:


#include <amxmodx>
#include <amxmisc>
#include <nvault>

new const Version[] = "0.2";

#define MAX_PLAYERS 32

const FortyEightHours = ( 86400 * 2 );

enum PlayerData
{
    pdAuthID[ 34 ],
    pdConnectTime,
    pdPlayTime,
    pdIgnorePlayer
}

new g_pdData[ MAX_PLAYERS + 1 ][ PlayerData ];
new g_Vault;

public plugin_init() 
{
    register_plugin( "Play Time VIP" , Version , "bugsy" );

    register_clcmd( "ptv_blacklist" , "Blacklist" );
    register_clcmd( "ptv_removevip" , "RemoveVIP" );
    
    g_Vault = nvault_open( "ptvip" );
}

public plugin_end() 
{
    nvault_close( g_Vault );
}

public client_authorized( id )
{
    new szTime[ 11 ] , iTS , szMsg[ 48 ];
    
    if ( !( g_pdData[ id ][ pdIgnorePlayer ] = ( is_user_bot( id ) || is_user_hltv( id ) ) ) )
    {
        get_user_authid( id , g_pdData[ id ][ pdAuthID ] , charsmax( g_pdData[][ pdAuthID ] ) );
        
        g_pdData[ id ][ pdConnectTime ] = get_systime();
        
        if ( nvault_lookup( g_Vault , g_pdData[ id ][ pdAuthID ] , szTime , charsmax( szTime ) , iTS ) )
        {
            g_pdData[ id ][ pdPlayTime ] = str_to_num( szTime );
            
            if ( g_pdData[ id ][ pdPlayTime ] != -1 )
            {
                if ( g_pdData[ id ][ pdPlayTime ] >= FortyEightHours )
                {
                    set_user_flags( id , ADMIN_LEVEL_F );
                    
                    formatex( szMsg , charsmax( szMsg ) , "You have played for %d seconds and now have VIP" , g_pdData[ id ][ pdPlayTime ] );
                }
                else
                {
                    formatex( szMsg , charsmax( szMsg ) , "You have played for %d seconds. Play more to get VIP" , g_pdData[ id ][ pdPlayTime ] );
                }
            }
        }
        else
        {
            copy( szMsg , charsmax( szMsg ) , "This is your first time connecting." );
        }
        
        set_task( 8.0 , "ShowMessage" , id , .parameter=szMsg , .len=sizeof( szMsg ) );
    }
}

public client_disconnect( id )
{
    new szTime[ 11 ];
    
    if ( !g_pdData[ id ][ pdIgnorePlayer ] && ( g_pdData[ id ][ pdPlayTime ] != -1 ) )
    {
        num_to_str( g_pdData[ id ][ pdPlayTime ] + ( get_systime() - g_pdData[ id ][ pdConnectTime ] ) , szTime , charsmax( szTime ) );
        nvault_set( g_Vault , g_pdData[ id ][ pdAuthID ] , szTime );
        g_pdData[ id ][ pdPlayTime ] = 0;
    }
}

public ShowMessage( szMsg[] , id )
{
    if ( is_user_connected( id ) )
    {
        client_print( id , print_chat , szMsg );
    }
}

public Blacklist( id )
{
    new szPlayer[ 32 ] , iPlayer , szBlacklist[] = "-1";
    
    read_argv( 1 , szPlayer , charsmax( szPlayer ) );
    
    if ( ( iPlayer = cmd_target( id , szPlayer ) ) )
    {
        nvault_pset( g_Vault , g_pdData[ iPlayer ][ pdAuthID ] , szBlacklist );
        remove_user_flags( iPlayer , ADMIN_LEVEL_F );
        client_print( iPlayer , print_chat , "* You have been blacklisted from getting VIP." );
    }
    
    return PLUGIN_HANDLED;
}

public RemoveVIP( id )
{
    new szPlayer[ 32 ] , iPlayer;
    
    read_argv( 1 , szPlayer , charsmax( szPlayer ) );
    
    if ( ( iPlayer = cmd_target( id , szPlayer ) ) )
    {
        nvault_remove( g_Vault , g_pdData[ iPlayer ][ pdAuthID ] );
        remove_user_flags( iPlayer , ADMIN_LEVEL_F );
        client_print( iPlayer , print_chat , "* Your VIP status has been removed." );
    } 
    
    return PLUGIN_HANDLED;
} 


[khashayar007]

Thank you so much It's working. But I need to see who is in vip list so that I can remove it. Can you make a menu for ptv_removevip that shows all vips thus I can delete the vip I want.

[khashayar007]

Bugsy can you please add a feature when a player becomes vip after 48 hours remove it's vip.

[Bugsy]

Originally Posted by khashayar007 Thank you so much It's working. But I need to see who is in vip list so that I can remove it. Can you make a menu for ptv_removevip that shows all vips thus I can delete the vip I want.

This will require that you use the nvault_array include which requires that all servers running this have either a amxmodx dev build running or have the fixed nvault module installed.

Originally Posted by khashayar007 Bugsy can you please add a feature when a player becomes vip after 48 hours remove it's vip.

I don't understand this request.