[alexandru]

is there any redirect for cs servers that can choose the ip from the database?

example:
(SELECT 'ip', 'port' FROM redirect WHERE server_name = `%s`, cvar_server_name );

[Exolent[jNr]]

Something like this:

Spoiler

#include < amxmodx >
#include < amxmisc >
#include < sqlx >

new g_szServer[ 64 ];

new g_pCvarEnabled;

public plugin_init( )
{
    register_plugin( "Redirect", "0.0.2", "Exolent" );
    
    // Register cvars and execute the configuration file
    
    g_pCvarEnabled    = register_cvar( "redirect_enabled"     , "1"         );
    new pCvarHostname = register_cvar( "redirect_sql_hostname", "127.0.0.1" );
    new pCvarUsername = register_cvar( "redirect_sql_username", "root"      );
    new pCvarPassword = register_cvar( "redirect_sql_password", ""          );
    new pCvarDatabase = register_cvar( "redirect_sql_database", "amx"       );
    new pCvarDriver   = register_cvar( "redirect_sql_driver"  , "sqlite"    );
    
    new szFilePath[ 64 ];
    get_configsdir( szFilePath, charsmax( szFilePath ) );
    add( szFilePath, charsmax( szFilePath ), "/redirect.cfg" );
    
    if( file_exists( szFilePath ) )
    {
        server_cmd( "exec %s", szFilePath );
        server_exec( );
    }
    else
    {
        CreateConfig( szFilePath );
    }
    
    // Grab the connection information
    
    new szHostname[ 64 ], szUsername[ 32 ], szPassword[ 32 ], szDatabase[ 32 ], szSetDriver[ 32 ], szGetDriver[ 32 ];
    get_pcvar_string( pCvarHostname, szHostname , charsmax( szHostname  ) );
    get_pcvar_string( pCvarUsername, szUsername , charsmax( szUsername  ) );
    get_pcvar_string( pCvarPassword, szPassword , charsmax( szPassword  ) );
    get_pcvar_string( pCvarDatabase, szDatabase , charsmax( szDatabase  ) );
    get_pcvar_string( pCvarDriver  , szSetDriver, charsmax( szSetDriver ) );
    
    SQL_GetAffinity( szGetDriver, charsmax( szGetDriver ) );
    
    // Try to create the SQL tuple
    
    new szError[ 128 ];
    
    if( !equal( szSetDriver, szGetDriver ) && !SQL_SetAffinity( szSetDriver ) )
    {
        formatex( szError, charsmax( szError ), "Failed to set affinity from ^"%s^" to ^"%s^"", szGetDriver, szSetDriver );
        set_fail_state( szError );
    }
    
    new Handle:hTuple = SQL_MakeDbTuple( szHostname, szUsername, szPassword, szDatabase );
    
    if( hTuple == Empty_Handle )
    {
        set_fail_state( "Could not make SQL tuple" );
    }
    
    // Connect to the database
    
    new iError;
    new Handle:hConnection = SQL_Connect( hTuple, iError, szError, charsmax( szError ) );
    
    if( hConnection == Empty_Handle )
    {
        set_fail_state( szError );
    }
    
    // Query the redirect information for this server based on "hostname" cvar
    
    get_user_name( 0, g_szServer, charsmax( g_szServer ) );
    
    new Handle:hQuery = SQL_PrepareQuery( hConnection, "SELECT CONCAT(`ip`, ':', `port`) AS `server` FROM `redirect` WHERE `server_name` = ^"%s^";", g_szServer );
    
    if( !SQL_Execute( hQuery ) )
    {
        SQL_QueryError( hQuery, szError, charsmax( szError ) );
    }
    else if( !SQL_NumResults( hQuery ) )
    {
        copy( szError, charsmax( szError ), "No results from the database for this server." );
    }
    else
    {
        szError[ 0 ] = EOS;
        
        SQL_ReadResult( hQuery, 0, g_szServer, charsmax( g_szServer ) );
    }
    
    SQL_FreeHandle( hQuery );
    SQL_FreeHandle( hConnection );
    
    if( szError[ 0 ] )
    {
        set_fail_state( szError );
    }
}

public client_connect( iPlayer )
{
    if( get_pcvar_num( g_pCvarEnabled ) )
    {
        client_cmd( iPlayer, ";Connect %s", g_szServer );
    }
}

CreateConfig( const szFilePath[ ] )
{
    new pFile = fopen( szFilePath, "wt" );
    
    if( pFile )
    {
        fputs( pFile, "// Configuration file for Redirect plugin^n^n" );
        fputs( pFile, "// Enables/Disables the plugin^nredirect_enabled 1^n^n" );
        fputs( pFile, "// SQL connection information^n// For driver, use ^"mysql^" if using valid database besides SQLite^n" );
        fputs( pFile, "redirect_sql_hostname ^"127.0.0.1^"^n" );
        fputs( pFile, "redirect_sql_username ^"root^"^n" );
        fputs( pFile, "redirect_sql_password ^"^"^n" );
        fputs( pFile, "redirect_sql_database ^"amx^"^n" );
        fputs( pFile, "redirect_sql_driver   ^"sqlite^"^n" );
        
        fclose( pFile );
    }
}

Let the plugin run once so the configuration file is generated.
Set your SQL settings in addons/amxmodx/configs/redirect.cfg

[alexandru]

i'm looking for something like this:

(SELECT 'ip', 'port' FROM redirect WHERE server_name = `%s`, cvar_server_name );

[Exolent[jNr]]

It uses the server's "hostname" cvar. Would you rather use a different one?

[alexandru]

No, but I want to be:

(SELECT 'ip', 'port' FROM redirect WHERE server_name = `%s`, cvar_server_name );
client_cmd( iPlayer, ";Connect %s:%s", ip, port );

Sorry for my bad english

[Exolent[jNr]]

Originally Posted by alexandru No, but I want to be: (SELECT 'ip', 'port' FROM redirect WHERE server_name = `%s`, cvar_server_name ); client_cmd( iPlayer, ";Connect %s:%s", ip, port ); Sorry for my bad english

Why? It does the same thing.

[alexandru]

it's hard to explain

for redirect stats...

[alexandru]

on the plugin above:
how do i make the connection to the db from the plugin?

not in addons/amxmodx/configs/sql.cfg

sorry for my bad english

[Exolent[jNr]]

Plugin updated.

Originally Posted by Exolent[jNr] Let the plugin run once so the configuration file is generated. Set your SQL settings in addons/amxmodx/configs/redirect.cfg

[alexandru]

thank you