[Exolent[jNr]]

Sylwester, I was making this myself for him, but I have no anger towards you that you released yours.
I'm just curious how you would read the floated time value from that byte code because I finally found the pattern but I could not read the float.

[Sylwester]

I skipped reading player time since it was impossible to change played time of a fakeclient.
Anyway, converting those bits to float is not so hard. Here is a fragment of a receive_data() function from my DuplicateServerInfo plugin with reading time included:

PHP Code:

public receive_data(){
    static cache[2048], len
    len = socket_recv(g_socket, cache, 2047)
    if(len < 5)
        return
    if(!equal( cache, { -1, -1, -1, -1 }, 4 ) )
        return
    if(cache[4] == 'D'){ //(players details) A2S_PLAYER reply if sent challange number is correct
        g_s_players = cache[5]

        new j=6
        for(new i=0; i<g_s_players; i++){
            j++
            j += copyc(g_s_player_name[i], 31, cache[j], 0)+1
            if(cache[j+3] < 0){ //negative number
                g_s_player_kills[i] = -((((255-ret_ac(cache[j+3]))*256+255-ret_ac(cache[j+2]))*256+255-ret_ac(cache[j+1]))*256+255-ret_ac(cache[j])+1)
            }else{//positive number
                g_s_player_kills[i] = (((ret_ac(cache[j+3])*256)+ret_ac(cache[j+2]))*256+ret_ac(cache[j+1]))*256+ret_ac(cache[j])
            }

            /* reading player time - start */
            new time_bits
            for(new k=7; k>=4; k--){
                time_bits<<=8
                time_bits+=ret_ac(cache[j+k])
            }
            new Float:time = Float:time_bits
            /* reading player time - end */

            j+=8
        }
        update_players()
    }

//..... 


[lucas_7_94]

hey , sylwester , can you make a simple plugin to look the map is remaiding X server ?

Ex : [AMXX] The ip xxx.xxx.xxx.xxx:27015 is now in map 'de_dust2' with 0/16 Players!

[Sylwester]

I'm not sure if this is what you wanted:

PHP Code:

#include <amxmodx>
#include <sockets>

new g_socket = 0
new g_host[32]
new g_port

public plugin_init(){
    register_plugin("Server Info", "1.0", "Sylwester")
    register_concmd("amx_server_info", "cmd_server_info")
}

public cmd_server_info(id){
    new tmp[64], tmp2[32], error
    read_args(tmp, 63)
    remove_quotes(tmp)
    strtok(tmp, g_host, 63, tmp2, 31, ':')
    g_port = str_to_num(tmp2)
    if(g_socket != 0){
        socket_close(g_socket)
        g_socket = 0
    }
    g_socket = socket_open(g_host, g_port, SOCKET_UDP, error)
    if(g_socket <= 0 || error){
        new error_msg[64]
        switch(error){
            case 0: error_msg = "unknown"
            case 1: error_msg = "error while creating socket"
            case 2: error_msg = "could not resolve hostname"
            case 3: format(error_msg, 63, "could not connect to %s:%d", g_host, g_port)
        }
        client_print(id, print_console, "Socket error: %s", error_msg)
        return
    }
    new cache[32]
    format(cache, 25, "%c%c%c%c%c%s%c", 255, 255, 255, 255, 84, "Source Engine Query", 0 )
    socket_send2(g_socket, cache, 25)
    set_task(0.1, "check_socket")
}

public check_socket(){
    static cnt
    cnt++
    if(g_socket <= 0){
        cnt = 0
        return
    }
    if(socket_change(g_socket, 1)){
        receive_data()
    }
    if(cnt!=20)
        set_task(0.1, "check_socket")
    else
        cnt=0
}

public receive_data(){
    static cache[2048], len, hostname[64], map[64], players, maxplayers, dir[64], game_desc[64]
    len = socket_recv(g_socket, cache, 2047)
    if(len < 5)
        return
    if(!equal( cache, { -1, -1, -1, -1 }, 4 ) )
        return
    if(cache[4] == 'I'){ //(server details) A2S_INFO reply
        new i = 6
        i += copyc(hostname, 127, cache[i], 0)+1
        i += copyc(map, 63, cache[i], 0)+1
        i += copyc(dir, 63, cache[i], 0)+1
        i += copyc(game_desc, 63, cache[i], 0)+1
        players = cache[i+2]
        maxplayers = cache[i+3]
        client_print(0, print_chat, "Server @ ^"%s:%d^": %s ## Map: %s ## Players: %d/%d", g_host, g_port, hostname, map, players, maxplayers)
        if(g_socket != 0){
            socket_close(g_socket)
            g_socket = 0
        }
    }
} 


write: amx_server_info "ip:port"
in console.

[lucas_7_94]

Thanks Awesome! i go to test

EDIT : Works very good , thnx.