[finishlast]

Hi,

is there a way to detect the ground under an entity? I mean how far it is under it?

Like lets say you spawn an prop_dynamic entity in the air like say between 200-400 pixels over the ground.

And it should hover 100 pixel over it. How would you teleport it down according to the actual ground?

Another example, you spawn an entity in front of you and used the position of yourself but the ground in front of you is deeper or higher.

How would you know the needed height for the entity?

Atm I adjust the height with

vPos[2] -= 60;

Thats OK on plain terrain but not like when you stand on a rock or somthing like that. The entity spawn must be dynamic.

Thx in advance.

[Silvers]

PHP Code:

float GetGroundHeight(float vPos[3])
{
    float vAng[3];

    Handle trace = TR_TraceRayFilterEx(vPos, view_as<float>({ 90.0, 0.0, 0.0 }), MASK_ALL, RayType_Infinite, TraceEntityFilterPlayer);
    if( TR_DidHit(trace) )
        TR_GetEndPosition(vAng, trace);

    delete trace;
    return vAng[2];
}

// Taken from "[L4D2] Weapon/Zombie Spawner"
// By "Zuko & McFlurry"
bool SetTeleportEndPoint(int client, float vPos[3], float vAng[3])
{
    float vAngles[3], vOrigin[3];

    GetClientEyePosition(client, vOrigin);
    GetClientEyeAngles(client, vAngles);

    Handle trace = TR_TraceRayFilterEx(vOrigin, vAngles, MASK_SHOT, RayType_Infinite, TraceEntityFilterPlayer);

    if( TR_DidHit(trace) )
    {
        float vBuffer[3], vStart[3], distance;

        TR_GetEndPosition(vStart, trace);
        distance = -15.0;
        GetAngleVectors(vAngles, vBuffer, NULL_VECTOR, NULL_VECTOR);
        vPos[0] = vStart[0] + (vBuffer[0] * distance);
        vPos[1] = vStart[1] + (vBuffer[1] * distance);
        vPos[2] = vStart[2] + (vBuffer[2] * distance);
        vPos[2] = GetGroundHeight(vPos);
        if( vPos[2] == 0.0 )
        {
            delete trace;
            return false;
        }

        vAng = vAngles;
    }
    else
    {
        delete trace;
        return false;
    }

    delete trace;
    return true;
} 


From various spawners of mine.

[finishlast]

Thank you silvers, I already looked into your scripts, it is all rocket science to me, that's why I hoped for a solution for dumb people like me

I put on my studdy glasses and this is working now, I don't know fully why it is working but well

Thank you again! And again.... And the other times too....