[xkp]

Well as many of you know or not known Amxmodx are keep updating & optimize stuff (1.8.3-dev) and thats okey but it is very difficult to understand what exactly are repaired or fixed.

So i try to take a look at git and i find the new functionality in _amxconst_ MAX_PLAYERS that defines MAX_PLAYERS but when I try to update some of the plugins I encounter a lot of errors.

I like to update this plugin first: Voteban made by @Alka - i use the latest non-public version becouse is far more updated in this posts.

Original voteban-plugin:

#define MAX_PLAYERS 32
// All is here
new g_iData[MAX_PLAYERS+1][MAX_PLAYERS+1];

New functuality from AMXX , amxconst.inc
---> #define MAX_PLAYERS 33 /* Maximum number of players AMX Mod X supports */

=================
With amxconst MAX_PLAYERS 33 and without + 1

new g_iData[MAX_PLAYERS][MAX_PLAYERS];

This returns: Error: Array index out of bounds (variable "g_iData") on line 66
=================
Without #define MAX_PLAYERS 32

new g_iData[MAX_PLAYERS+1][MAX_PLAYERS+1];

This is working but 33+1 (34?) - over the max limit.

[Arkshine]

If you compile the original plugin as it is, MAX_PLAYERS will be redefine to 32. You will get a warning with compiler but can be ignored without problem.

If you want to compile without warning, just remove the MAX_PLAYERS definition in plugin, and the +1 where MAX_PLAYERS is used (so what you did, but you did not removed previous MAX_PLAYERS definition)

[xkp]

Well i removed the definion of MAX_PLAYERS from the source, and i remove the + 1 in g_iData.

Spoiler

#include <amxmodx>

#define PLUGIN "Vote Ban"
#define VERSION "1.2"
#define AUTHOR "Alka"


// All is here
new g_iData[MAX_PLAYERS][MAX_PLAYERS];

// Macros for easy use
#define g_iVotes(%0)            g_iData[0][%0-1]
#define g_iVotedPlayer(%0)      g_iData[%0][MAX_PLAYERS]
#define g_iPlayerMenuData(%0,%1)    g_iData[%0][%1]

// Goodbye, get_players
new g_iConnected;

// You've voted without entering a reason? INVALID VOTE!
new g_iConfirmed;

new g_iMsgidSayText;

enum _:PCVARS
{
    CVAR_PERCENT = 0,
    CVAR_BANTYPE,
    CVAR_BANTIME
};

new g_szCvarName[PCVARS][] =
{
    "voteban_percent",
    "voteban_type",
    "voteban_time"
};

new g_szCvarValue[PCVARS][] =
{
    "80",
    "1",
    "60"
};

new g_iPcvar[PCVARS];
new g_szLogFile[64];

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_saycmd("voteban", "Cmd_VoteBan", -1, "");
    register_clcmd("_Voteban_Reason", "Cmd_VoteBanReason", -1, "");
    
    register_dictionary("voteban.txt");
    
    for(new i = 0 ; i < PCVARS; i++)
    {
        g_iPcvar[i] = register_cvar(g_szCvarName[i], g_szCvarValue[i]);
    }
    
    g_iMsgidSayText = get_user_msgid("SayText");
    
    new szLogInfo[] = "amx_logdir";
    get_localinfo(szLogInfo, g_szLogFile, charsmax(g_szLogFile));
    add(g_szLogFile, charsmax(g_szLogFile), "/voteban");
    
    if(!dir_exists(g_szLogFile))
        mkdir(g_szLogFile);
        
    new szTime[32];
    get_time("%d-%m-%Y", szTime, charsmax(szTime));
    format(g_szLogFile, charsmax(g_szLogFile), "%s/%s.log", g_szLogFile, szTime);
}

public client_putinserver(id)
{
    g_iVotes(id) = 0
    g_iConnected |= (1 << id-1)
    g_iConfirmed &= ~(1 << id-1)
}

public client_disconnect(id)
{
    g_iConnected &= ~(1 << id-1)
    g_iConfirmed &= ~(1 << id-1)
    
    if(g_iVotedPlayer(id))
    {
        g_iVotes(g_iVotedPlayer(id))--;
        g_iVotedPlayer(id) = 0;
    }
    
    if(g_iVotes(id))
    {
        for(new i = 1; i <= MAX_PLAYERS; i++)
        {
            if(g_iVotedPlayer(i) == id)
                g_iVotedPlayer(i) = 0
        }
    }
}

public Cmd_VoteBan(id)
{
    if(get_playersnum() < 3)
    {
        client_printc(id, "\g[Voteban] \d%L", id, "MORE_PLAYERS");
        return PLUGIN_HANDLED;
    }
    
    if(g_iVotedPlayer(id))
    {
        if(g_iConfirmed & (1 << id-1))
        {
            ConfirmMenu(id)
            return PLUGIN_CONTINUE;
        }
        else
            g_iVotedPlayer(id) = 0
    }
    
    VoteBanMenu(id);
    
    return PLUGIN_CONTINUE;
}

VoteBanMenu(id)
{
    static menushow[70], szName[32], count, percent;
    
    count = formatex(menushow, charsmax(menushow), "\r[Voteban] \y%L", id, "SELECT_PLAYER")
    // If there's more than one page, display "Page: x/y"
    if(get_playersnum() > 7)
        formatex(menushow[count], charsmax(menushow)-count, "^n%L:\r", id, "CURRENT_PAGE");
    
    new menu = menu_create(menushow, "Menu_VoteBan");
    count = 0;
    
    for(new i = 1; i <= MAX_PLAYERS; i++)
    {
        if(!(g_iConnected & (1 << i-1))) continue;
        
        g_iPlayerMenuData(id, count) = i;
        count++;
        
        get_user_name(i, szName, 31);
        
        percent = get_percent(g_iVotes(i), get_playersnum());
        
        formatex(menushow, charsmax(menushow), "%s \r[\%s%d%%\r]", szName, !percent ? "w" : "y", percent);
        
        menu_additem(menu, menushow, "", 0);
    }
    
    formatex(menushow, charsmax(menushow), "\y%L", id, "EXIT_NAME"); 
    menu_setprop(menu, MPROP_EXITNAME, menushow);
    
    formatex(menushow, charsmax(menushow), "%L", id, "BACK_NAME"); 
    menu_setprop(menu, MPROP_BACKNAME, "Anterior");
    
    formatex(menushow, charsmax(menushow), "%L^n", id, "NEXT_NAME"); 
    menu_setprop(menu, MPROP_NEXTNAME, "Siguiente^n");
    
    menu_setprop(menu, MPROP_NUMBER_COLOR, "\r");
    
    menu_display(id, menu, 0);
    
    return PLUGIN_HANDLED;
}

public Menu_VoteBan(id, menu, key)
{
    if(key == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new iPlayer = g_iPlayerMenuData(id, key)
    
    if(g_iConnected & (1 << iPlayer-1))
    {
        g_iVotedPlayer(id) = iPlayer
        g_iConfirmed &= ~(1 << id-1)
        client_print(id, print_center, "* %L *", id, "ENTER_REASON");
        client_cmd(id, "messagemode _Voteban_Reason");
    }
    else
        VoteBanMenu(id);
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

ConfirmMenu(id)
{
    new szName[100]
    get_user_name(g_iVotedPlayer(id), szName, 31)
    format(szName, charsmax(szName), "\r[Voteban] \w%L \y%s^n%L", id, "ALREADY_VOTEBAN", szName, id, "CANCEL_VOTEBAN")
    new menu = menu_create(szName, "Menu_Confirm")
    
    formatex(szName, charsmax(szName), "%L", id, "YES_CANCEL")
    menu_additem(menu, szName, "")
    
    formatex(szName, charsmax(szName), "%L", id, "NON_CANCEL")
    menu_additem(menu, szName, "")
    
    menu_setprop(menu, MPROP_EXIT, MEXIT_NEVER)
    menu_setprop(menu, MPROP_NUMBER_COLOR, "\r");
    
    menu_display(id, menu)
}

public Menu_Confirm(id, menu, key)
{
    menu_destroy(menu)
    
    if(key != 0)
        return PLUGIN_HANDLED;
    
    g_iVotes(g_iVotedPlayer(id))--
    g_iVotedPlayer(id) = 0
    g_iConfirmed &= ~(1 << id-1)
    
    VoteBanMenu(id)
    
    return PLUGIN_HANDLED
}

public Cmd_VoteBanReason(id)
{
    if(!g_iVotedPlayer(id))
        return PLUGIN_HANDLED;
    
    new szArgs[50], szName[2][32], iPlayer;
    read_argv(1, szArgs, charsmax(szArgs));
    iPlayer = g_iVotedPlayer(id)
    g_iConfirmed |= (1 << id-1)
    
    get_user_name(id, szName[0], charsmax(szName[]));
    get_user_name(iPlayer, szName[1], charsmax(szName[]));
    
    for(id = 1; id <= MAX_PLAYERS; id++)
    {
        if(!(g_iConnected & (1 << id-1))) continue;
         
        client_printc(id, "\g[Voteban] \t%s \d%L \t%s\d (%L: %s)", szName[0], id, "VOTEBANNED_FOR", szName[1], id, "VOTEBAN_REASON", szArgs);
    }
            
    g_iVotes(iPlayer)++;
    CheckVotes(iPlayer, id, szArgs);
    
    return PLUGIN_HANDLED;
}

public CheckVotes(id, voter, const reason[])
{
    new szTime = get_pcvar_num(g_iPcvar[CVAR_BANTIME]);
    
    if(get_percent(g_iVotes(id), get_playersnum()) >= get_pcvar_num(g_iPcvar[CVAR_PERCENT]))
    {
        switch(get_pcvar_num(g_iPcvar[CVAR_BANTYPE]))
        {
            case 1:
            {
                new szAuthid[32];
                get_user_authid(id, szAuthid, charsmax(szAuthid));
                server_cmd("kick #%d;wait;wait;wait;banid %d ^"%s^";wait;wait;wait;writeid", get_user_userid(id), szTime, szAuthid);
            }
            case 2:
            {
                new szIp[32];
                get_user_ip(id, szIp, charsmax(szIp), 1);
                server_cmd("kick #%d;wait;wait;wait;addip %d ^"%s^";wait;wait;wait;writeip", get_user_userid(id), szTime, szIp);
            }
        }
    
        g_iVotes(id) = 0;
        
        new szName[2][32];
        get_user_name(id, szName[0], charsmax(szName[]));
        get_user_name(voter, szName[1], charsmax(szName[]));
        
        for(new i = 1; i <= MAX_PLAYERS; i++)
        {
            if(!(g_iConnected & (1 << i-1))) continue;
            
            client_printc(i, "\g[Voteban] \t%s \d%L \g%d\d %L! %L (%s): %s", szName[0], i, "VOTEBANNED", szTime, i, "MINUTES", i, "VOTEBAN_REASON", szName[1], reason);
        }
        
        log_to_file(g_szLogFile, "%s banned for %d min. Reason (%s): %s", szName[0], szTime, szName[1], reason);
    }
}

stock get_percent(value, tvalue)
{     
    return floatround(floatmul(float(value) / float(tvalue) , 100.0));
}

stock register_saycmd(saycommand[], function[], flags = -1, info[])
{
    new szTemp[64];
    formatex(szTemp, charsmax(szTemp), "say %s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say_team %s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say /%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say .%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say_team /%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
    formatex(szTemp, charsmax(szTemp), "say_team .%s", saycommand);
    register_clcmd(szTemp, function, flags, info);
}

stock client_printc(id, const text[], any:...)
{
    if(!(g_iConnected & (1 << id-1)) || !id)
        return;
    
    new szMsg[191];
    vformat(szMsg, charsmax(szMsg), text, 3);
    
    replace_all(szMsg, charsmax(szMsg), "\g","^x04");
    replace_all(szMsg, charsmax(szMsg), "\d","^x01");
    replace_all(szMsg, charsmax(szMsg), "\t","^x03");
    
    message_begin(MSG_ONE_UNRELIABLE, g_iMsgidSayText, _, id);
    write_byte(id);
    write_string(szMsg);
    message_end();
}

AMX Mod X Compiler 1.8.3-dev+4537
Copyright (c) 1997-2006 ITB CompuPhase
Copyright (c) 2004-2013 AMX Mod X Team

Error: Array index out of bounds (variable "g_iData") on line 88
Error: Array index out of bounds (variable "g_iData") on line 90
Error: Array index out of bounds (variable "g_iData") on line 91
Error: Array index out of bounds (variable "g_iData") on line 98
Error: Array index out of bounds (variable "g_iData") on line 99
Error: Array index out of bounds (variable "g_iData") on line 112
Error: Array index out of bounds (variable "g_iData") on line 120
Error: Array index out of bounds (variable "g_iData") on line 184
Error: Array index out of bounds (variable "g_iData") on line 199
Error: Array index out of bounds (variable "g_iData") on line 222
Error: Array index out of bounds (variable "g_iData") on line 223
Error: Array index out of bounds (variable "g_iData") on line 233
Error: Array index out of bounds (variable "g_iData") on line 238

13 Errors.
Could not locate output file C:\Documents and Settings\Xakep\Desktop\Copy of voteban.amx (compile failed).

[Arkshine]

Yeah, author uses a very weird way to set/get/update vote datas.

g_iData[%0][MAX_PLAYERS-1] <= there, you need to add -1 (since MAX_PLAYERS is now 33 and g_iData has a max size of 33 ; purpose if this macro is set data to last entry, yeah it's fucking weird).

[jimaway]

why is the MAX_PLAYERS 33 in the include??

[Arkshine]

Because that's something almost all plugins are using, declaring such constants and doing +1 each time, so it makes sense to add it with 33 as value for convenience and readability. But it's okay, if you plugin has such define, it will be redefine with your value.

[fysiks]

I think it's technically misleading because 32 is the actual number of max players. Adding 1 isn't really an issue IMO and is just an artifact of having zero-based array indexing, I just use 33 literally instead of defining anything since it will NEVER change.

[Arkshine]

It's technically correct. Well, I wanted to use 32, because it makes sense since it's the technical limit, but we answered me (The motherfucker Nextra) it would be logic to use 33 as it's always this way MAX_PLAYERS is used in plugins. HIS FAULT! Well, if people have some difficulty with it, I guess we could change that to 32. It's still dev version, so any changes can happen!

[hleV]

It should be 32. Now it can't be used like this:

PHP Code:

new players[MAX_PLAYERS], num;
get_players(players, num); 


Personally I've always used MAX_PLAYERS + 1 for player ID arrays.

Anyway, regarding the topic, the easiest way to remove the warning would be to undefine MAX_PLAYERS before it is defined in the plugin source file.

[Bugsy]

I agree, should be 32. When someone is using it to size an array, then they should know to add 1.