[CrimsonGT]

I am always terrible at psuedo code, and for the life of me I cannot think of a decent way of coding a team scrambler function. The only thing I can really come up with is swapping every 2nd player from one team, with every 2nd player from the other team, or something to that affect.

If anyone can possibly throw me some pseudo code on scrambling teams that would be awesome. (Just to save you posting time, its not for TF2 so mp_scrambleteams isn't an option).

[bl4nk]

Store every player into an array, shuffle the array, and then put one person on team a, the next on b, the next on a, etc until you hit the end of the array.

[CrimsonGT]

Thanks bl4nk. I have rarely had to use arrays for my plugins, so I didn't know you could shuffle them.

For those needing to do this in the future, you can use SortStrings() with a sorting order of Sort_Random.

[CrimsonGT]

Would this work? I don't have anywhere to test it until tommorow

PHP Code:

public RandomizeTeams()
{
new Players[MAXPLAYERS + 1];
new clientcount = GetClientCount();
new max_clients = GetMaxClients();
new StartTeamID = 2;
for (new i=1; i <= max_clients; i++)
{
if (IsClientConnected(i) && IsClientInGame(i))
{
Players[i] = GetClientUserId(i);
}
else
{
continue;
}
}
//Randomize the Players in the Array
SortIntegers(Players, sizeof(Players), Sort_Random);
for (new i=1; i<=clientcount; i++)
{
if(StartTeamID == 2)
{
ChangeClientTeam(i, TEAM_BLUE);
StartTeamID = 3;
}
else
{
ChangeClientTeam(i, TEAM_RED);
StartTeamID = 2;
}
}
} 


[p3tsin]

Well, no... This is how I'd do it:

RandomizeTeams() {
    decl players[MAXPLAYERS], i
    new max_clients = GetMaxClients()
    new count, bool:team

    for(i = 1; i <= max_clients; i++) {
        if(IsClientInGame(i)) {
            players[count++] = i
        }
    }

    SortIntegers(players,count,Sort_Random)

    for(i = 0; i < count; i++) {
        ChangeClientTeam(players[i],team ? TEAM_RED : TEAM_BLUE)
        team = !team
    }
}

[CrimsonGT]

Thanks mate, helped much!
+Karma

[CrimsonGT]

Just out of curiosity, doesnt decl players[MAXPLAYERS] need to be MAXPLAYERS+1?

[p3tsin]

Nope. Only indexes from 0 to 63 will be used.