[PinHeaDi]

Is there any fancy way to check if there is admin in the server, before processing a command.

Player A (not an admin) type: sm_testcommand

The plugin will check if there is admin in the server and if there is - it will print for exampe "You can't use that command while an admin is in the server"

Something like that I guess.

PHP Code:

for (int client = 1; client <= MaxClients; client++)
{
     if(IsClientInGame(client) || CheckCommandAccess(client, "is_a_sm_admin", ADMFLAG_GENERIC, true))
     {
          //And add a count++ if an admin is online
     }
}

if(count> 0)
{
     PrintToChat(client, "Nope, admin online");
} 


[8guawong]

That will work

[pride95]

why count? use a bool for what you need and a break after you found an admin.
isclientingame and ( && ) checkcommandacces, not or ( || )

PHP Code:

bool admin = false;

for (int client = 1; client <= MaxClients; client++)
{
     if(IsClientInGame(client) && CheckCommandAccess(client, "is_a_sm_admin", ADMFLAG_GENERIC, true))
     {
          admin = true;
          break;
     }
} 


[PinHeaDi]

PHP Code:

        int Admins = 0;

    for(int i = 1; i <= MaxClients; i++)
    {
        if(IsValidClient(i))
        {
            if(CheckCommandAccess(i, "is_a_sm_admin", ADMFLAG_GENERIC, true))        Admins++;
        }
    }

    if(Admins >= 1)
    {
        PrintToChat(client, "message");
        return Plugin_Handled;
    } 


That's what I used, but I guess your code is more simple and well done.

[Visual77]

If you don't need to count admins, just use a function bool.

Then you only need one line. if (isAdminOnline()){ PrintToChatAll("admin is online"); }

The return true in the function bool will also make sure to break the loop. Plus you can re-use the function in other places and keep code shorter.

bool isAdminOnline()
{
	for (int i = 1; i <= MaxClients; i++)
	{
     		if (IsClientInGame(i) && !IsFakeClient(i) && CheckCommandAccess(i, "sm_admin", ADMFLAG_GENERIC))
     		{
          		return true;
     		}
	}
	return false;
}

[DarkDeviL]

Originally Posted by Visual77 Then you only need one line. if (isAdmin()){ PrintToChatAll("admin is online"); }

In that case, I strongly suggest using better and more descriptive variable / function names, such as for example "isAdminOnline" or something.

isAdmin() sounds more like a function used to check whether someone specific is admin, e.g. "isAdmin(client)".