[Watermelonnable]

Hello. So I'm trying to do a workaround of the infinite round plugin by Arkshine. I want the round to end when there's only 1 player alive. So I'm hooking to the "ham killed" post to achieve this. There I'm trying to count the alive persons to execute my code:

PHP Code:

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    pause("ac", "infinite_rounds.amxx");
    RegisterHamPlayer(Ham_Killed, "Ham_Killed_post", 1);
}

public Ham_Killed_post()
{
    new iPlayers[32], alivePlayers[32], rkWinnerName[32];
    get_players(iPlayers, alivePlayers, "a");

    if (alivePlayers <= 1) {
        pause("ac", "infinite_rounds.amxx");
        get_user_name(iPlayers[0], rkWinnerName, charsmax(rkWinnerName));
        client_print_color(0, print_team_default, "%s ¡%s was the round winner", TTT_TAG, rkWinnerName);
    }
} 


But honestly I don't understand that well how get_players work. This is my concept of the function at the moments:

It saves the indicated players in the third argument (the flags) in the variable given as first argument (iPlayers) but I don't know what's the second argument. I thought it was the player count but the compiler is giving me an error saying that it must be indexed.

Any help here please?

[Bugsy]

Bookmark this: http://www.amxmodx.org/api/

Here's what you need: http://www.amxmodx.org/api/amxmodx/get_players

[ZaX]

You can get the alive counts by this

PHP Code:

GetAliveCount()
{
    new iAlive, id
    
    for (id = 1; id <= get_maxplayers(); id++)
    {
        if (is_user_alive(id))
            iAlive++
    }
    
    return iAlive;
} 


and use

 if(GetAliveCount() == 1)

And if you want to know how you can use get_players, thats an example

PHP Code:

myfunction()
{
    new iPlayers[32], iNum
    new id

    get_players(iPlayers, iNum , "a") // Alive only

    for(new i = 0; i < iNum; i++)
    {
        id = iPlayers[i]
        set_user_health(id, 500)
    }
} 


[Bugsy]

ZaX, you should not use a constant native such as get_maxplayers() within the for-loop condition since it will get re-called for each iteration. Store the value in a variable and use that in the condition. I personally think it would be better to just use get_players() to get alive count.

PHP Code:

GetAliveCount()
{
    new iPlayers[ 32 ], iNum;
    
    get_players(iPlayers, iNum , "a")
    
    return iNum;
} 


You can kill 2 birds with 1 stone:

PHP Code:

public Test() 
{
    new iPlayers[ 32 ];
    new iAlive = GetAlivePlayers( iPlayers );
    
    server_print( "There are %d alive", iAlive );
}

GetAlivePlayers( iPlayers[ 32 ] )
{
    new iNum;
    
    get_players(iPlayers, iNum , "a")
    
    return iNum;
} 


[iceeedr]

PHP Code:

new Alive = get_playersnum_ex(GetPlayers_ExcludeAlive)

    if(Alive < 2) 


[Bugsy]

Originally Posted by iceeedr PHP Code: new Alive = get_playersnum_ex(GetPlayers_ExcludeAlive)     if(Alive < 2)

OP, you will need to be running AMX-X 1.9 to use the '_ex' version of get_players.

[Watermelonnable]

Thank you guys for your replies. Yes I checked the API documentation but maybe I'm kinda dumb so didn't understand it. I'm gonna try the iceeedr version since I'm using the latest amx version.

btw, shouldn't it be the GetPlayers_ExcludeDead flag?

EDIT: I'm sticking to get_players_ex since I also need to get the alive player's name

[OciXCrom]

Originally Posted by Watermelonnable btw, shouldn't it be the GetPlayers_ExcludeDead flag?

Yup.

[iceeedr]

Originally Posted by Watermelonnable btw, shouldn't it be the GetPlayers_ExcludeDead flag? EDIT: I'm sticking to get_players_ex since I also need to get the alive player's name

Oops, Oops, error clicking

[Natsheh]

Why are you pausing the plugin ? Instead use the API (OnRoundEnd forward) and return 1 or plugin_handled to block the round from ending.