[Mirk]

Hello guys,
Could you help me fix this plugin, please?

Writes that this error:
L 11/26/2015 - 09:48:41: [AMXX] [0] dont_bomb_camp.sma::PlayerPreThink (line 36)
L 11/26/2015 - 09:48:41: [ENGINE] Invalid entity 83
L 11/26/2015 - 09:48:41: [AMXX] Displaying debug trace (plugin "dont_bomb_camp.amxx")

- In the line 36 is code

entity_get_vector(weapbox, EV_VEC_origin, fOrigin);

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <cstrike>
#include <fakemeta_util>
#include <engine>

#define PLUGIN "Dont Bomb Camp"
#define VERSION "1.1"
#define AUTHOR "naven"

#define FADE_IN            (1<<0)
#define FADE_OUT        (1<<1)
#define FADE_HOLD        (1<<2)
#define FADE_LENGTH_PERM    (1<<0)

new g_msgFade;
new CvarDistance;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    g_msgFade = get_user_msgid("ScreenFade");
    
    register_forward(FM_PlayerPreThink, "PlayerPreThink");
    
    CvarDistance = register_cvar("gb_distance", "300.0")
}

public PlayerPreThink(id)
{
    new Float:fOrigin[3], Float: fPlayerOrigin[3];
    new weapbox, bomb = fm_find_ent_by_class(-1, "weapon_c4");
    if(bomb && (weapbox = pev(bomb, pev_owner)) > get_maxplayers())
    {
        entity_get_vector(weapbox, EV_VEC_origin, fOrigin);
        entity_get_vector(id, EV_VEC_origin, fPlayerOrigin);
        
        if(get_distance_f(fOrigin, fPlayerOrigin) < get_pcvar_float(CvarDistance))
        {
            new Float: punishPercentage = 1.0;
            new duration = (punishPercentage == 1.0) ? FADE_LENGTH_PERM : 1<<12;
            new holdTime = (punishPercentage == 1.0) ? FADE_LENGTH_PERM : 1<<8;
            new fadeType = (punishPercentage == 1.0) ? FADE_HOLD : FADE_IN;
            new blindness = 127 + floatround(128.0 * punishPercentage);
            
            message_begin(MSG_ONE, g_msgFade, {0,0,0}, id);
            write_short(duration);
            write_short(holdTime);
            write_short(fadeType);
            write_byte(0);
            write_byte(0);
            write_byte(0);
            write_byte(blindness);
            message_end();
            
            set_hudmessage(255, 0, 0, -1.0, 0.20, 0, 0.1, 0.5, _, _, -1);
            show_hudmessage(id, "Nekempi u bomby!");
        } else {
            punish_blind_stop(id);
        }
    }
}

public punish_blind_stop(id)
{
    message_begin(MSG_ONE, g_msgFade, {0,0,0}, id);
    write_short(0);
    write_short(1<<8);
    write_short(FADE_OUT);
    write_byte(0);
    write_byte(0);
    write_byte(0);
    write_byte(255);
    message_end();
} 


[tuty]

check if is a valid entity? pev_valid

[Bugsy]

I made the following changes:

• Removed PreThink and using a task instead with an interval of 1 second. PreThink was a terrible idea for something like this.
• Added a pev_valid() check to see if that fixes the error.
• Made the task only create if the current map has a 'de' prefix (de_dust, de_dust2, etc).

PHP Code:

#include <amxmodx>
#include <fakemeta>
#include <fakemeta_util>
#include <engine>

#define MAX_PLAYERS 32

new const Float:CheckInterval = 1.0;
new const HUDMessage[] = "Nekempi u bomby!";

new g_msgFade , CvarDistance;

public plugin_init()
{
    register_plugin( "Dont Bomb Camp" , "1.1b" , "naven/bugsy" );
    
    new szMap[ 3 ];
    get_mapname( szMap , charsmax( szMap ) );
    
    if ( szMap[ 0 ] == 'd' && szMap[ 1 ] == 'e' )
    {
        g_msgFade = get_user_msgid("ScreenFade");
        CvarDistance = register_cvar("gb_distance", "300.0");
        set_task( CheckInterval , "BombCheckTask" , .flags="b" );
    }
}

public BombCheckTask()
{
    new Float:fOrigin[ 3 ] , weapbox, bomb , id , playersList[32] , playersCount;
    
    bomb = fm_find_ent_by_class( -1 , "weapon_c4" );
    
    if ( bomb && !( 1 <= ( weapbox = pev( bomb , pev_owner ) ) <= MAX_PLAYERS ) && pev_valid( weapbox ) )
    {
        pev( weapbox , pev_origin , fOrigin );

        playersCount = find_sphere_class( 0 , "player" , get_pcvar_float( CvarDistance ) , playersList , sizeof( playersList ) , fOrigin );
            
        for ( new i = 0 ; i < playersCount ; i++ )
        {
            id = playersList[ i ];
            
            message_begin(MSG_ONE, g_msgFade, {0,0,0}, id);
            write_short(1<<12);
            write_short( FixedUnsigned16( CheckInterval , 1 << 12 ) );
            write_short(0);
            write_byte(0);
            write_byte(0);
            write_byte(0);
            write_byte(255);
            message_end();
            
            set_hudmessage(255, 0, 0, -1.0, 0.20, 0, 0.1, CheckInterval, _, _, -1)
            show_hudmessage(id, HUDMessage );
        }
    }
}

FixedUnsigned16(Float:flValue, iScale)
{
    new iOutput;

    iOutput = floatround(flValue * iScale);

    if ( iOutput < 0 )
        iOutput = 0;

    if ( iOutput > 0xFFFF )
        iOutput = 0xFFFF;

    return iOutput;
} 


[Mirk]

Originally Posted by tuty check if is a valid entity? pev_valid

No, I don't added valid entity, thank you for advise.

Originally Posted by Bugsy I made the following changes: Removed PreThink and using a task instead with an interval of 1 second. PreThink was a terrible idea for something like this. Added a pev_valid() check to see if that fixes the error. Made the task only create if the current map has a 'de' prefix (de_dust, de_dust2, etc). PHP Code: #include <amxmodx> #include <fakemeta> #include <fakemeta_util> #include <engine> #define MAX_PLAYERS 32 new const Float:CheckInterval = 1.0; new const HUDMessage[] = "Nekempi u bomby!"; new g_msgFade , CvarDistance; public plugin_init() {     register_plugin( "Dont Bomb Camp" , "1.1b" , "naven/bugsy" );          new szMap[ 3 ];     get_mapname( szMap , charsmax( szMap ) );          if ( szMap[ 0 ] == 'd' && szMap[ 1 ] == 'e' )     {         g_msgFade = get_user_msgid("ScreenFade");         CvarDistance = register_cvar("gb_distance", "300.0");         set_task( CheckInterval , "BombCheckTask" , .flags="b" );     } } public BombCheckTask() {     new Float:fOrigin[ 3 ] , weapbox, bomb , id , playersList[32] , playersCount;          bomb = fm_find_ent_by_class( -1 , "weapon_c4" );          if ( bomb && !( 1 <= ( weapbox = pev( bomb , pev_owner ) ) <= MAX_PLAYERS ) && pev_valid( weapbox ) )     {         pev( weapbox , pev_origin , fOrigin );         playersCount = find_sphere_class( 0 , "player" , get_pcvar_float( CvarDistance ) , playersList , sizeof( playersList ) , fOrigin );                      for ( new i = 0 ; i < playersCount ; i++ )         {             id = playersList[ i ];                          message_begin(MSG_ONE, g_msgFade, {0,0,0}, id);             write_short(1<<12);             write_short( FixedUnsigned16( CheckInterval , 1 << 12 ) );             write_short(0);             write_byte(0);             write_byte(0);             write_byte(0);             write_byte(255);             message_end();                          set_hudmessage(255, 0, 0, -1.0, 0.20, 0, 0.1, CheckInterval, _, _, -1)             show_hudmessage(id, HUDMessage );         }     } } FixedUnsigned16(Float:flValue, iScale) {     new iOutput;     iOutput = floatround(flValue * iScale);     if ( iOutput < 0 )         iOutput = 0;     if ( iOutput > 0xFFFF )         iOutput = 0xFFFF;     return iOutput; }

I love you Bugsy It is great code, thank you for helpfulness

[tuty]

Originally Posted by Mirk No, I don't added valid entity, thank you for advise.

what? Bugsy, explain kindly to this lad, what i have just said and what you have done.

[Bugsy]

Originally Posted by tuty check if is a valid entity? pev_valid

Originally Posted by Bugsy I made the following changes: Removed PreThink and using a task instead with an interval of 1 second. PreThink was a terrible idea for something like this. Added a pev_valid() check to see if that fixes the error. <- tuty said to do this, which I did for you. Made the task only create if the current map has a 'de' prefix (de_dust, de_dust2, etc).

Originally Posted by Mirk No, I don't added valid entity, thank you for advise.

Originally Posted by tuty what? Bugsy, explain kindly to this lad, what i have just said and what you have done.