[desire worker]

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <sdktools_functions>
#include <sdkhooks>

new CurrentV[MAXPLAYERS+1];

public OnPluginStart()
{
		CurrentV[1] = CreateConVar("CurrentV[1]", "0", "current speed of player 1", FCVAR_PLUGIN|FCVAR_PROTECTED);
		CurrentV[2] = CreateConVar("CurrentV[2]", "0", "current speed of player 2", FCVAR_PLUGIN|FCVAR_PROTECTED);
		CurrentV[3] = CreateConVar("CurrentV[3]", "0", "current speed of player 3", FCVAR_PLUGIN|FCVAR_PROTECTED);
		CurrentV[4] = CreateConVar("CurrentV[4]", "0", "current speed of player 4", FCVAR_PLUGIN|FCVAR_PROTECTED);
		HookConVarChange(CurrentV[1], SpeedUpdater);
		HookConVarChange(CurrentV[2], SpeedUpdater);
		HookConVarChange(CurrentV[3], SpeedUpdater);
		HookConVarChange(CurrentV[4], SpeedUpdater);
}

public void SpeedUpdater(ConVar convar, char[] oldValue, char[] newValue, client) 
{
		//blah blah blah
}

I wanna deliver extra argument(in this case; client) for callback function in HookConVarChange function but

		HookConVarChange(CurrentV[1], SpeedUpdater(1));
		HookConVarChange(CurrentV[2], SpeedUpdater(2));
		HookConVarChange(CurrentV[3], SpeedUpdater(3));
		HookConVarChange(CurrentV[4], SpeedUpdater(4));

and

		HookConVarChange(CurrentV[1], SpeedUpdater, 1);
		HookConVarChange(CurrentV[2], SpeedUpdater, 2);
		HookConVarChange(CurrentV[3], SpeedUpdater, 3);
		HookConVarChange(CurrentV[4], SpeedUpdater, 4);

compiled both but

Both is yielding compile error.

How to deliver extra arguments for SpeedUpdater function?

[Fyren]

You can't.

In your callback, you get the handle of the cvar, so you can use that to know which one it is. For example, you can check cvar == CurrentV[1], probably using a loop.

[desire worker]

like below?

public void SpeedUpdater(ConVar convar, char[] oldValue, char[] newValue, client) 
{
                new client
		for(client=1, client<GETMAXCLIENT(); client++)
               {
                          if(convar == CurrentV[client])
                                   break;
               } 
               func(client);
}

That means ConVar convar is kind of address(&convar) like c pointer?

[Psyk0tik]

The HookConVarChange()/ConVar.AddChangeHook() function uses a specific callback.

PHP Code:

typedef ConVarChanged = function void(ConVar convar, const char[] oldValue, const char[] newValue) 


First off, the callback that you're hooking has an extra parameter, which is the client, and that's ONE of the reasons you're getting compiler errors.

Second, the hook function itself only has 2 parameters (1 if you use the methodmap one), and in your code, you're passing 3 parameters.

Third, your ConVar handles aren't even handles...

Here's how I would do it:

PHP Code:

// old syntax
#include <sourcemod>

#pragma semicolon 1

new Handle:g_hConVars[MAXPLAYERS + 1];

public OnPluginStart()
{
    g_hConVars[1] = CreateConVar("CurrentV[1]", "0.0", "current speed of player 1", FCVAR_PROTECTED);
    g_hConVars[2] = CreateConVar("CurrentV[2]", "0.0", "current speed of player 2", FCVAR_PROTECTED);
    g_hConVars[3] = CreateConVar("CurrentV[3]", "0.0", "current speed of player 3", FCVAR_PROTECTED);
    g_hConVars[4] = CreateConVar("CurrentV[4]", "0.0", "current speed of player 4", FCVAR_PROTECTED);

    for (new pos = 1; pos < 5; pos++)
    {
        HookConVarChange(g_hConVars[pos], ConVars_Changed);
    }
}

public ConVars_Changed(Handle:convar, const String:oldVal[], const String:newVal[])
{
    for (new client = 1; client <= MaxClients; client++)
    {
        if (IsClientInGame(client) && convar == g_hConVars[client])
        {
            new Float:flNewSpeed = StringToFloat(newVal);
            if (flNewSpeed > 0.0)
            {
                SpeedUpdater(client, flNewSpeed);
            }
            else
            {
                SpeedUpdater(client, 1.0);
            }
        }
    }
}

SpeedUpdater(client, Float:value)
{
    PrintToChatAll("Client %i: %N's new speed is: %.2f", client, client, value);
} 


PHP Code:

// new syntax
#include <sourcemod>

#pragma semicolon 1
#pragma newdecls required

ConVar g_cvConVars[MAXPLAYERS + 1];

public void OnPluginStart()
{
    g_cvConVars[1] = CreateConVar("CurrentV[1]", "0.0", "current speed of player 1", FCVAR_PROTECTED);
    g_cvConVars[2] = CreateConVar("CurrentV[2]", "0.0", "current speed of player 2", FCVAR_PROTECTED);
    g_cvConVars[3] = CreateConVar("CurrentV[3]", "0.0", "current speed of player 3", FCVAR_PROTECTED);
    g_cvConVars[4] = CreateConVar("CurrentV[4]", "0.0", "current speed of player 4", FCVAR_PROTECTED);

    for (int iPos = 1; iPos < 5; iPos++)
    {
        g_cvConVars[iPos].AddChangeHook(ConVars_Changed);
    }
}

public void ConVars_Changed(ConVar convar, const char[] oldVal, const char[] newVal)
{
    for (int client = 1; client <= MaxClients; client++)
    {
        if (IsClientInGame(client) && convar == g_cvConVars[client])
        {
            float flNewSpeed = StringToFloat(newVal);
            if (flNewSpeed > 0.0)
            {
                SpeedUpdater(client, flNewSpeed);
            }
            else
            {
                SpeedUpdater(client, 1.0);
            }
        }
    }
}

void SpeedUpdater(int client, float value)
{
    PrintToChatAll("Client %i: %N's new speed is: %.2f", client, client, value);
} 


I apologize in advance if I made any typos or misunderstood something. It's late here.

[desire worker]

oh that was`t handle... that`s why my convarchange function didn`t work.

thank you for your kind answer and code.

[Fyren]

Originally Posted by desire worker That means ConVar convar is kind of address(&convar) like c pointer?

Handles are not pointers, they're more like handles in the Windows API or file descriptors.

[Spirit_12]

Originally Posted by Crasher_3637 PHP Code:     for (int iPos = 1; iPos < 5; iPos++)     {         g_cvConVars[iPos].AddChangeHook(ConVars_Changed);     }

Don't hardcode your loops when running them with non-static variables.

PHP Code:

    for (int iPos; iPos < sizeof g_cvConVars; iPos++)
    {
        g_cvConVars[iPos].AddChangeHook(ConVars_Changed);
    } 


[Psyk0tik]

Originally Posted by Spirit_12 Don't hardcode your loops when running them with non-static variables. PHP Code:     for (int iPos; iPos < sizeof g_cvConVars; iPos++)     {         g_cvConVars[iPos].AddChangeHook(ConVars_Changed);     }

You're right, but I did that in this example because I only created 5 convars. There's no point in hooking the rest if they don't even have a convar stored in them. The OP can adjust it as he/she sees fit.