[Catastrophe]

[ZP50] Addon: AP change forward

Found a much better way, Thnx to H.RED.ZONE and Yokomo

Solution: #7

[zmd94]

Thank you for sharing. ;)

This will be useful.

[H.RED.ZONE]

You are useing prethink, to check every frame if users ammopacks are changed. If someone wants this type of forward it would be much better way just to check inside zp50_ammopacks when ammopacks are trying to be found in case someone uses your plugin his CPU usage would jump a lot... (Native zp_ammopacks_get) .

Spoiler

/*================================================================================
	
	-----------------------
	-*- [ZP] Ammo Packs -*-
	-----------------------
	
	This plugin is part of Zombie Plague Mod and is distributed under the
	terms of the GNU General Public License. Check ZP_ReadMe.txt for details.
	
================================================================================*/

#include <amxmodx>
#include <fakemeta>
#include <zp50_core>

#define is_user_valid(%1) (1 <= %1 <= g_MaxPlayers)

#define TASK_HIDEMONEY 100
#define ID_HIDEMONEY (taskid - TASK_HIDEMONEY)

// CS Player PData Offsets (win32)
const PDATA_SAFE = 2
const OFFSET_CSMONEY = 115

const HIDE_MONEY_BIT = (1<<5)

#define MAXPLAYERS 32

new Forward_Change, Forward_Result

new g_MaxPlayers
new g_MsgHideWeapon, g_MsgCrosshair
new g_AmmoPacks[MAXPLAYERS+1]

new cvar_starting_ammo_packs, cvar_disable_money

public plugin_init()
{
	register_plugin("[ZP] Ammo Packs", ZP_VERSION_STRING, "ZP Dev Team")
	
	g_MaxPlayers = get_maxplayers()
	g_MsgHideWeapon = get_user_msgid("HideWeapon")
	g_MsgCrosshair = get_user_msgid("Crosshair")
	
	cvar_starting_ammo_packs = register_cvar("zp_starting_ammo_packs", "5")
	cvar_disable_money = register_cvar("zp_disable_money", "0")
	
	register_event("ResetHUD", "event_reset_hud", "be")
	register_message(get_user_msgid("Money"), "message_money")
	
	Forward_Change = CreateMultiForward("zp_fw_ammopacks_change", ET_IGNORE, FP_CELL, FP_CELL)
}

public plugin_natives()
{
	register_library("zp50_ammopacks")
	register_native("zp_ammopacks_get", "native_ammopacks_get")
	register_native("zp_ammopacks_set", "native_ammopacks_set")
}

public native_ammopacks_get(plugin_id, num_params)
{
	new id = get_param(1)
	
	if (!is_user_valid(id))
	{
		log_error(AMX_ERR_NATIVE, "[ZP] Invalid Player (%d)", id)
		return -1;
	}
	
	
	ExecuteForward(Forward_Change, Forward_Result, id, g_AmmoPacks[id])
	return g_AmmoPacks[id];
}

public native_ammopacks_set(plugin_id, num_params)
{
	new id = get_param(1)
	
	if (!is_user_valid(id))
	{
		log_error(AMX_ERR_NATIVE, "[ZP] Invalid Player (%d)", id)
		return false;
	}
	
	new amount = get_param(2)
	
	g_AmmoPacks[id] = amount
	return true;
}

public client_putinserver(id)
{
	g_AmmoPacks[id] = get_pcvar_num(cvar_starting_ammo_packs)
}

public client_disconnect(id)
{
	remove_task(id+TASK_HIDEMONEY)
}

public event_reset_hud(id)
{
	// Hide money?
	if (get_pcvar_num(cvar_disable_money))
		set_task(0.1, "task_hide_money", id+TASK_HIDEMONEY)
}

// Hide Player's Money Task
public task_hide_money(taskid)
{
	// Hide money
	message_begin(MSG_ONE, g_MsgHideWeapon, _, ID_HIDEMONEY)
	write_byte(HIDE_MONEY_BIT) // what to hide bitsum
	message_end()
	
	// Hide the HL crosshair that's drawn
	message_begin(MSG_ONE, g_MsgCrosshair, _, ID_HIDEMONEY)
	write_byte(0) // toggle
	message_end()
}

public message_money(msg_id, msg_dest, msg_entity)
{
	// Disable money setting enabled?
	if (!get_pcvar_num(cvar_disable_money))
		return PLUGIN_CONTINUE;
	
	fm_cs_set_user_money(msg_entity, 0)
	return PLUGIN_HANDLED;
}

// Set User Money
stock fm_cs_set_user_money(id, value)
{
	// Prevent server crash if entity's private data not initalized
	if (pev_valid(id) != PDATA_SAFE)
		return;
	
	set_pdata_int(id, OFFSET_CSMONEY, value)
}

And u don't need this amx_settings_api, zp50_core (This one is called inside zp50_ammopacks.inc)

[wicho]

Welcome back dude, i will check and test the code later..

[Catastrophe]

@H.RED
Check the code and u will find the forward isn't executed every frame its executed after some checks are done and the resultant ammopack change is not 0 I.e when AP are changed.So as of prethink its just does a check or two like many other plugins if not executing the forward. About the include ye sorry I just include everything and then remove what I don't need so I guess I forgot to remove the unused one this time

EDIT: Also the zp_ammopacks_get is a native which is used to get a players current Ap so I didn't quite get what u meant when u wrote that.

[H.RED.ZONE]

I did check the code, your checks are called inside Prethink. (Meaning it checks every frame and its not like any other plugin)
And "zp_ammopacks_get" is called when u set someones ammopacks = reason (zp_ammopacks_set(id, zp_ammopacks_get(id) + 100) It still calls and if u don't call, it will just set it. And non of the codes that set ammopacks can work if u don't get someones AP first.

[yokomo]

Seriously PreThink is overkill lol, just edit "zp50_ammopacks.sma" and call forward on these 2 event.

PHP Code:

public native_ammopacks_set(plugin_id, num_params)
{
    new id = get_param(1)
    
    if (!is_user_valid(id))
    {
        log_error(AMX_ERR_NATIVE, "[ZP] Invalid Player (%d)", id)
        return false;
    }
    
    new amount = get_param(2)
    
    g_AmmoPacks[id] = amount
    ExecuteForward(Forward_Change, Forward_Result, id, g_AmmoPacks[id])
    return true;
}

public client_putinserver(id)
{
    g_AmmoPacks[id] = get_pcvar_num(cvar_starting_ammo_packs)
    ExecuteForward(Forward_Change, Forward_Result, id, g_AmmoPacks[id])
} 


[Catastrophe]

@H.RED
i seriously didnt get your reference to zp50_ammopacks_get/set

@yokomo
thnx dude i never thought of that... much appreciated ;)

EDIT: H.RED if u mean wht yokomo said.. then thnx u actually told it to me earlier lol.
EDIT2: oh lol, i didnt actually check the entire code, so now i saw what H.RED gave me in the first code... Sorry ive got a little dumb, all this time ive spent away from scripting T_T

[wicho]

Maybe you should give an example of how to use the forward, so people can know how to use it..