Assign to an entity a team.

Craxor · **Author**

I'm trying to assing a entity to a team, the goal is the next: in my heart heart entity when you kill somebody a red heart enttiy is spawned, if you touch it you get+1 lifes, i want to make to only users from the same team with the 'victim' can touch the heart.

Example if i'm a tero and i die, only terrorists can take that heart. also to render the entity based on the team .. rendering is working fine bun i can't assing to a entity a team, idk why , here's the code:

Declaration:

PHP Code:


			
// i will ad in g_pdData[] but for the moment leave it separatly until somebody figure out why is not working 
// i use 33 the size because anyway can exist in a round as much entites as much players die  . so i think is enough 33
new EntTeamId[ Max_Players + 1 ];

Assigning the value of the victim team ( i try in a looooot of ways, is just simple not working ):

PHP Code:


			
    switch( EntTeamId[ iEnt ] = get_user_team( iV ) )
    {
        case 1:
        {
            set_rendering( iEnt, kRenderFxGlowShell, 255, 0, 0, kRenderTransAlpha, 20 );
        }
        case 2:
        {
            set_rendering( iEnt, kRenderFxGlowShell, 0, 0, 255, kRenderTransAlpha, 20 );
        }

        default:
        {
            set_rendering( iEnt, kRenderFxGlowShell, 0, 255, 0, kRenderTransAlpha, 20 );
        }
    }

I try also like that but is not working:

PHP Code:


			
    switch( get_user_team( iV ) )
    {
        case 1:
        {
            EntTeamId[ iEnt ] = 1;
            set_rendering( iEnt, kRenderFxGlowShell, 255, 0, 0, kRenderTransAlpha, 20 );
        }
        case 2:
        {
            EntTeamId[ iEnt ] = 2;
            set_rendering( iEnt, kRenderFxGlowShell, 0, 0, 255, kRenderTransAlpha, 20 );
        }

        default:
        {
            EntTeamId[ iEnt ] = 0;
            set_rendering( iEnt, kRenderFxGlowShell, 0, 255, 0, kRenderTransAlpha, 20 );
        }
    }

And also the comparation in touch event:

PHP Code:


			
if( equal( szClassname, gHealthEntity) && get_user_team( id ) == EntTeamId[ iEnt ] )
        {
            g_pdData[ id ] [ iLives ]++;
        
        set_hudmessage(208, 10, 20, 0.09, 0.75, 0, 6.0, 2.0);
        show_hudmessage( id, "+1 lives" );
    
            engfunc( EngFunc_RemoveEntity, iEnt );

    }

The whole code:

Spoiler

PHP Code:


			
#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < fun >
#include < fakemeta >
#include < engine >
#include < nvault >
#include < hamsandwich >

#pragma semicolon 1;

new const PLUGIN []         = "Heart Lives";
new const VERSION[]        = "1.5";
new const AUTHOR []         = "Craxor";


new const szHealthModel[]     = "models/w_hh.mdl";
new const VName[]         = "heart_respawn_vault";
new const gHealthEntity[]     = "health_heart_entitty";

const Max_Players = 32;

enum PlayerData
{
    iLives,
    iTimes,
    szAuthID[ 34 ],
    szName[32]
}

new EntTeamId[ Max_Players + 1 ];

new g_pdData[ Max_Players + 1 ][ PlayerData ]; 

new gVault;
new gInfoTarget;

enum _:Cvars
{
    HEALTH_AMMOUNT,
    HEALTH_LIMIT,
    HEALTH_TIME,
    RESPAWN_LIVES
};

new CVS[ Cvars ];

public plugin_init( )
{
    register_plugin
    (
        PLUGIN,
        VERSION,
        AUTHOR
    );

    register_event( "DeathMsg","Event_DeathMsg","a" );
    register_logevent( "LOGEvent_Round_Start", 2, "1=Round_Start" );
    
    RegisterHam( Ham_Touch , "info_target" , "forward_touch" );

    gVault = nvault_open( VName );

    if( gVault == INVALID_HANDLE )
    {
        set_fail_state( "Problems openning 'heart_respawn_vault' file." );
    }

    register_clcmd( "say /respawn", "respawn_hook" );
    register_clcmd( "say_team /respawn", "respawn_hook" );

    register_clcmd( "say /lives", "lives_hook" );
    register_clcmd( "say_team /lives", "lives_hook" );

    register_clcmd( "say /hh", "hh_hook" );
    register_clcmd( "say_team /hh", "hh_hook" );

    register_concmd( "amx_lives", "cmd_lives", ADMIN_BAN, "<Name> <Lives>" );
    register_concmd( "amx_lives_reset", "cmd_lives_reset", ADMIN_RCON , "<Name> <Lives>" );

    CVS[HEALTH_AMMOUNT] = register_cvar( "hh_lives_health_ammount", "35" );
    CVS[HEALTH_LIMIT] = register_cvar( "hh_lives_health_limit", "100" );
    CVS[HEALTH_TIME] = register_cvar( "hh_lives_health_delay", "13" );
    CVS[RESPAWN_LIVES] = register_cvar( "hh_respawn_lives", "10" );

    gInfoTarget = engfunc( EngFunc_AllocString, "info_target" );    
}

public plugin_precache( )
{
    precache_model( szHealthModel );
}

public plugin_end( )
{
    nvault_close( gVault );
}

public cmd_lives( id, level, cid )
{
    if( !cmd_access( id, level, cid, 3 ) )
        return PLUGIN_HANDLED;

    new szArg1[32], szArg2[4];

    read_argv( 1, szArg1, charsmax( szArg1 ) );
    read_argv( 2, szArg2, charsmax( szArg2 ) );

    new TgId = cmd_target( id, szArg1, CMDTARGET_ALLOW_SELF );
    new iArg2 = str_to_num( szArg2 );

    if( TgId && iArg2 )
    {
        g_pdData[ TgId ] [ iLives ] = iArg2;
        client_print( TgId, print_chat, "Admin '%s' set your lives count to: %i", g_pdData[ id ] [ szName ], iArg2 );
    }

    return PLUGIN_HANDLED;    
}

public cmd_lives_reset( id, level, cid )
{
    if( !cmd_access( id, level, cid, 1 ) )
        return PLUGIN_HANDLED;

    nvault_prune( gVault, 0, get_systime( ) );

    for( new i = 0; i < sizeof g_pdData; i++ )
    {
        if( g_pdData[ i ] [ iLives ] )
        {
            g_pdData[ i ] [ iLives ] = 0;
        }
    }

    client_print( 0, print_chat, "Admin '%s' reseted all the lives!", g_pdData[ id ] [ szName ] );

    return PLUGIN_HANDLED;
}

public hh_hook( id )
{
    new CTime = floatround( get_gametime( ) );
    new iCurrentUserHealth = get_user_health( id );

    if( is_user_alive( id ) )
    {
        if( g_pdData[ id ] [ iLives ] )
        {
            if( iCurrentUserHealth < get_pcvar_num( CVS[HEALTH_LIMIT] ) )
            {
                if( CTime >= g_pdData[ id ] [ iTimes ] )
                {
                    set_user_health( id, iCurrentUserHealth + get_pcvar_num( CVS[HEALTH_AMMOUNT] ) );

                    g_pdData[ id ] [ iTimes ] = CTime + get_pcvar_num( CVS[HEALTH_TIME] );  

                    g_pdData[ id ] [ iLives ]--;
                }

                else
                {    
                    client_print( id, print_center, "Wait %i seconds until use again this command.", g_pdData[ id ] [ iTimes ] - CTime );
                }
            }

            else
            {
                client_print( id, print_chat, "You already have full health pack." );
            }
        }
        
        else
        {
            client_print( id, print_chat, "You have no lives." );
        }
    }
    else
    {
        client_print( id, print_chat, "Only alive users can use this command." );
    }

    return PLUGIN_HANDLED;    
}

public lives_hook( id ) 
{
    client_print( id , print_chat, "Lives to use: %i", g_pdData[ id ] [ iLives ] );
    return PLUGIN_HANDLED;
}

public respawn_hook( id )
{
    new pCvarRespawnLives = get_pcvar_num( CVS[ RESPAWN_LIVES ] );

    if( !is_user_alive( id ) )
    {
        if( g_pdData[ id ] [ iLives ] >= pCvarRespawnLives )
        {
            ExecuteHam( Ham_CS_RoundRespawn, id );
            g_pdData[ id ] [ iLives ] = g_pdData[ id ] [ iLives ] - pCvarRespawnLives;
        }

        else
        {
            client_print( id , print_chat , "You need at least %i lives to use this commnad.", pCvarRespawnLives );
        }
    }

    else
    {
        client_print( id, print_chat, "You already are alive, use this command when you're dead!" );
    }

    return PLUGIN_HANDLED;
}

public Event_DeathMsg( )
{
    new iEnt = engfunc( EngFunc_CreateNamedEntity, gInfoTarget );

    if( !pev_valid( iEnt ) )
    {
        return PLUGIN_HANDLED;
        }

    new iV = read_data( 2 );

    static FLoat:flOrigin[3];
    pev( iV, pev_origin, flOrigin );

    engfunc( EngFunc_SetOrigin, iEnt, flOrigin );

    
        set_pev( iEnt, pev_classname, gHealthEntity );
        engfunc( EngFunc_SetModel, iEnt, szHealthModel );
        dllfunc( DLLFunc_Spawn, iEnt );
        set_pev( iEnt, pev_solid, SOLID_TRIGGER );
        set_pev( iEnt, pev_movetype, MOVETYPE_NONE );
        engfunc( EngFunc_SetSize, iEnt, Float:{ -23.160000, -13.660000, -0.050000 }, Float:{ 11.470000, 12.780000, 6.720000 } );
        engfunc( EngFunc_DropToFloor, iEnt );

    switch( get_user_team( iV ) )
    {
        case 1:
        {
            EntTeamId[ iEnt ] = 1;
            set_rendering( iEnt, kRenderFxGlowShell, 255, 0, 0, kRenderTransAlpha, 20 );
        }
        case 2:
        {
            EntTeamId[ iEnt ] = 2;
            set_rendering( iEnt, kRenderFxGlowShell, 0, 0, 255, kRenderTransAlpha, 20 );
        }

        default:
        {
            EntTeamId[ iEnt ] = 0;
            set_rendering( iEnt, kRenderFxGlowShell, 0, 255, 0, kRenderTransAlpha, 20 );
        }
    }    

    return PLUGIN_HANDLED;
}

public forward_touch( iEnt, id )
{
    if( !pev_valid( iEnt ) || is_user_bot( id ) || !is_user_alive( id ) )
        return HAM_IGNORED;
        
    
        new szClassname[ 32 ];
        pev( iEnt, pev_classname, szClassname, charsmax( szClassname ) );
    
        if( equal( szClassname, gHealthEntity) && get_user_team( id ) == EntTeamId[ iEnt ] )
        {
            g_pdData[ id ] [ iLives ]++;
        
        set_hudmessage(208, 10, 20, 0.09, 0.75, 0, 6.0, 2.0);
        show_hudmessage( id, "+1 lives" );
    
            engfunc( EngFunc_RemoveEntity, iEnt );

    }
        return HAM_IGNORED;
}

public LOGEvent_Round_Start( )
{
    new iEntity = -1;

    while( ( iEntity = find_ent_by_class( iEntity, gHealthEntity ) ) )
    {
        engfunc( EngFunc_RemoveEntity, iEntity );
    }        
}

public client_authorized( id )
{
    if( !is_user_bot( id ) )
    {
        get_user_authid( id, g_pdData[ id ] [ szAuthID ], charsmax( g_pdData ) );
        get_user_name( id, g_pdData[ id ] [ szName ], charsmax( g_pdData ) );

        g_pdData[ id ] [ iLives ] = nvault_get( gVault , g_pdData[ id ] [ szAuthID ] );
    
    }
}

public client_disconnect( id )
{
    if( !is_user_bot( id ) )
    {
        new szData[4];
        num_to_str( g_pdData[ id ] [ iLives ] , szData , charsmax( szData ) );

        nvault_set( gVault, g_pdData[ id ] [ szAuthID ], szData );
    }
}

public client_infochanged( id )
{
    get_user_info( id, "name", g_pdData[ id ] [ szName ], charsmax( g_pdData ) );
}

Napoleon_be · 01-03-2017 , 06:31 Re: Assign to an entity a team.

What i would try:

1) When the victim drops the heart, assign the victim to a an array something like

PHP Code:


			
 new player[33]; player[id] = id

2) If a player wants to pick up the heart, check if get_user_team(player[id]) == get_user_team(playerpickingupheart[id]) and handle on this outcome?

Craxor · 01-03-2017 , 06:48 Re: Assign to an entity a team.

won't work, just if i want to pickup my own entity, the problem itself is with assignment, why is not working i don't understand ..

klippy · 01-03-2017 , 07:39 Re: Assign to an entity a team.

Just set pev_team on that entity and check it when a player touches it.

Craxor · *Last edited by Craxor; 01-03-2017 at 08:58.*

Quote:

Originally Posted by KliPPy

Just set pev_team on that entity and check it when a player touches it.

It has no effect.

In death msg:

PHP Code:


			
    new cTeam = pev( iV , pev_team );
    set_pev( iEnt , pev_team , cTeam );

In touch_forward:

PHP Code:


			
        if( equal( szClassname, gHealthEntity) && pev( id, pev_team ) == pev( iEnt, pev_team ) )

klippy · 01-03-2017 , 09:03 Re: Assign to an entity a team.

It does. If you set entity's pev_team to some value it will remain that way unless some other code changes it (like the game itself, which is unlikely for info_target entities). Just as for any other pev_ value. Even Lasermine plugin uses it to determine lasermine entity's team if I remember correctly.

Craxor · *Last edited by Craxor; 01-03-2017 at 09:10.*

Quote:

Originally Posted by KliPPy

It does. If you set entity's pev_team to some value it will remain that way unless some other code changes it (like the game itself, which is unlikely for info_target entities). Just as for any other pev_ value. Even Lasermine plugin uses it to determine lasermine entity's team if I remember correctly.

So what i done wrong above ?
However i'm also curious 'why' my first code wasn't working ?

klippy · 01-03-2017 , 09:31 Re: Assign to an entity a team.

I don't know, I don't like that entity array either way. Try with pev_team and post your code if you can't get it working.

**HamletEagle** · 01-03-2017 , 10:02 Re: Assign to an entity a team.

Quote:

However i'm also curious 'why' my first code wasn't working ?

Just because you can make such arrays for players, does not mean you can make it for other entities too.

Let me explain:

PHP Code:


			
new EntTeamId[ Max_Players + 1 ];

This array has valid indexes from 0 to 32(however, for players you will only use the 1 - 32 indexes). You should know by now that the first 32 indexes are always reserved for players. In other words, from 1 to maxplayers there are always players. After MAX_PLAYERS, the other entities indexes start. Given that your "iEnt" is a custom entity it's guaranteed that it's index will be bigger than 32, so there is no way to do EntTeamId[iEnt].
Check your error logs, this code will produce an index out of bounds.

What Klippy said is correct and should work. Anyway, you can use other unused fields like pev_iuser1.

Craxor · 01-03-2017 , 13:15 Re: Assign to an entity a team.

klippy in the example i show i removed the EntTeam array, i just use set_pev as directly with the entity and no effect.

Hamlet, thanks, i didn't know, looks resoursfull