[vato loco [GE-S]]

Originally Posted by malec321 Thanks a lot guys!

which guys !?

you're welcome

[ConnorMcLeod]

Would be preferable to use get_players.

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN  "Alive Player"
#define VERSION "1.0"
#define AUTHOR  "vato loco [GE-S]"

#define TASK_GETPLAYER    37852
#define TASK_LOOP_TIME    2.0

new g_SyncTeamCount

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)

    state OutOfRound

    g_SyncTeamCount = CreateHudSyncObj()

    register_logevent("LogEvent_Round_Start", 2, "1=Round_Start")
    register_logevent("Logevent_Round_End", 2, "1=Round_End")

    RegisterHam(Ham_Spawn, "player", "client_disconnect", true)
    RegisterHam(Ham_Killed, "player", "client_disconnect", true)
}

public client_disconnect() <OutOfRound> {}
public client_disconnect() <InRound>
{
    GetPlayers()
}

public LogEvent_Round_Start()
{
    state InRound
    remove_task( TASK_GETPLAYER )
    set_task(TASK_LOOP_TIME, "GetPlayers", TASK_GETPLAYER, .flags="b")
}

public Logevent_Round_End()
{
    state OutOfRound
    remove_task( TASK_GETPLAYER )
}

public GetPlayers()
{
    new iPlayers[32], iNum, iTnum, iCTnum
    get_players(iPlayers, iNum, "a")
    for(--iNum; iNum>=0; iNum--)
    {
        switch( cs_get_user_team( iPlayers[iNum] ) )
        {
            case CS_TEAM_T:++iTnum
            case CS_TEAM_CT:++iCTnum
        }
    }

    set_hudmessage(255, 50, 0, -1.0, 0.04, _, _, TASK_LOOP_TIME+0.01, _,  _, 1)
    ShowSyncHudMsg(0, g_SyncTeamCount, "[Alive T: %d] - [Alive CT: %d]", iTnum, iCTnum)
} 


[malec321]

Originally Posted by vato loco [GE-S] which guys !? you're welcome

You Thanks

[blacktample]

Originally Posted by ConnorMcLeod Would be preferable to use get_players. PHP Code: //code...

PHP Code:

if(iTnum == 1)
{
ShowSyncHudMsg(0, g_SyncTeamCount, "Alive hiders: Only one!! || Alive seekers: %d", iCTnum)
}
else if(iTnum == 1 || iCTnum == 1)
{
ShowSyncHudMsg(0, g_SyncTeamCount, "[ 1 vs 1 ]")
}
else
{
ShowSyncHudMsg(0, g_SyncTeamCount, "Alive hiders: %d || Alive seekers: %d", iTnum, iCTnum)
} 


how to code 1 vs 1

[Lolz0r]

@ConnorMcLeod, will do it [Alive T: %d] in red color and [Alive CT: %d] in blue.

[MAJESTIC_SZ]

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <hamsandwich>

#define PLUGIN  "Alive Player"
#define VERSION "1.0"
#define AUTHOR  "vato loco [GE-S]"

#define TASK_GETPLAYER     37852
#define SetBits(%1,%2)       %1 |= 1<<(%2 & 31)
#define ClearBits(%1,%2)   %1 &= ~(1<<(%2 & 31))
#define GetBits(%1,%2)       %1 &  1<<(%2 & 31)

new g_bitAlive
new g_SyncTeam1
new g_SyncTeam2
new g_iMaxPlayers

public plugin_init() 
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn", 1)
    RegisterHam(Ham_Killed, "player", "fw_PlayerKilled", 1)
    
    g_SyncTeam1 = CreateHudSyncObj()
    g_SyncTeam2 = CreateHudSyncObj()
    g_iMaxPlayers = get_maxplayers()
    
    set_task(0.5, "GetPlayer", TASK_GETPLAYER, _, _, "b")
}

public client_putinserver(id)
{
    ClearBits(g_bitAlive, id)
}

public client_disconnected(id)
{
    ClearBits(g_bitAlive, id)
}

public fw_PlayerSpawn(id)
{
    if(is_user_alive(id))
    {
        SetBits(g_bitAlive, id)
    }
}

public fw_PlayerKilled(id)
{
    ClearBits(g_bitAlive, id)
}

public GetPlayer()
{
    static id, iTeam
    new iPlayerTrroNum, iPlayerCtNum
    
    for(id = 1; id <= g_iMaxPlayers; id++)
    {
        if(GetBits(g_bitAlive, id))
        {
            iTeam = get_user_team(id)
            
            switch(iTeam)
            {
                case 1: ++iPlayerTrroNum
                    
                case 2: ++iPlayerCtNum
                    
            }
            ShowCustomSync(id, g_SyncTeam1, "TE vivos: %d", 255, 0, 0, 0.01, 1, iPlayerTrroNum)
            ShowCustomSync(id, g_SyncTeam2, "^nCT vivos: %d", 0, 100, 255, 0.01, 2, iPlayerCtNum)
        }
    }
}

ShowCustomSync(id, SyncType, Msg[], Red, Green, Blue, Float:xPos, Channel, TeamCount) 
{
    set_hudmessage(Red, Green, Blue, xPos, 0.14, _, _, 2.0, _,  _, Channel)
    ShowSyncHudMsg(id, SyncType, Msg, TeamCount)
} 


Hello 12 years later
The code wrote by ConnorMcLeod is not working properly for me.
I have edited line 75 so the plugin shows 2 separated messages, 1 on each line.
But the plugin is not counting players as it should.
Example:
We are 20 on server, 10 vs 10.
Plugin shows 8 vs 7.
Some times we are 9 vs 8.
The plugin shows 5 vs 5.
Or like the image below:


Or any other amounts.
What can it be?
I compiled it using the latest amx 10.
I use rehlds, regame, amx10 and metamod-r.

Thank you.

[Jhob94]

Pai sapo?
Btw, the code seems ok. It should work perfectly if you use default amxmodx. Since you running rehlds and other stuff i have no idea what kind of impact it can have on plugin’s performance.

Edit:
Try with get_players, flags ae, will instantly give you the count per team. Maybe this way it works

[MAJESTIC_SZ]

Originally Posted by Jhob94 Pai sapo? Btw, the code seems ok. It should work perfectly if you use default amxmodx. Since you running rehlds and other stuff i have no idea what kind of impact it can have on plugin’s performance. Edit: Try with get_players, flags ae, will instantly give you the count per team. Maybe this way it works

Thank you for your answer!
I don't really know how to code, i can edit somethings only...
Where do i edit that? Here?

PHP Code:

set_task(0.5, "GetPlayer", TASK_GETPLAYER, _, _, "b") 


to:

PHP Code:

set_task(0.5, "GetPlayers", TASK_GETPLAYERS, _, _, "ae") 


?

Another thing i noticed is the hud info is not permanently shown on screen. It fades away and then comes back, this happens randomly, but since the purpose is to help alive players, it should be permanent.

[DJEarthQuake]

This will accurately count and display in team colors. Green for hostages.

PHP Code:

/*Spin-off idea derived from request by malec321*/
#include <amxmodx>
#include <engine_stocks>
#include <fakemeta>

#define PLUGIN  "!Alive"
#define VERSION "1.0.1"
#define AUTHOR  "SPiNX | vato loco [GE-S]"

#define TASK_GETPLAYER    37852
#define TASK_LOOP_TIME    1.0

#define SetBits(%1,%2)       %1 |=   1<<(%2 & 31)
#define ClearBits(%1,%2)     %1 &= ~(1<<(%2 & 31))
#define GetBits(%1,%2)       %1 &    1<<(%2 & 31)

#if !defined client_disconnect
#define client_disconnected client_disconnect
#endif

#define charsmin -1

new g_AI, g_cvar_cont, g_continuous, g_rescue
static g_Hostie

static g_SyncTeamCount_CT,  g_SyncTeamCount_H, g_SyncTeamCount_T

new const szEnt[] = "hostage_entity"
new const szRescue[] = "2=Rescued_A_Hostage"
new const CvarDesc[] = "Show who is alive as round ends. 2 is debugger."

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)

    g_SyncTeamCount_CT = CreateHudSyncObj()
    g_SyncTeamCount_H = CreateHudSyncObj()
    g_SyncTeamCount_T = CreateHudSyncObj()

    register_logevent("@rescue", 3, szRescue)
    register_logevent("@LogEvent_Round_Start", 2, "1=Round_Start")
    g_continuous = register_logevent("@Logevent_Round_End", 2, "1=Round_End")
    bind_pcvar_num(create_cvar("continuous_player_alive", "0",FCVAR_SERVER, CvarDesc,.has_min = true, .min_val = 0.0, .has_max = true, .max_val = 2.0), g_cvar_cont)
    g_Hostie = has_map_ent_class(szEnt) ? 1 : 0
    state OFF
}

@rescue()
    ++g_rescue

@LogEvent_Round_Start()
{
    g_rescue = 0
    state ON
    @solid_state()

    g_cvar_cont ? disable_logevent(g_continuous) : enable_logevent(g_continuous)
}

@Logevent_Round_End()
    @solid_state()

public client_putinserver(id)
{
    if(is_user_connected(id) && is_user_bot(id))
    {
        SetBits(g_AI, id)
    }
}

public client_disconnected(id)
    ClearBits(g_AI, id)

@solid_state()<ON>{set_task(TASK_LOOP_TIME, "@GetPlayers", TASK_GETPLAYER, .flags="b");if(g_cvar_cont>1)server_print("%s is on...", PLUGIN);}

@solid_state()<OFF>{remove_task( TASK_GETPLAYER );if(g_cvar_cont>1)server_print("%s is off..", PLUGIN);}

@GetPlayers()
{
    new
    ALIVE,
    R,G,B, id,
    Float:X, Float:Y,
    iPlayers[MAX_PLAYERS], iNum, iTnum, iCTnum;

    get_players(iPlayers, iNum, "a")

    if(iNum)
    {
        for(new ALIVE; ALIVE < iNum; ++ALIVE)
        {
            switch( get_user_team( iPlayers[ALIVE] ) )
            {
                case 1: ++iTnum
                case 2: ++iCTnum
            }
        }

        id = iPlayers[ALIVE]

        if(iTnum && iCTnum)
        {
            if(~GetBits(g_AI, id))
            {
                R = 255, X = 0.391;
                set_hudmessage(R, G, B, X, Y, _, _, TASK_LOOP_TIME+0.01, _,  _, 1)

                ShowSyncHudMsg(id, g_SyncTeamCount_T, "[Alive T: %d]", iTnum)

                R = 0, B = 255, X =0.54;
                set_hudmessage(R, G, B, X, Y, _, _, TASK_LOOP_TIME+0.01, _,  _, 1)

                ShowSyncHudMsg(id, g_SyncTeamCount_CT, "[Alive CT: %d]", iCTnum)
                if(g_Hostie)
                {
                    G = 255, B = 0, X =0.462;
                    set_hudmessage(R, G, B, X, Y, _, _, TASK_LOOP_TIME+0.01, _,  _, 1)
                    new iHostage,  Is_Hostage_alive, iHostie_count
                    while ((iHostage = find_ent(iHostage , szEnt)) > 0)
                    {
                        Is_Hostage_alive = pev(iHostage, pev_health)
                        if(Is_Hostage_alive)
                            iHostie_count++
                    }
                    ShowSyncHudMsg(id, g_SyncTeamCount_H, "[Hostages: %d]", iHostie_count-g_rescue)
                }
            }
        }state OFF
    }state OFF
} 


[Ark_Procession]

Originally Posted by MAJESTIC_SZ Thank you for your answer! I don't really know how to code, i can edit somethings only... Where do i edit that? Here? PHP Code: set_task(0.5, "GetPlayer", TASK_GETPLAYER, _, _, "b")  to: PHP Code: set_task(0.5, "GetPlayers", TASK_GETPLAYERS, _, _, "ae")  ? Another thing i noticed is the hud info is not permanently shown on screen. It fades away and then comes back, this happens randomly, but since the purpose is to help alive players, it should be permanent.

this is the one i am using with dhud:

/* Sublime AMXX Editor v2.2 */

#pragma semicolon 1

#include <amxmodx>

#define PLUGIN  "Show Players"
#define VERSION "1.0"
#define AUTHOR  "NapoleoN#"

#define MSGID 81045

#if !defined MAX_PLAYERS
    const MAX_PLAYERS = 32;
#endif

enum _:ePlayerInfo
{
    iTotalPlayers,
    iCtPlayers,
    iCtAlive,
    iTerPlayers,
    iTerAlive
};

new iInfo[ePlayerInfo];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
}

public client_putinserver(id)
{
    iInfo[iTotalPlayers]++;

    if(!task_exists(MSGID))
    {
        set_task(10.0, "displayMessage", MSGID);
    }
}


#if AMXX_VERSION_NUM < 183
public client_disconnect(id)
#else
public client_disconnected(id)
#endif
{
    iInfo[iTotalPlayers]--;

    if(iInfo[iTotalPlayers] == 0 && task_exists(MSGID))
    {
        remove_task(MSGID);
    }
}

public displayMessage()
{
    if(task_exists(MSGID))
    {
        iInfo[iTerPlayers] = GetPlayersTeamNum(CS_TEAM_T, false);

        iInfo[iTerAlive] = GetPlayersTeamNum(CS_TEAM_T, true);

        iInfo[iCtPlayers] = GetPlayersTeamNum(CS_TEAM_CT, false);

        iInfo[iCtAlive] = GetPlayersTeamNum(CS_TEAM_CT, true);

        set_hudmessage(255, 100, 0, -1.0, 0.0, 0, 0.0, 1.1, 0.1, 0.2, -1);
        show_dhudmessage(0, "T: %i/%i | CT: %i/%i", iInfo[iTerAlive], iInfo[iTerPlayers], iInfo[iCtAlive], iInfo[iCtPlayers]);

        set_task(1.0, "displayMessage", MSGID);
    }
}

stock GetPlayersTeamNum(CsTeams:Team, bool:alive)
{
    new iPlayers[MAX_PLAYERS], iNum;
    get_players(iPlayers, iNum, alive ? "ae" : "e", Team == CS_TEAM_CT ? "CT" : "TERRORIST");
    return iNum;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/