[TCB_WyattEarp]

Is there a plugin that will stop a player from joining a specific team based on steam ID?
Ever have a player that ALWAYS joins T side and them camps spawn every round.
Looking for a way to stop this and if they can't join T< problem solved..

???

[Bugsy]

Not sure how you are storing the steam-id for these players. Hard-coded for now.

PHP Code:


#include <amxmodx>
#include <cstrike>

new const Version[] = "0.1";

new const ForceToCT[][] = 
{
    "STEAM_0:0:12345",
    "STEAM_0:0:67890"
}

new const g_TeamInfo[ CsTeams ][] =
{
    "UNASSIGNED",
    "TERRORIST",
    "CT",
    "SPECTATOR"
};

public plugin_init()
{
    register_plugin( "Force Team" , Version , "bugsy" );
    
    register_message( get_user_msgid( "TeamInfo" ) , "MessageTeamInfo" );
}

public MessageTeamInfo( msgid , dest , receiver )
{
    if ( dest != MSG_ALL && dest != MSG_BROADCAST ) 
        return;
    
    new szTeam[ 2 ] , iPlayer , szAuthID[ 34 ] , bool:bForceToCT;
    
    iPlayer = get_msg_arg_int( 1 );
    get_user_authid( iPlayer , szAuthID , charsmax( szAuthID ) );
    
    for ( new i = 0 ; i < sizeof( ForceToCT ) ; i++ )
    {
        if ( equali( szAuthID , ForceToCT[ i ] ) )
        {
            bForceToCT = true;
            break;
        }
    }
    
    if ( bForceToCT )
    {
        get_msg_arg_string( 2 , szTeam, charsmax( szTeam ) );
        
        if ( szTeam[ 0 ] == 'T' )
        {
            cs_set_user_team( iPlayer , CS_TEAM_CT );
            set_msg_arg_string( 2 , g_TeamInfo[ CS_TEAM_CT ] );
        }
    }
} 


[TCB_WyattEarp]

This works, will it still work if limit teams is enabled ?

Would be better if steam ID's could be stored in an INI but this does work

[Bugsy]

This only sets the team, you will need to adjust team balancing accordingly.

[instinctpt1]

Originally Posted by TCB_WyattEarp This works, will it still work if limit teams is enabled ? Would be better if steam ID's could be stored in an INI but this does work

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

new const Version[] = "0.1";

new const g_TeamInfo[ CsTeams ][] =
{
    "UNASSIGNED",
    "TERRORIST",
    "CT",
    "SPECTATOR"
};

new Array:a_steamIds
new szFile[64]

public plugin_init()
{
    register_plugin( "Force Team" , Version , "bugsy" );
    a_steamIds = ArrayCreate(32)
    get_configsdir(szFile, charsmax(szFile))
    formatex(szFile, charsmax(szFile), "%s/force_team.ini", szFile)
    register_message( get_user_msgid( "TeamInfo" ) , "MessageTeamInfo" );
}

public plugin_cfg()
{
    new szData[33]
    new file = fopen(szFile, "rt")

    while(!feof(file))
    {
        fgets(file, szData, charsmax(szData))
        trim(szData)
        if( !szData[0] || szData[0] == ';' || szData[0] == '/' && szData[1] == '/' ) 
            continue;
        
        remove_quotes(szData)
        ArrayPushString(a_steamIds, szData)
    }
    fclose(file)
}

public MessageTeamInfo( msgid , dest , receiver )
{
    if ( dest != MSG_ALL && dest != MSG_BROADCAST ) 
        return;
    
    new szTeam[ 2 ] , iPlayer , szAuthID[ 34 ] 
    
    iPlayer = get_msg_arg_int( 1 );
    get_user_authid( iPlayer , szAuthID , charsmax( szAuthID ) );
    
    if ( ArrayFindString(a_steamIds, szAuthID) != -1 )
    {
        get_msg_arg_string( 2 , szTeam, charsmax( szTeam ) );
        
        if ( szTeam[ 0 ] == 'T' )
        {
            cs_set_user_team( iPlayer , CS_TEAM_CT );
            set_msg_arg_string( 2 , g_TeamInfo[ CS_TEAM_CT ] );
        }
    }
} 


Here you go, enter steamIDs in file `force_team.ini` under configs folder in amxmodx dir

[Mordekay]

Just to satisfy my curiosity: If that guy is such a, let's call it: "bad teamplayer", why do you bother about him at all? Just ban him. Problem solved. No plugin needed, nothing, just a amx_addban "ID" "moron" "0" (if that is correct, i regulary ban through amxbans).