[BeNq!]

Hello,

I have a code:

__loadFileClass( )
{
	new szFile[ 256 ];
	
	get_configsdir( szFile, 255 );
	format( szFile, 255, "%s/NameFile.ini", szFile );
	
	if( !file_exists( szFile ) )
		return;
	
	new szRow[ 256 ], iTrash,  iSize = file_size( szFile, 1 );
	
	for( new i = 0; i < iSize; i++ )
	{
		read_file( szFile, i, szRow, charsmax( szRow ), iTrash );
		
		if( ( contain( szRow, ";" ) != 0 ) && strlen( szRow ) )
		{
			replace( szRow, charsmax( szRow ), "[class]", "" );
			split( szRow, szClassNameBlock[ iLine ], charsmax( szClassNameBlock[ ] ), szItemNameBlock[ iLine ], charsmax( szItemNameBlock[ ] ), "[item]" );
			iLine++;
		}
	}  
}

and

for( new i = 0; i < iLine; i++ )
	{
		if( equali( classBuffer[ ciName ], szClassNameBlock[ i ] ) && equali( itemBuffer[ iiName ], szItemNameBlock[ i ] ) )
		{
			break;
		} 
	}

NameFile.ini:

[class]Test[item]ItemName
[class]Test[item]ItemName2
[class]Test2[item]ItemName3

How can I make it work that way:

[class]Test[item]ItemName,ItemName2,...
[class]Test2[item]ItemName3

So for classes e.g. "Test" to be assigned ItemName, ItemName2...

if( equali( classBuffer[ ciName ], szClassNameBlock[ i ] ) && equali( itemBuffer[ iiName ], szItemNameBlock[ i ] ) )
Class Test | ItemName
if( equali( classBuffer[ ciName ], szClassNameBlock[ i ] ) && equali( itemBuffer[ iiName ], szItemNameBlock[ i ] ) )
Class Test | ItemName2

[fysiks]

You simply need to parse the [item] text as a comma separated string list using strtok() or similar function.

[BeNq!]

Are you giving an example?

[SpawnerF]

You can use something like that

Spoiler

/* First, save the file !   -   Sublime AMXX Editor v1.9 */

#include <amxmodx>

#define PLUGIN  "New Plug-In"
#define VERSION "1.0"
#define AUTHOR  "Spawner"

#define string. _String_

#pragma semicolon 1 

new _multipleInput[][] = {  "[class]myClass1[item]item1,item2,item3[/item]", 
                            "[class]myClass2[item]2_item1,2_item2,3_item3[/item]",
                            "[class]myClass3[item]3_item1,3_item2,3_item3[/item]"
};

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_srvcmd("parse", "parse_Hook");
}

public parse_Hook(){
    
    for(new i = 0; i < sizeof _multipleInput; i++){
        
        new _myString[7][64];
        string.Split( _myString,
                string.GetBetween(_multipleInput[i], "[item]", "[/item]"),
                ','
        );
    
        server_print("Class name : %s", string.GetBetween(_multipleInput[i], "[class]", "[item]"));
    
        new i;
        while( strlen(_myString[i]) != 0  ){
        
            server_print("  [+] Item name : %s", _myString[i]);
            i++;
        
        }
    
    }
    
}

stock string.GetBetween( _content[], _begin[], _end[] ){
    
    new _Parse[ 256 ];
    
    if(     containi(_content, _begin )  != -1 &&
            containi(_content, _end ) != -1 )
    {
        new iStart, iEnd;
        
        iStart  = strfind(_content, _begin)  + strlen(_begin);
        iEnd    = strfind(_content, _end, _, iStart);
        
        //formatex( _Parse, iEnd - iStart, "%s", _content[iStart] );        
        copy( _Parse , iEnd - iStart , _content[ iStart ] );
        
        return _Parse;
    }
    
    _Parse = "Can't find it!";  return _Parse; // return "" ... crash the compiler ( AGAIN ! )
    
}

// <a href="https://forums.alliedmods.net/showpost.php?p=63298&postcount=14" target="_blank" rel="noopener">https://forums.alliedmods.net/showpo...8&postcount=14</a>
stock string.Split( p_szOutput[][], p_szInput[], p_szDelimiter, size = sizeof p_szOutput[], size2 = sizeof p_szOutput ) 
{ 
    new nIdx = 0, l = strlen(p_szInput);
    new nLen = (1 + copyc( p_szOutput[nIdx], size, p_szInput, p_szDelimiter ));
    
    while( (nLen < l) && (++nIdx < size2) ) 
        nLen += (1 + copyc( p_szOutput[nIdx], size, p_szInput[nLen], p_szDelimiter ));

    return nIdx;
}

Edit :
Output

] parse
Class name : myClass1
	[+] Item name : item1
	[+] Item name : item2
	[+] Item name : item3
Class name : myClass2
	[+] Item name : 2_item1
	[+] Item name : 2_item2
	[+] Item name : 3_item3
Class name : myClass3
	[+] Item name : 3_item1
	[+] Item name : 3_item2
	[+] Item name : 3_item3

[fysiks]

SpawnerF, please stop trying to proliferate your dot notation. It provided little if any benefit, is confusing (especially for new coders), and completely unnecessary in this language.

[SpawnerF]

I never said that it's important, it's just my way of coding, sorry if it does bother you but I like it like that.

[fysiks]

Strings should never be returned from functions especially general purpose functions.

I'm not sure what angle brackets do for creating an array but it's not wise to use extremely obscure features when providing support on these forums unless it's the only way to do it.

containi() returns the position in the string where the search string starts. If it is not found, it will return -1. So "~containi()" will evaluate as True when the string is NOT found and when the string does not start at the beginning.

[SpawnerF]

Strings should never be returned from functions especially general purpose functions.

What do you suggest then?

I'm not sure what angle brackets do for creating an array but it's not wise to use extremely obscure features when providing support on these forums unless it's the only way to do it.

It's a macro replaced by the pre-processor, I add it because when I do charsmax(p_szOutput[]) I get an error saying "indeterminate array size" but nvm It's fixed I updated my code adding the size parameters using sizeof in Split func.

[fysiks]

Originally Posted by SpawnerF Strings should never be returned from functions especially general purpose functions. What do you suggest then?

Strings should be passed as byref function parameters the same way that every AMX Mod X function that generates a string as its output. For example, get_user_name() takes the string array and the length as parameters.

Originally Posted by SpawnerF I'm not sure what angle brackets do for creating an array but it's not wise to use extremely obscure features when providing support on these forums unless it's the only way to do it. It's a macro replaced by the pre-processor, I add it because when I do charsmax(p_szOutput[]) I get an error saying "indeterminate array size" but nvm It's fixed I updated my code adding the size parameters using sizeof in Split func.

charsmax and sizeof are pre-processor functions so it is not possible to use them on arrays that don't have a determined size at compile time. Therefore, you can't use them on any variables in a function's prototype that doesn't have a defined size.

Given this, I don't know how your Split() function can actually work since you are using sizeof in the function's prototype. Not sure why it even compiles. If you need to know the dimensions of the arrays provided to the function, you'll need to pass those dimensions into the function as shown in the URL that you referenced.

Did you test your code?

[SpawnerF]

Yes it's working. You can try it.

edit : sizeof is a pre-processor function?