[headline]

Hey guys, I am switching over to the new syntax and I am wondering how I should use the Menu. Not much documentation and I am doing terribly. Any help?

PHP Code:

public void OpenScrimMenu(int client)
{
    Menu MainMenu = new Menu(ScrimMenu, MenuAction_Select | MenuAction_End);
    MainMenu.SetTitle("Scrim Menu:");

    MainMenu.AddItem("pregame", "Start pregame");
    MainMenu.AddItem("knife", "Start the knife round");
    MainMenu.AddItem("start", "Start the scrim");
    MainMenu.AddItem("scramble", "Scramble teams");
    MainMenu.AddItem("transfer", "Transfer players");
    MainMenu.AddItem("help", "Help (Opens up a window)");
    
    DisplayMenu(Menu MainMenu, client, MENU_TIME_FOREVER);
}

public void ScrimMenu(Menu MainMenu, MenuAction action, int param1, int param2)
{
    switch (action)
    {
        case MenuAction_Select:
        {
            char item[64];
            MainMenu.GetMenuItem(Menu, param2, item, sizeof(item));
            
        }
        case MenuAction_End:
        {
            CloseHandle(MainMenu);
        }
    }
} 


[Potato Uno]

This seems to compile on Spider:

PHP Code:

#include <sourcemod>

#pragma semicolon 1
#pragma newdecls required

public void OpenScrimMenu(int client) 
{ 
    Menu MainMenu = new Menu(ScrimMenu, MenuAction_Select | MenuAction_End); 
    MainMenu.SetTitle("Scrim Menu:"); 

    MainMenu.AddItem("pregame", "Start pregame"); 
    MainMenu.AddItem("knife", "Start the knife round"); 
    MainMenu.AddItem("start", "Start the scrim"); 
    MainMenu.AddItem("scramble", "Scramble teams"); 
    MainMenu.AddItem("transfer", "Transfer players"); 
    MainMenu.AddItem("help", "Help (Opens up a window)"); 
     
    DisplayMenu(MainMenu, client, MENU_TIME_FOREVER); 
} 

public int ScrimMenu(Menu MainMenu, MenuAction action, int param1, int param2) 
{ 
    switch (action) 
    { 
        case MenuAction_Select: 
        { 
            char item[64]; 
            MainMenu.GetItem(param2, item, sizeof(item)); 
             
        } 
        case MenuAction_End: 
        { 
            CloseHandle(MainMenu); 
        } 
    } 
} 


I don't use methodmaps so I don't have any advice on that. (I still use the old traditional way of making this stuff.)

Read the docs about menus here: https://sm.alliedmods.net/new-api/menus/Menu

[WildCard65]

https://sm.alliedmods.net/new-api/menus/MenuHandler

[lingzhidiyu]

most like c++ or java.

PHP Code:

#include <sourcemod>

#pragma semicolon 1
#pragma newdecls required

public void OpenScrimMenu(int client) 
{ 
    Menu m = new Menu(ScrimMenu, MenuAction_Select | MenuAction_End); 
    m.SetTitle("Scrim Menu:"); 

    m.AddItem("pregame", "Start pregame"); 
    m.AddItem("knife", "Start the knife round"); 
    m.AddItem("start", "Start the scrim"); 
    m.AddItem("scramble", "Scramble teams"); 
    m.AddItem("transfer", "Transfer players"); 
    m.AddItem("help", "Help (Opens up a window)"); 
     
    m.Display(client, MENU_TIME_FOREVER); 
} 

public int ScrimMenu(Menu m, MenuAction action, int param1, int param2) 
{ 
    switch (action) 
    { 
        case MenuAction_Select: 
        { 
            char item[64]; 
            m.GetItem(param2, item, sizeof(item)); 
             
        } 
        case MenuAction_End: 
        { 
            delete m;
        } 
    } 
}