[strangeguy]

Hi!
Someone can fix this plugin? I'm beginner in scripts and i don't know what's mistakes I was made because this plugin is not compiled for me.

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta>
#include <nvault>

#define iKiller

new kill[32];
new g_save;

public plugin_init()
{
    register_plugin("Kill Count", "1.0", "Me");
    register_event("DeathMsg", "Event_DeathMsg", "a", "");
    g_save = nvault_open("kills");
    return 0;
}

public Event_DeathMsg()
{
    if (is_user_alive(iKiller) && cs_get_user_team(iVictim))
    {
        kill[iKiller]++;
    }
    return 0;
}

public plugin_natives()
{
    register_native("get_user_kills", "native_kills", 1);
    return 0;
}

public native_kills(id)
{
    return kill[id][0][0];
}

public client_disconnect(id)
{
    save(id);
    return 0;
}

public client_putinserver(id)
{
    set_task(2.00, "save_kills", id, "", 0, "", 0);
    return 0;
}

public save_kills(id)
{
    load(id);
    return 0;
}

public save(id)
{
    new vaultkey[64];
    new vaultdata[256];
    new name[33];
    get_user_name(id, name, 32);
    format(vaultkey, 63, "%s-/", name);
    format(vaultdata, 255, "%i#", kill[id]);
    nvault_set(g_save, vaultkey, vaultdata);
    return 0;
}

public load(id)
{
    new vaultkey[64];
    new vaultdata[256];
    new name[33];
    get_user_name(id, name, 32);
    format(vaultkey, 63, "%s-/", name);
    format(vaultdata, 255, "%i#", kill[id]);
    nvault_get(g_save, vaultkey, vaultdata, 255);
    replace_all(vaultdata, 255, "#", " ");
    new kill1[32];
    parse(vaultdata, kill1, 31);
    kill[id] = str_to_num(kill1);
    return 0;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ ansicpg1250\\ deff0\\ deflang1045{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ f0\\ fs16 \n\\ par }
*/

[Napoleon_be]

Found something i made for someone else in the past. Might be useful for you. Also, if you're trying to learn, don't just ask to "fix" a code. Ask for help and try to understand what's wrong.

PHP Code:

#include <amxmodx>
#include <nvault>

#pragma semicolon 1

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32;
#endif

#if AMXX_VERSION_NUM < 190
    #define client_disconnected(%1) client_disconnect(%1)
#endif

new const szVersion[] = "1.0.0";

new iKnifeCount[MAX_PLAYERS + 1];

new iVault;

public plugin_init() {
      register_plugin("KnifeKillCount", szVersion, "NapoleoN#");

      register_clcmd("say /kc", "KnifeCount");

      register_event("DeathMsg", "eDeath", "a", "1>0");

      iVault = nvault_open("KnifeKillCount");
}

public plugin_end() {
    nvault_close(iVault);
}

public client_disconnected(id) {
    SaveData(id);
}

public client_authorized(id) {
    LoadData(id);
}

public eDeath() {
    new iAttacker = read_data(1);
    new iClip, iAmmo, iWeapon;
    iWeapon = get_user_weapon(iAttacker, iClip, iAmmo);

    if(iWeapon == CSW_KNIFE && is_user_connected(iAttacker)) {
        iKnifeCount[iAttacker]++;
    }
}

public KnifeCount(id) {
    client_print(id, print_chat, "Knife KillCount: %i", iKnifeCount[id]);
}

SaveData(id) {
    new szAuth[35], szTemp[10];
    get_user_authid(id, szAuth, charsmax(szAuth));

    formatex(szTemp, charsmax(szTemp), "%i", iKnifeCount[id]);

    nvault_set(iVault, szAuth, szTemp);
}

LoadData(id) {
    new szAuth[35], szKillCount[10], szTemp[10];
    get_user_authid(id, szAuth, charsmax(szAuth));

    nvault_get(iVault, szAuth, szTemp, charsmax(szTemp));

    parse(szTemp, szKillCount, charsmax(szKillCount));

    iKnifeCount[id] = str_to_num(szKillCount);
} 


[fysiks]

iKiller and iVictim are not variables and you haven't assigned them any values. You need to first create the variables (e.g. new iKiller, iVictim) and then you need to assign them the proper value. In the case of the DeathMsg event, the first and second parameters of the even are the entity indices for the killer and the victim, respectively. You get the event parameters with read_data(). Here is an example of this in only two lines:

	new iKiller = read_data(1)
	new iVictim = read_data(2)

Also, you'll need to remove #define iKiller because it does not declare a variable and will break your code.

Other issues include that you are using cstrike functions but you have not included the cstrike module. Then, you're trying to index an array using 3 indices which is not value because the variable is a single dimension.

[strangeguy]

Originally Posted by fysiks iKiller and iVictim are not variables and you haven't assigned them any values. You need to first create the variables (e.g. new iKiller, iVictim) and then you need to assign them the proper value. In the case of the DeathMsg event, the first and second parameters of the even are the entity indices for the killer and the victim, respectively. You get the event parameters with read_data(). Here is an example of this in only two lines: new iKiller = read_data(1) new iVictim = read_data(2) Also, you'll need to remove #define iKiller because it does not declare a variable and will break your code. Other issues include that you are using cstrike functions but you have not included the cstrike module. Then, you're trying to index an array using 3 indices which is not value because the variable is a single dimension.

Thanks for help

[Natsheh]

Napoleon_be may i ask why did you add the condition "1!2" to the register_event ?

[Napoleon_be]

Originally Posted by Natsheh Napoleon_be may i ask why did you add the condition "1!2" to the register_event ?

That's my bad, it shouldn't be there, i removed it. I didn't take much time reading the code anyways. The first condition is enough. Yet, the code is incomplete. There should be a few more checks within the event function, such as iVictim != iAttacker, team attacker != team victim, ...

[iceeedr]

Originally Posted by Napoleon_be Found something i made for someone else in the past. Might be useful for you. Also, if you're trying to learn, don't just ask to "fix" a code. Ask for help and try to understand what's wrong. PHP Code: #include <amxmodx> #include <nvault> #pragma semicolon 1 #if !defined MAX_PLAYERS     const MAX_PLAYERS = 32; #endif #if AMXX_VERSION_NUM < 190     #define client_disconnected(%1) client_disconnect(%1) #endif new const szVersion[] = "1.0.0"; new iKnifeCount[MAX_PLAYERS + 1]; new iVault; public plugin_init() {       register_plugin("KnifeKillCount", szVersion, "NapoleoN#");       register_clcmd("say /kc", "KnifeCount");       register_event("DeathMsg", "eDeath", "a", "1>0");       iVault = nvault_open("KnifeKillCount"); } public plugin_end() {     nvault_close(iVault); } public client_disconnected(id) {     SaveData(id); } public client_authorized(id) {     LoadData(id); } public eDeath() {     new iAttacker = read_data(1);     new iClip, iAmmo, iWeapon;     iWeapon = get_user_weapon(iAttacker, iClip, iAmmo);     if(iWeapon == CSW_KNIFE && is_user_connected(iAttacker)) {         iKnifeCount[iAttacker]++;     } } public KnifeCount(id) {     client_print(id, print_chat, "Knife KillCount: %i", iKnifeCount[id]); } SaveData(id) {     new szAuth[35], szTemp[10];     get_user_authid(id, szAuth, charsmax(szAuth));     formatex(szTemp, charsmax(szTemp), "%i", iKnifeCount[id]);     nvault_set(iVault, szAuth, szTemp); } LoadData(id) {     new szAuth[35], szKillCount[10], szTemp[10];     get_user_authid(id, szAuth, charsmax(szAuth));     nvault_get(iVault, szAuth, szTemp, charsmax(szTemp));     parse(szTemp, szKillCount, charsmax(szKillCount));     iKnifeCount[id] = str_to_num(szKillCount); }

register_event("DeathMsg", "eDeath", "a", "4=knife")

[Napoleon_be]

Originally Posted by iceeedr register_event("DeathMsg", "eDeath", "a", "4=knife")

I had no clue, thanks for this.